Add papercolor_light scheme for lightline.vim

autoload/lightline/colorscheme/papercolor_light.vim

@@ -0,0 +1,259 @@
+" =============================================================================
+" Filename: autoload/lightline/colorscheme/autoload/lightline/colorscheme/papercolor_light.vim
+" Author: TKNGUE
+" License: MIT License
+" Last Change: 2015/07/21 13:18:03
+" =============================================================================
+
+fun! <SID>grey_number(x) "{{{
+    if &t_Co == 88
+      if a:x < 23
+        return 0
+      elseif a:x < 69
+        return 1
+      elseif a:x < 103
+        return 2
+      elseif a:x < 127
+        return 3
+      elseif a:x < 150
+        return 4
+      elseif a:x < 173
+        return 5
+      elseif a:x < 196
+        return 6
+      elseif a:x < 219
+        return 7
+      elseif a:x < 243
+        return 8
+      else
+        return 9
+      endif
+    else
+      if a:x < 14
+        return 0
+      else
+        let l:n = (a:x - 8) / 10
+        let l:m = (a:x - 8) % 10
+        if l:m < 5
+          return l:n
+        else
+          return l:n + 1
+        endif
+      endif
+    endif
+  endfun"}}}
+
+  " Returns the actual grey level represented by the grey index
+  fun! <SID>grey_level(n)"{{{
+    if &t_Co == 88
+      if a:n == 0
+        return 0
+      elseif a:n == 1
+        return 46
+      elseif a:n == 2
+        return 92
+      elseif a:n == 3
+        return 115
+      elseif a:n == 4
+        return 139
+      elseif a:n == 5
+        return 162
+      elseif a:n == 6
+        return 185
+      elseif a:n == 7
+        return 208
+      elseif a:n == 8
+        return 231
+      else
+        return 255
+      endif
+    else
+      if a:n == 0
+        return 0
+      else
+        return 8 + (a:n * 10)
+      endif
+    endif
+  endfun"}}}
+
+  " Returns the palette index for the given grey index
+  fun! <SID>grey_colour(n)"{{{
+    if &t_Co == 88
+      if a:n == 0
+        return 16
+      elseif a:n == 9
+        return 79
+      else
+        return 79 + a:n
+      endif
+    else
+      if a:n == 0
+        return 16
+      elseif a:n == 25
+        return 231
+      else
+        return 231 + a:n
+      endif
+    endif
+  endfun"}}}
+
+  " Returns an approximate colour index for the given colour level
+  fun! <SID>rgb_number(x)"{{{
+    if &t_Co == 88
+      if a:x < 69
+        return 0
+      elseif a:x < 172
+        return 1
+      elseif a:x < 230
+        return 2
+      else
+        return 3
+      endif
+    else
+      if a:x < 75
+        return 0
+      else
+        let l:n = (a:x - 55) / 40
+        let l:m = (a:x - 55) % 40
+        if l:m < 20
+          return l:n
+        else
+          return l:n + 1
+        endif
+      endif
+    endif
+  endfun"}}}
+
+  " Returns the actual colour level for the given colour index
+  fun! <SID>rgb_level(n)"{{{
+    if &t_Co == 88
+      if a:n == 0
+        return 0
+      elseif a:n == 1
+        return 139
+      elseif a:n == 2
+        return 205
+      else
+        return 255
+      endif
+    else
+      if a:n == 0
+        return 0
+      else
+        return 55 + (a:n * 40)
+      endif
+    endif
+  endfun"}}}
+
+  " Returns the palette index for the given R/G/B colour indices
+  fun! <SID>rgb_colour(x, y, z)"{{{
+    if &t_Co == 88
+      return 16 + (a:x * 16) + (a:y * 4) + a:z
+    else
+      return 16 + (a:x * 36) + (a:y * 6) + a:z
+    endif
+  endfun"}}}
+
+  " Returns the palette index to approximate the given R/G/B colour levels
+  fun! <SID>colour(r, g, b)"{{{
+    " Get the closest grey
+    let l:gx = <SID>grey_number(a:r)
+    let l:gy = <SID>grey_number(a:g)
+    let l:gz = <SID>grey_number(a:b)
+
+    " Get the closest colour
+    let l:x = <SID>rgb_number(a:r)
+    let l:y = <SID>rgb_number(a:g)
+    let l:z = <SID>rgb_number(a:b)
+
+    if l:gx == l:gy && l:gy == l:gz
+      " There are two possibilities
+      let l:dgr = <SID>grey_level(l:gx) - a:r
+      let l:dgg = <SID>grey_level(l:gy) - a:g
+      let l:dgb = <SID>grey_level(l:gz) - a:b
+      let l:dgrey = (l:dgr * l:dgr) + (l:dgg * l:dgg) + (l:dgb * l:dgb)
+      let l:dr = <SID>rgb_level(l:gx) - a:r
+      let l:dg = <SID>rgb_level(l:gy) - a:g
+      let l:db = <SID>rgb_level(l:gz) - a:b
+      let l:drgb = (l:dr * l:dr) + (l:dg * l:dg) + (l:db * l:db)
+      if l:dgrey < l:drgb
+        " Use the grey
+        return <SID>grey_colour(l:gx)
+      else
+        " Use the colour
+        return <SID>rgb_colour(l:x, l:y, l:z)
+      endif
+    else
+      " Only one possibility
+      return <SID>rgb_colour(l:x, l:y, l:z)
+    endif
+  endfun"}}}
+
+  " Returns the palette index to approximate the '#rrggbb' hex string
+  fun! <SID>rgb(rgb)"{{{
+    let l:r = ("0x" . strpart(a:rgb, 1, 2)) + 0
+    let l:g = ("0x" . strpart(a:rgb, 3, 2)) + 0
+    let l:b = ("0x" . strpart(a:rgb, 5, 2)) + 0
+
+    return <SID>colour(l:r, l:g, l:b)
+  endfun"}}}
+
+ fun! <SID>X(color)"{{{
+   return [a:color, <SID>rgb(a:color)]
+ endfun"}}}
+
+let s:red     = <SID>X("#df0000")       "Include/Exception
+let s:green   = <SID>X("#008700")       "Boolean/Special
+let s:blue    = <SID>X("#4271ae")       "Keyword
+
+let s:pink    = <SID>X("#d7005f")       "Type
+let s:olive   = <SID>X("#718c00")       "String
+let s:navy    = <SID>X("#005f87")       "StorageClass
+
+let s:orange  = <SID>X("#d75f00")       "Number
+let s:purple  = <SID>X("#8959a8")       "Repeat/Conditional
+let s:aqua    = <SID>X("#3e999f")       "Operator/Delimiter
+
+
+" Basics:
+let s:foreground   = <SID>X("#4d4d4c")
+let s:background   = <SID>X("#F5F5F5")
+let s:window       = <SID>X("#efefef")
+let s:status       = s:aqua
+let s:error        = <SID>X("#ffafdf")
+
+" Tabline:
+let s:tabline_bg          = s:navy
+let s:tabline_active_fg   = s:foreground
+let s:tabline_active_bg   = s:window
+let s:tabline_inactive_fg = s:background
+let s:tabline_inactive_bg = s:aqua
+
+" Statusline:
+let s:statusline_active_fg   = s:window
+let s:statusline_active_bg   = s:navy
+let s:statusline_inactive_fg = s:foreground
+let s:statusline_inactive_bg = <SID>X("#dadada")
+
+" Visual:
+let s:visual_fg = s:background
+let s:visual_bg = s:blue
+
+let s:p = {'normal': {}, 'inactive': {}, 'insert': {}, 'replace': {}, 'visual': {}, 'tabline': {}}
+let s:p.normal.left       = [ [ s:foreground, s:background ], [ s:statusline_active_fg, s:status ], [ s:statusline_active_fg, s:statusline_active_bg ] ]
+let s:p.normal.right      = [ [ s:foreground, s:background ], [ s:statusline_active_fg, s:status ], [ s:statusline_active_fg, s:statusline_active_bg ] ]
+let s:p.normal.middle     = [ [ s:statusline_active_fg, s:statusline_active_bg ]]
+let s:p.inactive.right    = [ [ s:foreground, s:background ], [ s:foreground, s:background ] ]
+let s:p.inactive.left     = [ [ s:foreground, s:background ], [ s:foreground, s:background ] ]
+let s:p.inactive.middle   = [ [ s:foreground, s:background ], ]
+" let s:p.insert.left     = [ [ s:base0, s:base0 ], [ s:base3, s:base01 ] ]
+let s:p.replace.left    = [ [ s:background, s:pink ], [s:statusline_active_fg, s:status ], [ s:statusline_active_fg, s:statusline_active_bg ] ]
+let s:p.visual.left     = [ [ s:background, s:blue ], [s:statusline_active_fg, s:status ], [ s:statusline_active_fg, s:statusline_active_bg ]  ]
+let s:p.tabline.left      = [ [s:tabline_inactive_fg, s:tabline_inactive_bg ]]
+let s:p.tabline.tabsel    = [ [s:tabline_active_fg, s:tabline_active_bg ] ]
+let s:p.tabline.middle    = [ [s:tabline_bg, s:tabline_bg]]
+let s:p.tabline.right   = copy(s:p.normal.right)
+let s:p.normal.error    = [ [ s:background, s:error ] ]
+let s:p.normal.warning  = [ [ s:background, s:olive ] ]
+
+let lightline#colorscheme#papercolor_light#palette = lightline#colorscheme#flatten(s:p)