mirror of
https://github.com/tpope/vim-markdown.git
synced 2025-11-09 18:33:49 -05:00
f35c43c535
1. Add support for setext style headings 2. Use the 's' flag in search() to set the ' mark instead of using m' 3. Fix the guard
83 lines
2.5 KiB
VimL
83 lines
2.5 KiB
VimL
" Vim filetype plugin
|
|
" Language: Markdown
|
|
" Maintainer: Tim Pope <vimNOSPAM@tpope.org>
|
|
" Last Change: 2019 Dec 05
|
|
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
|
|
runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
|
|
|
|
setlocal comments=fb:*,fb:-,fb:+,n:> commentstring=<!--%s-->
|
|
setlocal formatoptions+=tcqln formatoptions-=r formatoptions-=o
|
|
setlocal formatlistpat=^\\s*\\d\\+\\.\\s\\+\\\|^[-*+]\\s\\+\\\|^\\[^\\ze[^\\]]\\+\\]:
|
|
|
|
if exists('b:undo_ftplugin')
|
|
let b:undo_ftplugin .= "|setl cms< com< fo< flp<"
|
|
else
|
|
let b:undo_ftplugin = "setl cms< com< fo< flp<"
|
|
endif
|
|
|
|
if !exists("g:no_plugin_maps") && !exists("g:no_markdown_maps")
|
|
nnoremap <silent><buffer> [[ :<C-U>call search('\%(^#\{1,5\}\s\+\S\\|^\S.*\n^[=-]\+$\)', "bsW")<CR>
|
|
nnoremap <silent><buffer> ]] :<C-U>call search('\%(^#\{1,5\}\s\+\S\\|^\S.*\n^[=-]\+$\)', "sW")<CR>
|
|
xnoremap <silent><buffer> [[ :<C-U>exe "normal! gv"<Bar>call search('\%(^#\{1,5\}\s\+\S\\|^\S.*\n^[=-]\+$\)', "bsW")<CR>
|
|
xnoremap <silent><buffer> ]] :<C-U>exe "normal! gv"<Bar>call search('\%(^#\{1,5\}\s\+\S\\|^\S.*\n^[=-]\+$\)', "sW")<CR>
|
|
let b:undo_ftplugin .= '|sil! nunmap <buffer> [[|sil! nunmap <buffer> ]]|sil! xunmap <buffer> [[|sil! xunmap <buffer> ]]'
|
|
endif
|
|
|
|
function! s:NotCodeBlock(lnum) abort
|
|
return synIDattr(synID(v:lnum, 1, 1), 'name') !=# 'markdownCode'
|
|
endfunction
|
|
|
|
function! MarkdownFold() abort
|
|
let line = getline(v:lnum)
|
|
|
|
if line =~# '^#\+ ' && s:NotCodeBlock(v:lnum)
|
|
return ">" . match(line, ' ')
|
|
endif
|
|
|
|
let nextline = getline(v:lnum + 1)
|
|
if (line =~ '^.\+$') && (nextline =~ '^=\+$') && s:NotCodeBlock(v:lnum + 1)
|
|
return ">1"
|
|
endif
|
|
|
|
if (line =~ '^.\+$') && (nextline =~ '^-\+$') && s:NotCodeBlock(v:lnum + 1)
|
|
return ">2"
|
|
endif
|
|
|
|
return "="
|
|
endfunction
|
|
|
|
function! s:HashIndent(lnum) abort
|
|
let hash_header = matchstr(getline(a:lnum), '^#\{1,6}')
|
|
if len(hash_header)
|
|
return hash_header
|
|
else
|
|
let nextline = getline(a:lnum + 1)
|
|
if nextline =~# '^=\+\s*$'
|
|
return '#'
|
|
elseif nextline =~# '^-\+\s*$'
|
|
return '##'
|
|
endif
|
|
endif
|
|
endfunction
|
|
|
|
function! MarkdownFoldText() abort
|
|
let hash_indent = s:HashIndent(v:foldstart)
|
|
let title = substitute(getline(v:foldstart), '^#\+\s*', '', '')
|
|
let foldsize = (v:foldend - v:foldstart + 1)
|
|
let linecount = '['.foldsize.' lines]'
|
|
return hash_indent.' '.title.' '.linecount
|
|
endfunction
|
|
|
|
if has("folding") && exists("g:markdown_folding")
|
|
setlocal foldexpr=MarkdownFold()
|
|
setlocal foldmethod=expr
|
|
setlocal foldtext=MarkdownFoldText()
|
|
let b:undo_ftplugin .= " foldexpr< foldmethod< foldtext<"
|
|
endif
|
|
|
|
" vim:set sw=2:
|