Add v language, closes #437

README.md

@@ -10,7 +10,7 @@ A collection of language packs for Vim.
 > One to rule them all, one to find them, one to bring them all and in the darkness bind them.
 
 - It **won't affect your startup time**, as scripts are loaded only on demand\*.
-- It **installs and updates 120+ times faster** than the <!--Package Count-->146<!--/Package Count--> packages it consists of.
+- It **installs and updates 120+ times faster** than the <!--Package Count-->147<!--/Package Count--> packages it consists of.
 - Solid syntax and indentation support (other features skipped). Only the best language packs.
 - All unnecessary files are ignored (like enormous documentation from php support).
 - No support for esoteric languages, only most popular ones (modern too, like `slim`).
@@ -119,7 +119,7 @@ If you need full functionality of any plugin, please use it directly with your p
 - [log](https://github.com/MTDL9/vim-log-highlighting) (syntax)
 - [lua](https://github.com/tbastos/vim-lua) (syntax, indent)
 - [mako](https://github.com/sophacles/vim-bundle-mako) (syntax, indent, ftplugin)
-- [markdown](https://github.com/plasticboy/vim-markdown) (syntax, indent)
+- [markdown](https://github.com/plasticboy/vim-markdown) (syntax, indent, ftplugin)
 - [mathematica](https://github.com/voldikss/vim-mma) (syntax, ftplugin)
 - [mdx](https://github.com/jxnblk/vim-mdx-js) (syntax)
 - [meson](https://github.com/mesonbuild/meson) (syntax, indent, ftplugin)
@@ -178,6 +178,7 @@ If you need full functionality of any plugin, please use it directly with your p
 - [tptp](https://github.com/c-cube/vim-tptp) (syntax)
 - [twig](https://github.com/lumiliet/vim-twig) (syntax, indent, ftplugin)
 - [typescript](https://github.com/HerringtonDarkholme/yats.vim) (syntax, indent, compiler, ftplugin)
+- [v](https://github.com/ollykel/v-vim) (syntax, indent, ftplugin)
 - [vala](https://github.com/arrufat/vala.vim) (syntax, indent, ftplugin)
 - [vbnet](https://github.com/vim-scripts/vbnet.vim) (syntax)
 - [vcl](https://github.com/smerrill/vcl-vim-plugin) (syntax)

after/ftplugin/markdown.vim

@@ -0,0 +1,205 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'markdown') == -1
+
+" vim: ts=4 sw=4:
+" folding for Markdown headers, both styles (atx- and setex-)
+" http://daringfireball.net/projects/markdown/syntax#header
+"
+" this code can be placed in file
+"   $HOME/.vim/after/ftplugin/markdown.vim
+"
+" original version from Steve Losh's gist: https://gist.github.com/1038710
+
+function! s:is_mkdCode(lnum)
+    let name = synIDattr(synID(a:lnum, 1, 0), 'name')
+    return (name =~ '^mkd\%(Code$\|Snippet\)' || name != '' && name !~ '^\%(mkd\|html\)')
+endfunction
+
+if get(g:, "vim_markdown_folding_style_pythonic", 0)
+    function! Foldexpr_markdown(lnum)
+        let l1 = getline(a:lnum)
+        "~~~~~ keep track of fenced code blocks ~~~~~
+        "If we hit a code block fence
+        if l1 =~ '````*' || l1 =~ '\~\~\~\~*'
+            " toggle the variable that says if we're in a code block
+            if b:fenced_block == 0
+                let b:fenced_block = 1
+            elseif b:fenced_block == 1
+                let b:fenced_block = 0
+            endif
+        " else, if we're caring about front matter
+        elseif g:vim_markdown_frontmatter == 1
+            " if we're in front matter and not on line 1
+            if b:front_matter == 1 && a:lnum > 2
+                let l0 = getline(a:lnum-1)
+                " if the previous line fenced front matter
+                if l0 == '---'
+                    " we must not be in front matter
+                    let b:front_matter = 0
+                endif
+            " else, if we're on line one
+            elseif a:lnum == 1
+                " if we hit a front matter fence
+                if l1 == '---'
+                    " we're in the front matter
+                    let b:front_matter = 1
+                endif
+            endif
+        endif
+
+        " if we're in a code block or front matter
+        if b:fenced_block == 1 || b:front_matter == 1
+            if a:lnum == 1
+                " fold any 'preamble'
+                return '>1'
+            else
+                " keep previous foldlevel
+                return '='
+            endif
+        endif
+
+        let l2 = getline(a:lnum+1)
+        " if the next line starts with two or more '='
+        " and is not code
+        if l2 =~ '^==\+\s*' && !s:is_mkdCode(a:lnum+1)
+            " next line is underlined (level 1)
+            return '>0'
+        " else, if the nex line starts with two or more '-'
+        " and is not code
+        elseif l2 =~ '^--\+\s*' && !s:is_mkdCode(a:lnum+1)
+            " next line is underlined (level 2)
+            return '>1'
+        endif
+
+        "if we're on a non-code line starting with a pound sign
+        if l1 =~ '^#' && !s:is_mkdCode(a:lnum)
+            " set the fold level to the number of hashes -1
+            " return '>'.(matchend(l1, '^#\+') - 1)
+            " set the fold level to the number of hashes
+            return '>'.(matchend(l1, '^#\+'))
+        " else, if we're on line 1
+        elseif a:lnum == 1
+            " fold any 'preamble'
+            return '>1'
+        else
+            " keep previous foldlevel
+            return '='
+        endif
+    endfunction
+
+    function! Foldtext_markdown()
+        let line = getline(v:foldstart)
+        let has_numbers = &number || &relativenumber
+        let nucolwidth = &fdc + has_numbers * &numberwidth
+        let windowwidth = winwidth(0) - nucolwidth - 6
+        let foldedlinecount = v:foldend - v:foldstart
+        let line = strpart(line, 0, windowwidth - 2 -len(foldedlinecount))
+        let line = substitute(line, '\%("""\|''''''\)', '', '')
+        let fillcharcount = windowwidth - len(line) - len(foldedlinecount) + 1
+        return line . ' ' . repeat("-", fillcharcount) . ' ' . foldedlinecount
+    endfunction
+else " vim_markdown_folding_style_pythonic == 0
+    function! Foldexpr_markdown(lnum)
+        if (a:lnum == 1)
+            let l0 = ''
+        else
+            let l0 = getline(a:lnum-1)
+        endif
+
+        " keep track of fenced code blocks
+        if l0 =~ '````*' || l0 =~ '\~\~\~\~*'
+            if b:fenced_block == 0
+                let b:fenced_block = 1
+            elseif b:fenced_block == 1
+                let b:fenced_block = 0
+            endif
+        elseif g:vim_markdown_frontmatter == 1
+            if b:front_matter == 1
+                if l0 == '---'
+                    let b:front_matter = 0
+                endif
+            elseif a:lnum == 2
+                if l0 == '---'
+                    let b:front_matter = 1
+                endif
+            endif
+        endif
+
+        if b:fenced_block == 1 || b:front_matter == 1
+            " keep previous foldlevel
+            return '='
+        endif
+
+        let l2 = getline(a:lnum+1)
+        if  l2 =~ '^==\+\s*' && !s:is_mkdCode(a:lnum+1)
+            " next line is underlined (level 1)
+            return '>1'
+        elseif l2 =~ '^--\+\s*' && !s:is_mkdCode(a:lnum+1)
+            " next line is underlined (level 2)
+            if s:vim_markdown_folding_level >= 2
+                return '>1'
+            else
+                return '>2'
+            endif
+        endif
+
+        let l1 = getline(a:lnum)
+        if l1 =~ '^#' && !s:is_mkdCode(a:lnum)
+            " fold level according to option
+            if s:vim_markdown_folding_level == 1 || matchend(l1, '^#\+') > s:vim_markdown_folding_level
+                if a:lnum == line('$')
+                    return matchend(l1, '^#\+') - 1
+                else
+                    return -1
+                endif
+            else
+                " headers are not folded
+                return 0
+            endif
+        endif
+
+        if l0 =~ '^#' && !s:is_mkdCode(a:lnum-1)
+            " previous line starts with hashes
+            return '>'.matchend(l0, '^#\+')
+        else
+            " keep previous foldlevel
+            return '='
+        endif
+    endfunction
+endif
+
+
+let b:fenced_block = 0
+let b:front_matter = 0
+let s:vim_markdown_folding_level = get(g:, "vim_markdown_folding_level", 1)
+
+function! s:MarkdownSetupFolding()
+    if !get(g:, "vim_markdown_folding_disabled", 0)
+        if get(g:, "vim_markdown_folding_style_pythonic", 0)
+            if get(g:, "vim_markdown_override_foldtext", 1)
+                setlocal foldtext=Foldtext_markdown()
+            endif
+        endif
+        setlocal foldexpr=Foldexpr_markdown(v:lnum)
+        setlocal foldmethod=expr
+    endif
+endfunction
+
+function! s:MarkdownSetupFoldLevel()
+    if get(g:, "vim_markdown_folding_style_pythonic", 0)
+        " set default foldlevel
+        execute "setlocal foldlevel=".s:vim_markdown_folding_level
+    endif
+endfunction
+
+call s:MarkdownSetupFoldLevel()
+call s:MarkdownSetupFolding()
+
+augroup Mkd
+    " These autocmds need to be kept in sync with the autocmds calling
+    " s:MarkdownRefreshSyntax in ftplugin/markdown.vim.
+    autocmd BufWinEnter,BufWritePost <buffer> call s:MarkdownSetupFolding()
+    autocmd InsertEnter,InsertLeave <buffer> call s:MarkdownSetupFolding()
+    autocmd CursorHold,CursorHoldI <buffer> call s:MarkdownSetupFolding()
+augroup END
+
+endif

build

@@ -233,7 +233,7 @@ PACKS="
   log:MTDL9/vim-log-highlighting
   lua:tbastos/vim-lua
   mako:sophacles/vim-bundle-mako
-  markdown:plasticboy/vim-markdown:_SYNTAX
+  markdown:plasticboy/vim-markdown
   mathematica:voldikss/vim-mma
   mdx:jxnblk/vim-mdx-js
   meson:mesonbuild/meson:_ALL:/data/syntax-highlighting/vim/
@@ -292,6 +292,7 @@ PACKS="
   tptp:c-cube/vim-tptp
   twig:lumiliet/vim-twig
   typescript:HerringtonDarkholme/yats.vim
+  v:ollykel/v-vim
   vala:arrufat/vala.vim
   vbnet:vim-scripts/vbnet.vim
   vcl:smerrill/vcl-vim-plugin

ftdetect/polyglot.vim

@@ -781,7 +781,7 @@ endif
 
 if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'markdown') == -1
   augroup filetypedetect
-  " markdown, from markdown.vim in plasticboy/vim-markdown:_SYNTAX
+  " markdown, from markdown.vim in plasticboy/vim-markdown
 if !has('patch-7.4.480')
     " Before this patch, vim used modula2 for .md.
     au! filetypedetect BufRead,BufNewFile *.md
@@ -1473,6 +1473,14 @@ autocmd BufNewFile,BufRead *.tsx setlocal filetype=typescriptreact
   augroup end
 endif
 
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'v') == -1
+  augroup filetypedetect
+  " v, from vlang.vim in ollykel/v-vim
+au BufNewFile,BufRead *.v set filetype=vlang
+au BufNewFile,BufRead *.v set syntax=vlang
+  augroup end
+endif
+
 if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'vala') == -1
   augroup filetypedetect
   " vala, from vala.vim in arrufat/vala.vim

ftplugin/markdown.vim

@@ -0,0 +1,795 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'markdown') == -1
+
+"TODO print messages when on visual mode. I only see VISUAL, not the messages.
+
+" Function interface phylosophy:
+"
+" - functions take arbitrary line numbers as parameters.
+"    Current cursor line is only a suitable default parameter.
+"
+" - only functions that bind directly to user actions:
+"
+"    - print error messages.
+"       All intermediate functions limit themselves return `0` to indicate an error.
+"
+"    - move the cursor. All other functions do not move the cursor.
+"
+" This is how you should view headers for the header mappings:
+"
+"   |BUFFER
+"   |
+"   |Outside any header
+"   |
+" a-+# a
+"   |
+"   |Inside a
+"   |
+" a-+
+" b-+## b
+"   |
+"   |inside b
+"   |
+" b-+
+" c-+### c
+"   |
+"   |Inside c
+"   |
+" c-+
+" d-|# d
+"   |
+"   |Inside d
+"   |
+" d-+
+" e-|e
+"   |====
+"   |
+"   |Inside e
+"   |
+" e-+
+
+" For each level, contains the regexp that matches at that level only.
+"
+let s:levelRegexpDict = {
+    \ 1: '\v^(#[^#]@=|.+\n\=+$)',
+    \ 2: '\v^(##[^#]@=|.+\n-+$)',
+    \ 3: '\v^###[^#]@=',
+    \ 4: '\v^####[^#]@=',
+    \ 5: '\v^#####[^#]@=',
+    \ 6: '\v^######[^#]@='
+\ }
+
+" Maches any header level of any type.
+"
+" This could be deduced from `s:levelRegexpDict`, but it is more
+" efficient to have a single regexp for this.
+"
+let s:headersRegexp = '\v^(#|.+\n(\=+|-+)$)'
+
+" Returns the line number of the first header before `line`, called the
+" current header.
+"
+" If there is no current header, return `0`.
+"
+" @param a:1 The line to look the header of. Default value: `getpos('.')`.
+"
+function! s:GetHeaderLineNum(...)
+    if a:0 == 0
+        let l:l = line('.')
+    else
+        let l:l = a:1
+    endif
+    while(l:l > 0)
+        if join(getline(l:l, l:l + 1), "\n") =~ s:headersRegexp
+            return l:l
+        endif
+        let l:l -= 1
+    endwhile
+    return 0
+endfunction
+
+" -  if inside a header goes to it.
+"    Return its line number.
+"
+" -  if on top level outside any headers,
+"    print a warning
+"    Return `0`.
+"
+function! s:MoveToCurHeader()
+    let l:lineNum = s:GetHeaderLineNum()
+    if l:lineNum != 0
+        call cursor(l:lineNum, 1)
+    else
+        echo 'outside any header'
+        "normal! gg
+    endif
+    return l:lineNum
+endfunction
+
+" Move cursor to next header of any level.
+"
+" If there are no more headers, print a warning.
+"
+function! s:MoveToNextHeader()
+    if search(s:headersRegexp, 'W') == 0
+        "normal! G
+        echo 'no next header'
+    endif
+endfunction
+
+" Move cursor to previous header (before current) of any level.
+"
+" If it does not exist, print a warning.
+"
+function! s:MoveToPreviousHeader()
+    let l:curHeaderLineNumber = s:GetHeaderLineNum()
+    let l:noPreviousHeader = 0
+    if l:curHeaderLineNumber <= 1
+        let l:noPreviousHeader = 1
+    else
+        let l:previousHeaderLineNumber = s:GetHeaderLineNum(l:curHeaderLineNumber - 1)
+        if l:previousHeaderLineNumber == 0
+            let l:noPreviousHeader = 1
+        else
+            call cursor(l:previousHeaderLineNumber, 1)
+        endif
+    endif
+    if l:noPreviousHeader
+        echo 'no previous header'
+    endif
+endfunction
+
+" - if line is inside a header, return the header level (h1 -> 1, h2 -> 2, etc.).
+"
+" - if line is at top level outside any headers, return `0`.
+"
+function! s:GetHeaderLevel(...)
+    if a:0 == 0
+        let l:line = line('.')
+    else
+        let l:line = a:1
+    endif
+    let l:linenum = s:GetHeaderLineNum(l:line)
+    if l:linenum != 0
+        return s:GetLevelOfHeaderAtLine(l:linenum)
+    else
+        return 0
+    endif
+endfunction
+
+" Returns the level of the header at the given line.
+"
+" If there is no header at the given line, returns `0`.
+"
+function! s:GetLevelOfHeaderAtLine(linenum)
+    let l:lines = join(getline(a:linenum, a:linenum + 1), "\n")
+    for l:key in keys(s:levelRegexpDict)
+        if l:lines =~ get(s:levelRegexpDict, l:key)
+            return l:key
+        endif
+    endfor
+    return 0
+endfunction
+
+" Move cursor to parent header of the current header.
+"
+" If it does not exit, print a warning and do nothing.
+"
+function! s:MoveToParentHeader()
+    let l:linenum = s:GetParentHeaderLineNumber()
+    if l:linenum != 0
+        call cursor(l:linenum, 1)
+    else
+        echo 'no parent header'
+    endif
+endfunction
+
+" Return the line number of the parent header of line `line`.
+"
+" If it has no parent, return `0`.
+"
+function! s:GetParentHeaderLineNumber(...)
+    if a:0 == 0
+        let l:line = line('.')
+    else
+        let l:line = a:1
+    endif
+    let l:level = s:GetHeaderLevel(l:line)
+    if l:level > 1
+        let l:linenum = s:GetPreviousHeaderLineNumberAtLevel(l:level - 1, l:line)
+        return l:linenum
+    endif
+    return 0
+endfunction
+
+" Return the line number of the previous header of given level.
+" in relation to line `a:1`. If not given, `a:1 = getline()`
+"
+" `a:1` line is included, and this may return the current header.
+"
+" If none return 0.
+"
+function! s:GetNextHeaderLineNumberAtLevel(level, ...)
+    if a:0 < 1
+        let l:line = line('.')
+    else
+        let l:line = a:1
+    endif
+    let l:l = l:line
+    while(l:l <= line('$'))
+        if join(getline(l:l, l:l + 1), "\n") =~ get(s:levelRegexpDict, a:level)
+            return l:l
+        endif
+        let l:l += 1
+    endwhile
+    return 0
+endfunction
+
+" Return the line number of the previous header of given level.
+" in relation to line `a:1`. If not given, `a:1 = getline()`
+"
+" `a:1` line is included, and this may return the current header.
+"
+" If none return 0.
+"
+function! s:GetPreviousHeaderLineNumberAtLevel(level, ...)
+    if a:0 == 0
+        let l:line = line('.')
+    else
+        let l:line = a:1
+    endif
+    let l:l = l:line
+    while(l:l > 0)
+        if join(getline(l:l, l:l + 1), "\n") =~ get(s:levelRegexpDict, a:level)
+            return l:l
+        endif
+        let l:l -= 1
+    endwhile
+    return 0
+endfunction
+
+" Move cursor to next sibling header.
+"
+" If there is no next siblings, print a warning and don't move.
+"
+function! s:MoveToNextSiblingHeader()
+    let l:curHeaderLineNumber = s:GetHeaderLineNum()
+    let l:curHeaderLevel = s:GetLevelOfHeaderAtLine(l:curHeaderLineNumber)
+    let l:curHeaderParentLineNumber = s:GetParentHeaderLineNumber()
+    let l:nextHeaderSameLevelLineNumber = s:GetNextHeaderLineNumberAtLevel(l:curHeaderLevel, l:curHeaderLineNumber + 1)
+    let l:noNextSibling = 0
+    if l:nextHeaderSameLevelLineNumber == 0
+        let l:noNextSibling = 1
+    else
+        let l:nextHeaderSameLevelParentLineNumber = s:GetParentHeaderLineNumber(l:nextHeaderSameLevelLineNumber)
+        if l:curHeaderParentLineNumber == l:nextHeaderSameLevelParentLineNumber
+            call cursor(l:nextHeaderSameLevelLineNumber, 1)
+        else
+            let l:noNextSibling = 1
+        endif
+    endif
+    if l:noNextSibling
+        echo 'no next sibling header'
+    endif
+endfunction
+
+" Move cursor to previous sibling header.
+"
+" If there is no previous siblings, print a warning and do nothing.
+"
+function! s:MoveToPreviousSiblingHeader()
+    let l:curHeaderLineNumber = s:GetHeaderLineNum()
+    let l:curHeaderLevel = s:GetLevelOfHeaderAtLine(l:curHeaderLineNumber)
+    let l:curHeaderParentLineNumber = s:GetParentHeaderLineNumber()
+    let l:previousHeaderSameLevelLineNumber = s:GetPreviousHeaderLineNumberAtLevel(l:curHeaderLevel, l:curHeaderLineNumber - 1)
+    let l:noPreviousSibling = 0
+    if l:previousHeaderSameLevelLineNumber == 0
+        let l:noPreviousSibling = 1
+    else
+        let l:previousHeaderSameLevelParentLineNumber = s:GetParentHeaderLineNumber(l:previousHeaderSameLevelLineNumber)
+        if l:curHeaderParentLineNumber == l:previousHeaderSameLevelParentLineNumber
+            call cursor(l:previousHeaderSameLevelLineNumber, 1)
+        else
+            let l:noPreviousSibling = 1
+        endif
+    endif
+    if l:noPreviousSibling
+        echo 'no previous sibling header'
+    endif
+endfunction
+
+function! s:Toc(...)
+    if a:0 > 0
+        let l:window_type = a:1
+    else
+        let l:window_type = 'vertical'
+    endif
+
+
+    let l:bufnr = bufnr('%')
+    let l:cursor_line = line('.')
+    let l:cursor_header = 0
+    let l:fenced_block = 0
+    let l:front_matter = 0
+    let l:header_list = []
+    let l:header_max_len = 0
+    let l:vim_markdown_toc_autofit = get(g:, "vim_markdown_toc_autofit", 0)
+    let l:vim_markdown_frontmatter = get(g:, "vim_markdown_frontmatter", 0)
+    for i in range(1, line('$'))
+        let l:lineraw = getline(i)
+        let l:l1 = getline(i+1)
+        let l:line = substitute(l:lineraw, "#", "\\\#", "g")
+        if l:line =~ '````*' || l:line =~ '\~\~\~\~*'
+            if l:fenced_block == 0
+                let l:fenced_block = 1
+            elseif l:fenced_block == 1
+                let l:fenced_block = 0
+            endif
+        elseif l:vim_markdown_frontmatter == 1
+            if l:front_matter == 1
+                if l:line == '---'
+                    let l:front_matter = 0
+                endif
+            elseif i == 1
+                if l:line == '---'
+                    let l:front_matter = 1
+                endif
+            endif
+        endif
+        if l:line =~ '^#\+' || (l:l1 =~ '^=\+\s*$' || l:l1 =~ '^-\+\s*$') && l:line =~ '^\S'
+            let l:is_header = 1
+        else
+            let l:is_header = 0
+        endif
+        if l:is_header == 1 && l:fenced_block == 0 && l:front_matter == 0
+            " append line to location list
+            let l:item = {'lnum': i, 'text': l:line, 'valid': 1, 'bufnr': l:bufnr, 'col': 1}
+            let l:header_list = l:header_list + [l:item]
+            " set header number of the cursor position
+            if l:cursor_header == 0
+                if i == l:cursor_line
+                    let l:cursor_header = len(l:header_list)
+                elseif i > l:cursor_line
+                    let l:cursor_header = len(l:header_list) - 1
+                endif
+            endif
+            " keep track of the longest header size (heading level + title)
+            let l:total_len = stridx(l:line, ' ') + strdisplaywidth(l:line)
+            if l:total_len > l:header_max_len
+                let l:header_max_len = l:total_len
+            endif
+        endif
+    endfor
+    call setloclist(0, l:header_list)
+    if len(l:header_list) == 0
+        echom "Toc: No headers."
+        return
+    endif
+
+    if l:window_type ==# 'horizontal'
+        lopen
+    elseif l:window_type ==# 'vertical'
+        vertical lopen
+        " auto-fit toc window when possible to shrink it
+        if (&columns/2) > l:header_max_len && l:vim_markdown_toc_autofit == 1
+            execute 'vertical resize ' . (l:header_max_len + 1)
+        else
+            execute 'vertical resize ' . (&columns/2)
+        endif
+    elseif l:window_type ==# 'tab'
+        tab lopen
+    else
+        lopen
+    endif
+    setlocal modifiable
+    for i in range(1, line('$'))
+        " this is the location-list data for the current item
+        let d = getloclist(0)[i-1]
+        " atx headers
+        if match(d.text, "^#") > -1
+            let l:level = len(matchstr(d.text, '#*', 'g'))-1
+            let d.text = substitute(d.text, '\v^#*[ ]*', '', '')
+            let d.text = substitute(d.text, '\v[ ]*#*$', '', '')
+        " setex headers
+        else
+            let l:next_line = getbufline(d.bufnr, d.lnum+1)
+            if match(l:next_line, "=") > -1
+                let l:level = 0
+            elseif match(l:next_line, "-") > -1
+                let l:level = 1
+            endif
+        endif
+        call setline(i, repeat('  ', l:level). d.text)
+    endfor
+    setlocal nomodified
+    setlocal nomodifiable
+    execute 'normal! ' . l:cursor_header . 'G'
+endfunction
+
+" Convert Setex headers in range `line1 .. line2` to Atx.
+"
+" Return the number of conversions.
+"
+function! s:SetexToAtx(line1, line2)
+    let l:originalNumLines = line('$')
+    execute 'silent! ' . a:line1 . ',' . a:line2 . 'substitute/\v(.*\S.*)\n\=+$/# \1/'
+    execute 'silent! ' . a:line1 . ',' . a:line2 . 'substitute/\v(.*\S.*)\n-+$/## \1/'
+    return l:originalNumLines - line('$')
+endfunction
+
+" If `a:1` is 0, decrease the level of all headers in range `line1 .. line2`.
+"
+" Otherwise, increase the level. `a:1` defaults to `0`.
+"
+function! s:HeaderDecrease(line1, line2, ...)
+    if a:0 > 0
+        let l:increase = a:1
+    else
+        let l:increase = 0
+    endif
+    if l:increase
+        let l:forbiddenLevel = 6
+        let l:replaceLevels = [5, 1]
+        let l:levelDelta = 1
+    else
+        let l:forbiddenLevel = 1
+        let l:replaceLevels = [2, 6]
+        let l:levelDelta = -1
+    endif
+    for l:line in range(a:line1, a:line2)
+        if join(getline(l:line, l:line + 1), "\n") =~ s:levelRegexpDict[l:forbiddenLevel]
+            echomsg 'There is an h' . l:forbiddenLevel . ' at line ' . l:line . '. Aborting.'
+            return
+        endif
+    endfor
+    let l:numSubstitutions = s:SetexToAtx(a:line1, a:line2)
+    let l:flags = (&gdefault ? '' : 'g')
+    for l:level in range(replaceLevels[0], replaceLevels[1], -l:levelDelta)
+        execute 'silent! ' . a:line1 . ',' . (a:line2 - l:numSubstitutions) . 'substitute/' . s:levelRegexpDict[l:level] . '/' . repeat('#', l:level + l:levelDelta) . '/' . l:flags
+    endfor
+endfunction
+
+" Format table under cursor.
+"
+" Depends on Tabularize.
+"
+function! s:TableFormat()
+    let l:pos = getpos('.')
+    normal! {
+    " Search instead of `normal! j` because of the table at beginning of file edge case.
+    call search('|')
+    normal! j
+    " Remove everything that is not a pipe, colon or hyphen next to a colon othewise
+    " well formated tables would grow because of addition of 2 spaces on the separator
+    " line by Tabularize /|.
+    let l:flags = (&gdefault ? '' : 'g')
+    execute 's/\(:\@<!-:\@!\|[^|:-]\)//e' . l:flags
+    execute 's/--/-/e' . l:flags
+    Tabularize /|
+    " Move colons for alignment to left or right side of the cell.
+    execute 's/:\( \+\)|/\1:|/e' . l:flags
+    execute 's/|\( \+\):/|:\1/e' . l:flags
+    execute 's/ /-/' . l:flags
+    call setpos('.', l:pos)
+endfunction
+
+" Wrapper to do move commands in visual mode.
+"
+function! s:VisMove(f)
+    norm! gv
+    call function(a:f)()
+endfunction
+
+" Map in both normal and visual modes.
+"
+function! s:MapNormVis(rhs,lhs)
+    execute 'nn <buffer><silent> ' . a:rhs . ' :call ' . a:lhs . '()<cr>'
+    execute 'vn <buffer><silent> ' . a:rhs . ' <esc>:call <sid>VisMove(''' . a:lhs . ''')<cr>'
+endfunction
+
+" Parameters:
+"
+" - step +1 for right, -1 for left
+"
+" TODO: multiple lines.
+"
+function! s:FindCornerOfSyntax(lnum, col, step)
+    let l:col = a:col
+    let l:syn = synIDattr(synID(a:lnum, l:col, 1), 'name')
+    while synIDattr(synID(a:lnum, l:col, 1), 'name') ==# l:syn
+        let l:col += a:step
+    endwhile
+    return l:col - a:step
+endfunction
+
+" Return the next position of the given syntax name,
+" inclusive on the given position.
+"
+" TODO: multiple lines
+"
+function! s:FindNextSyntax(lnum, col, name)
+    let l:col = a:col
+    let l:step = 1
+    while synIDattr(synID(a:lnum, l:col, 1), 'name') !=# a:name
+        let l:col += l:step
+    endwhile
+    return [a:lnum, l:col]
+endfunction
+
+function! s:FindCornersOfSyntax(lnum, col)
+    return [<sid>FindLeftOfSyntax(a:lnum, a:col), <sid>FindRightOfSyntax(a:lnum, a:col)]
+endfunction
+
+function! s:FindRightOfSyntax(lnum, col)
+    return <sid>FindCornerOfSyntax(a:lnum, a:col, 1)
+endfunction
+
+function! s:FindLeftOfSyntax(lnum, col)
+    return <sid>FindCornerOfSyntax(a:lnum, a:col, -1)
+endfunction
+
+" Returns:
+"
+" - a string with the the URL for the link under the cursor
+" - an empty string if the cursor is not on a link
+"
+" TODO
+"
+" - multiline support
+" - give an error if the separator does is not on a link
+"
+function! s:Markdown_GetUrlForPosition(lnum, col)
+    let l:lnum = a:lnum
+    let l:col = a:col
+    let l:syn = synIDattr(synID(l:lnum, l:col, 1), 'name')
+
+    if l:syn ==# 'mkdInlineURL' || l:syn ==# 'mkdURL' || l:syn ==# 'mkdLinkDefTarget'
+        " Do nothing.
+    elseif l:syn ==# 'mkdLink'
+        let [l:lnum, l:col] = <sid>FindNextSyntax(l:lnum, l:col, 'mkdURL')
+        let l:syn = 'mkdURL'
+    elseif l:syn ==# 'mkdDelimiter'
+        let l:line = getline(l:lnum)
+        let l:char = l:line[col - 1]
+        if l:char ==# '<'
+            let l:col += 1
+        elseif l:char ==# '>' || l:char ==# ')'
+            let l:col -= 1
+        elseif l:char ==# '[' || l:char ==# ']' || l:char ==# '('
+            let [l:lnum, l:col] = <sid>FindNextSyntax(l:lnum, l:col, 'mkdURL')
+        else
+            return ''
+        endif
+    else
+        return ''
+    endif
+
+    let [l:left, l:right] = <sid>FindCornersOfSyntax(l:lnum, l:col)
+    return getline(l:lnum)[l:left - 1 : l:right - 1]
+endfunction
+
+" Front end for GetUrlForPosition.
+"
+function! s:OpenUrlUnderCursor()
+    let l:url = s:Markdown_GetUrlForPosition(line('.'), col('.'))
+    if l:url != ''
+        call s:VersionAwareNetrwBrowseX(l:url)
+    else
+        echomsg 'The cursor is not on a link.'
+    endif
+endfunction
+
+" We need a definition guard because we invoke 'edit' which will reload this
+" script while this function is running. We must not replace it.
+if !exists('*s:EditUrlUnderCursor')
+    function s:EditUrlUnderCursor()
+        let l:url = s:Markdown_GetUrlForPosition(line('.'), col('.'))
+        if l:url != ''
+            if get(g:, 'vim_markdown_autowrite', 0)
+                write
+            endif
+            let l:anchor = ''
+            if get(g:, 'vim_markdown_follow_anchor', 0)
+                let l:parts = split(l:url, '#', 1)
+                if len(l:parts) == 2
+                    let [l:url, l:anchor] = parts
+                    let l:anchorexpr = get(g:, 'vim_markdown_anchorexpr', '')
+                    if l:anchorexpr != ''
+                        let l:anchor = eval(substitute(
+                            \ l:anchorexpr, 'v:anchor',
+                            \ escape('"'.l:anchor.'"', '"'), ''))
+                    endif
+                endif
+            endif
+            if l:url != ''
+                let l:ext = ''
+                if get(g:, 'vim_markdown_no_extensions_in_markdown', 0)
+                    " use another file extension if preferred
+                    if exists('g:vim_markdown_auto_extension_ext')
+                        let l:ext = '.'.g:vim_markdown_auto_extension_ext
+                    else
+                        let l:ext = '.md'
+                    endif
+                endif
+                let l:url = fnameescape(fnamemodify(expand('%:h').'/'.l:url.l:ext, ':.'))
+                let l:editmethod = ''
+                " determine how to open the linked file (split, tab, etc)
+                if exists('g:vim_markdown_edit_url_in')
+                  if g:vim_markdown_edit_url_in == 'tab'
+                    let l:editmethod = 'tabnew'
+                  elseif g:vim_markdown_edit_url_in == 'vsplit'
+                    let l:editmethod = 'vsp'
+                  elseif g:vim_markdown_edit_url_in == 'hsplit'
+                    let l:editmethod = 'sp'
+                  else
+                    let l:editmethod = 'edit'
+                  endif
+                else
+                  " default to current buffer
+                  let l:editmethod = 'edit'
+                endif
+                execute l:editmethod l:url
+            endif
+            if l:anchor != ''
+                silent! execute '/'.l:anchor
+            endif
+        else
+            echomsg 'The cursor is not on a link.'
+        endif
+    endfunction
+endif
+
+function! s:VersionAwareNetrwBrowseX(url)
+    if has('patch-7.4.567')
+        call netrw#BrowseX(a:url, 0)
+    else
+        call netrw#NetrwBrowseX(a:url, 0)
+    endif
+endf
+
+function! s:MapNotHasmapto(lhs, rhs)
+    if !hasmapto('<Plug>' . a:rhs)
+        execute 'nmap <buffer>' . a:lhs . ' <Plug>' . a:rhs
+        execute 'vmap <buffer>' . a:lhs . ' <Plug>' . a:rhs
+    endif
+endfunction
+
+call <sid>MapNormVis('<Plug>Markdown_MoveToNextHeader', '<sid>MoveToNextHeader')
+call <sid>MapNormVis('<Plug>Markdown_MoveToPreviousHeader', '<sid>MoveToPreviousHeader')
+call <sid>MapNormVis('<Plug>Markdown_MoveToNextSiblingHeader', '<sid>MoveToNextSiblingHeader')
+call <sid>MapNormVis('<Plug>Markdown_MoveToPreviousSiblingHeader', '<sid>MoveToPreviousSiblingHeader')
+call <sid>MapNormVis('<Plug>Markdown_MoveToParentHeader', '<sid>MoveToParentHeader')
+call <sid>MapNormVis('<Plug>Markdown_MoveToCurHeader', '<sid>MoveToCurHeader')
+nnoremap <Plug>Markdown_OpenUrlUnderCursor :call <sid>OpenUrlUnderCursor()<cr>
+nnoremap <Plug>Markdown_EditUrlUnderCursor :call <sid>EditUrlUnderCursor()<cr>
+
+if !get(g:, 'vim_markdown_no_default_key_mappings', 0)
+    call <sid>MapNotHasmapto(']]', 'Markdown_MoveToNextHeader')
+    call <sid>MapNotHasmapto('[[', 'Markdown_MoveToPreviousHeader')
+    call <sid>MapNotHasmapto('][', 'Markdown_MoveToNextSiblingHeader')
+    call <sid>MapNotHasmapto('[]', 'Markdown_MoveToPreviousSiblingHeader')
+    call <sid>MapNotHasmapto(']u', 'Markdown_MoveToParentHeader')
+    call <sid>MapNotHasmapto(']c', 'Markdown_MoveToCurHeader')
+    call <sid>MapNotHasmapto('gx', 'Markdown_OpenUrlUnderCursor')
+    call <sid>MapNotHasmapto('ge', 'Markdown_EditUrlUnderCursor')
+endif
+
+command! -buffer -range=% HeaderDecrease call s:HeaderDecrease(<line1>, <line2>)
+command! -buffer -range=% HeaderIncrease call s:HeaderDecrease(<line1>, <line2>, 1)
+command! -buffer -range=% SetexToAtx call s:SetexToAtx(<line1>, <line2>)
+command! -buffer TableFormat call s:TableFormat()
+command! -buffer Toc call s:Toc()
+command! -buffer Toch call s:Toc('horizontal')
+command! -buffer Tocv call s:Toc('vertical')
+command! -buffer Toct call s:Toc('tab')
+
+" Heavily based on vim-notes - http://peterodding.com/code/vim/notes/
+if exists('g:vim_markdown_fenced_languages')
+    let s:filetype_dict = {}
+    for s:filetype in g:vim_markdown_fenced_languages
+        let key = matchstr(s:filetype, "[^=]*")
+        let val = matchstr(s:filetype, "[^=]*$")
+        let s:filetype_dict[key] = val
+    endfor
+else
+    let s:filetype_dict = {
+        \ 'c++': 'cpp',
+        \ 'viml': 'vim',
+        \ 'bash': 'sh',
+        \ 'ini': 'dosini'
+    \ }
+endif
+
+function! s:MarkdownHighlightSources(force)
+    " Syntax highlight source code embedded in notes.
+    " Look for code blocks in the current file
+    let filetypes = {}
+    for line in getline(1, '$')
+        let ft = matchstr(line, '```\s*\zs[0-9A-Za-z_+-]*')
+        if !empty(ft) && ft !~ '^\d*$' | let filetypes[ft] = 1 | endif
+    endfor
+    if !exists('b:mkd_known_filetypes')
+        let b:mkd_known_filetypes = {}
+    endif
+    if !exists('b:mkd_included_filetypes')
+        " set syntax file name included
+        let b:mkd_included_filetypes = {}
+    endif
+    if !a:force && (b:mkd_known_filetypes == filetypes || empty(filetypes))
+        return
+    endif
+
+    " Now we're ready to actually highlight the code blocks.
+    let startgroup = 'mkdCodeStart'
+    let endgroup = 'mkdCodeEnd'
+    for ft in keys(filetypes)
+        if a:force || !has_key(b:mkd_known_filetypes, ft)
+            if has_key(s:filetype_dict, ft)
+                let filetype = s:filetype_dict[ft]
+            else
+                let filetype = ft
+            endif
+            let group = 'mkdSnippet' . toupper(substitute(filetype, "[+-]", "_", "g"))
+            if !has_key(b:mkd_included_filetypes, filetype)
+                let include = s:SyntaxInclude(filetype)
+                let b:mkd_included_filetypes[filetype] = 1
+            else
+                let include = '@' . toupper(filetype)
+            endif
+            let command = 'syntax region %s matchgroup=%s start="^\s*```\s*%s$" matchgroup=%s end="\s*```$" keepend contains=%s%s'
+            execute printf(command, group, startgroup, ft, endgroup, include, has('conceal') && get(g:, 'vim_markdown_conceal', 1) && get(g:, 'vim_markdown_conceal_code_blocks', 1) ? ' concealends' : '')
+            execute printf('syntax cluster mkdNonListItem add=%s', group)
+
+            let b:mkd_known_filetypes[ft] = 1
+        endif
+    endfor
+endfunction
+
+function! s:SyntaxInclude(filetype)
+    " Include the syntax highlighting of another {filetype}.
+    let grouplistname = '@' . toupper(a:filetype)
+    " Unset the name of the current syntax while including the other syntax
+    " because some syntax scripts do nothing when "b:current_syntax" is set
+    if exists('b:current_syntax')
+        let syntax_save = b:current_syntax
+        unlet b:current_syntax
+    endif
+    try
+        execute 'syntax include' grouplistname 'syntax/' . a:filetype . '.vim'
+        execute 'syntax include' grouplistname 'after/syntax/' . a:filetype . '.vim'
+    catch /E484/
+        " Ignore missing scripts
+    endtry
+    " Restore the name of the current syntax
+    if exists('syntax_save')
+        let b:current_syntax = syntax_save
+    elseif exists('b:current_syntax')
+        unlet b:current_syntax
+    endif
+    return grouplistname
+endfunction
+
+
+function! s:MarkdownRefreshSyntax(force)
+    if &filetype =~ 'markdown' && line('$') > 1
+        call s:MarkdownHighlightSources(a:force)
+    endif
+endfunction
+
+function! s:MarkdownClearSyntaxVariables()
+    if &filetype =~ 'markdown'
+        unlet! b:mkd_included_filetypes
+    endif
+endfunction
+
+augroup Mkd
+    " These autocmd calling s:MarkdownRefreshSyntax need to be kept in sync with
+    " the autocmds calling s:MarkdownSetupFolding in after/ftplugin/markdown.vim.
+    autocmd! * <buffer>
+    autocmd BufWinEnter <buffer> call s:MarkdownRefreshSyntax(1)
+    autocmd BufUnload <buffer> call s:MarkdownClearSyntaxVariables()
+    autocmd BufWritePost <buffer> call s:MarkdownRefreshSyntax(0)
+    autocmd InsertEnter,InsertLeave <buffer> call s:MarkdownRefreshSyntax(0)
+    autocmd CursorHold,CursorHoldI <buffer> call s:MarkdownRefreshSyntax(0)
+augroup END
+
+endif

ftplugin/vlang.vim

@@ -0,0 +1,6 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'v') == -1
+
+setlocal commentstring=//\ %s
+setlocal makeprg=v\ %
+
+endif

indent/vlang.vim

@@ -0,0 +1,69 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'v') == -1
+
+" Based on the Go identation file.
+"
+" Copyright 2011 The Go Authors. All rights reserved.
+" Use of this source code is governed by a BSD-style
+" license that can be found in the LICENSE file.
+
+if exists("b:did_indent")
+  finish
+endif
+let b:did_indent = 1
+
+setlocal nolisp
+setlocal autoindent
+setlocal indentexpr=VlangIndent(v:lnum)
+setlocal indentkeys+=<:>,0=},0=)
+
+if exists("*VlangIndent")
+  finish
+endif
+
+let s:cpo_save = &cpo
+set cpo&vim
+
+function! VlangIndent(lnum) abort
+  let prevlnum = prevnonblank(a:lnum-1)
+  if prevlnum == 0
+    return 0
+  endif
+
+  let prevl = substitute(getline(prevlnum), '//.*$', '', '')
+  let thisl = substitute(getline(a:lnum), '//.*$', '', '')
+  let previ = indent(prevlnum)
+
+  let ind = previ
+
+  if prevl =~ '[({]\s*$'
+    " previous line opened a block
+    let ind += shiftwidth()
+  endif
+  if prevl =~# '^\s*\(case .*\|default\):$'
+    " previous line is part of a switch statement
+    let ind += shiftwidth()
+  endif
+
+  if thisl =~ '^\s*[)}]'
+    " this line closed a block
+    let ind -= shiftwidth()
+  endif
+
+  " Colons are tricky.
+  " We want to outdent if it's part of a switch ("case foo:" or "default:").
+  " We ignore trying to deal with jump labels because (a) they're rare, and
+  " (b) they're hard to disambiguate from a composite literal key.
+  if thisl =~# '^\s*\(case .*\|default\):$'
+    let ind -= shiftwidth()
+  endif
+
+  return ind
+endfunction
+
+" restore Vi compatibility settings
+let &cpo = s:cpo_save
+unlet s:cpo_save
+
+" vim: sw=2 ts=2 et
+
+endif

syntax/vlang.vim

@@ -0,0 +1,268 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'v') == -1
+
+" Vim syntax file
+" Language:	V
+" Maintainer:	Oliver Kelton (https://github.com/ollykel)
+" Last Change:	2019 Jun 13
+" NOTE: largely based on go.vim, maintained by David Barnett
+"       see David Barnett (https://github.com/google/vim-ft-go)
+" Options:
+"   There are some options for customizing the highlighting; the recommended
+"   settings are the default values, but you can write:
+"     let OPTION_NAME = 0
+"   in your ~/.vimrc file to disable particular options. You can also write:
+"     let OPTION_NAME = 1
+"   to enable particular options. At present, all options default to on.
+"
+"   - g:v_highlight_array_whitespace_error
+"     Highlights white space after "[]".
+"   - g:v_highlight_chan_whitespace_error
+"     Highlights white space around the communications operator that don't
+"     follow the standard style.
+"     Highlights commonly used library types (io.Reader, etc.).
+"   - g:v_highlight_space_tab_error
+"     Highlights instances of tabs following spaces.
+"   - g:v_highlight_trailing_whitespace_error
+"     Highlights trailing white space.
+
+" Quit when a (custom) syntax file was already loaded
+if exists('b:current_syntax')
+  finish
+endif
+
+if !exists('g:v_highlight_array_whitespace_error')
+  let g:v_highlight_array_whitespace_error = 1
+endif
+if !exists('g:v_highlight_chan_whitespace_error')
+  let g:v_highlight_chan_whitespace_error = 1
+endif
+if !exists('g:v_highlight_space_tab_error')
+  let g:v_highlight_space_tab_error = 1
+endif
+if !exists('g:v_highlight_trailing_whitespace_error')
+  let g:v_highlight_trailing_whitespace_error = 1
+endif
+if !exists('g:v_highlight_function_calls')
+  let g:v_highlight_function_calls = 1
+endif
+if !exists('g:v_highlight_fields')
+  let g:v_highlight_fields = 1
+endif
+
+syn case match
+
+syn match    	vDeclType          "\<\(struct\|interface\)\>"
+
+syn keyword    	vDirective         module import
+syn keyword    	vDeclaration       pub mut const type enum
+syn region	    vIncluded	display contained start=+"+ skip=+\\\\\|\\"+ end=+"+
+syn match	    vIncluded	display contained "<[^>]*>"
+syn match	    vFlagDefinition display contained "\s\i[^\n]*"
+syn match	    vInclude	display "^\s*\zs\(%:\|#\)\s*include\>\s*["<]" contains=vIncluded
+syn match	    vFlag   	display "^\s*\zs\(%:\|#\)\s*flag\>\s*[^\n]*" contains=vFlagDefinition
+syn region      vShebang    display start=/^#!/ end=/$/
+
+hi def link    	vDirective         Statement
+hi def link    	vDeclaration       Keyword
+hi def link    	vDeclType          Keyword
+hi def link     vInclude          Include
+hi def link     vFlag             Include
+hi def link     vIncluded	      vString
+hi def link     vFlagDefinition	  vString
+hi def link     vShebang          Include
+
+" Keywords within functions
+syn keyword    	vStatement         defer go goto return break continue fallthrough
+syn keyword    	vConditional       if else switch match or
+syn keyword    	vLabel             case default
+syn keyword    	vRepeat            for in
+syn match       vCodeGen           /$if\>/
+syn match       vCodeGen           /\.fields\>/
+syn match       vCodeGen           /\.$\i*\>/
+
+hi def link    	vStatement         Statement
+hi def link    	vConditional       Conditional
+hi def link    	vLabel             Label
+hi def link    	vRepeat            Repeat
+hi def link     vCodeGen           Identifier
+
+" Predefined types
+syn keyword    	vType              chan map bool string error voidptr
+syn keyword    	vSignedInts        int i8 i16 i32 i64 rune intptr
+syn keyword    	vUnsignedInts      byte uint u8 u16 u32 u64 byteptr
+syn keyword    	vFloats            f32 f64 floatptr
+syn keyword    	vComplexes         complex64 complex128
+
+hi def link    	vType              Type
+hi def link    	vSignedInts        Type
+hi def link    	vUnsignedInts      Type
+hi def link    	vFloats            Type
+hi def link    	vComplexes         Type
+
+" Treat fn specially: it's a declaration at the start of a line, but a type
+" elsewhere. Order matters here.
+" syn match      	vType              /\<fn\>/
+syn match      	vDeclaration       /\<fn\>/
+syn match      	vDeclaration       contained /\<fn\>/
+
+" Predefined functions and values
+syn keyword    	vBuiltins          assert C cap complex copy delete exit imag
+syn keyword    	vBuiltins          print println eprint eprintln print_backtrace  
+syn keyword    	vBuiltins          float_calloc ok memdup range_int real recover
+syn keyword    	vBuiltins          malloc byte_calloc float_calloc
+syn keyword    	vBuiltins          isok isnil panic on_panic
+syn keyword    	vConstants         iota true false
+syn match	    vBuiltins          /\<json\.\(encode\|decode\)\>/
+
+hi def link    	vBuiltins          Keyword
+hi def link    	vConstants         Keyword
+
+" Comments; their contents
+syn keyword    	vTodo              contained TODO FIXME XXX BUG
+syn cluster    	vCommentGroup      contains=vTodo
+syn region     	vComment           start="/\*" end="\*/" contains=@vCommentGroup,@Spell
+syn region     	vComment           start="//" end="$" contains=@vCommentGroup,@Spell
+
+hi def link    	vComment           Comment
+hi def link    	vTodo              Todo
+
+" Go escapes
+syn match      	vEscapeOctal       display contained "\\[0-7]\{3}"
+syn match       vEscapeVar         display contained "\$[0-9A-Za-z\.]*"
+syn match       vEscapeVar         display contained "\${[^}]*}"
+syn match      	vEscapeC           display contained +\\[abfnrtv\\'"]+
+syn match      	vEscapeX           display contained "\\x\x\{2}"
+syn match      	vEscapeU           display contained "\\u\x\{4}"
+syn match      	vEscapeBigU        display contained "\\U\x\{8}"
+syn match      	vEscapeError       display contained +\\[^0-7xuUabfnrtv\\'"]+
+
+hi def link    	vEscapeOctal      	vSpecialString
+hi def link     vEscapeVar          vSpecialString
+hi def link    	vEscapeC          	vSpecialString
+hi def link    	vEscapeX          	vSpecialString
+hi def link    	vEscapeU          	vSpecialString
+hi def link    	vEscapeBigU       	vSpecialString
+hi def link    	vSpecialString     Special
+hi def link    	vEscapeError       Error
+
+" Strings and their contents
+syn cluster    	vStringGroup       contains=vEscapeOctal,vEscapeVar,vEscapeC,vEscapeX,vEscapeU,vEscapeBigU,vEscapeError
+syn region     	vString            start=+"+ skip=+\\\\\|\\'+ end=+"+ contains=@vStringGroup
+syn region     	vRawString         start=+`+ end=+`+
+
+hi def link    	vString            String
+hi def link    	vRawString         String
+
+" Characters; their contents
+syn cluster    	vCharacterGroup    contains=vEscapeOctal,vEscapeC,vEscapeVar,vEscapeX,vEscapeU,vEscapeBigU
+syn region     	vCharacter         start=+'+ skip=+\\\\\|\\'+ end=+'+ contains=@vCharacterGroup
+
+hi def link    	vCharacter         Character
+
+" Regions
+syn region     	vBlock             start="{" end="}" transparent fold
+syn region     	vParen             start='(' end=')' transparent
+
+" Integers
+syn match      	vDecimalInt        "\<\d\+\([Ee]\d\+\)\?\>"
+syn match      	vHexadecimalInt    "\<0x\x\+\>"
+syn match      	vOctalInt          "\<0\o\+\>"
+syn match      	vOctalError        "\<0\o*[89]\d*\>"
+
+hi def link    	vDecimalInt        Integer
+hi def link    	vHexadecimalInt    Integer
+hi def link    	vOctalInt          Integer
+hi def link     Integer             Number
+
+" Floating point
+syn match      	vFloat             "\<\d\+\.\d*\([Ee][-+]\d\+\)\?\>"
+syn match      	vFloat             "\<\.\d\+\([Ee][-+]\d\+\)\?\>"
+syn match      	vFloat             "\<\d\+[Ee][-+]\d\+\>"
+
+hi def link    	vFloat             Float
+
+" Imaginary literals
+syn match      	vImaginary         "\<\d\+i\>"
+syn match      	vImaginary         "\<\d\+\.\d*\([Ee][-+]\d\+\)\?i\>"
+syn match      	vImaginary         "\<\.\d\+\([Ee][-+]\d\+\)\?i\>"
+syn match      	vImaginary         "\<\d\+[Ee][-+]\d\+i\>"
+
+hi def link    	vImaginary         Number
+
+" Generics
+syn match     vGenericBrackets     display contained "[<>]"
+syn match     vInterfaceDeclaration  display "\s*\zsinterface\s*\i*\s*<[^>]*>" contains=vDeclType,vGenericBrackets
+syn match     vStructDeclaration  display "\s*\zsstruct\s*\i*\s*<[^>]*>" contains=vDeclType,vGenericBrackets
+" vFunctionName only appears when v_highlight_function_calls set
+syn match     vFuncDeclaration  display "\s*\zsfn\s*\i*\s*<[^>]*>" contains=vFunctionName,vDeclaration,vGenericBrackets
+
+hi def link     vGenericBrackets  Identifier
+
+" Spaces after "[]"
+if	v_highlight_array_whitespace_error != 0
+  syn match	vSpaceError display "\(\[\]\)\@<=\s\+"
+endif
+
+" Spacing errors around the 'chan' keyword
+if	v_highlight_chan_whitespace_error != 0
+  " receive-only annotation on chan type
+  syn match	vSpaceError display "\(<-\)\@<=\s\+\(chan\>\)\@="
+  " send-only annotation on chan type
+  syn match	vSpaceError display "\(\<chan\)\@<=\s\+\(<-\)\@="
+  " value-ignoring receives in a few contexts
+  syn match	vSpaceError display "\(\(^\|[={(,;]\)\s*<-\)\@<=\s\+"
+endif
+
+" Space-tab error
+if	v_highlight_space_tab_error != 0
+  syn match	vSpaceError display " \+\t"me=e-1
+endif
+
+" Trailing white space error
+if	v_highlight_trailing_whitespace_error != 0
+  syn match	vSpaceError display excludenl "\s\+$"
+endif
+
+hi def link    	vSpaceError        Error
+
+" Function calls and Fields are from: https://github.com/fatih/vim-go/blob/master/syntax/go.vim
+" Function calls;
+if v_highlight_function_calls
+  syn match vFunctionCall      /\w\+\ze\s*(/ contains=vBuiltins,vDeclaration
+  syn match vFunctionName     display contained /\s\w\+/
+  hi def link   vFunctionName      Special
+endif
+
+hi def link     vFunctionCall      Special
+
+" Fields;
+if v_highlight_fields
+  " 1. Match a sequence of word characters coming after a '.'
+  " 2. Require the following but dont match it: ( \@= see :h E59)
+  "    - The symbols: / - + * %   OR
+  "    - The symbols: [] {} <> )  OR
+  "    - The symbols: \n \r space OR
+  "    - The symbols: , : .
+  " 3. Have the start of highlight (hs) be the start of matched
+  "    pattern (s) offsetted one to the right (+1) (see :h E401)
+  syn match       vField   /\.\w\+\
+        \%(\%([\/\-\+*%]\)\|\
+        \%([\[\]{}<\>\)]\)\|\
+        \%([\!=\^|&]\)\|\
+        \%([\n\r\ ]\)\|\
+        \%([,\:.]\)\)\@=/hs=s+1
+endif
+hi def link    vField              Identifier
+
+" Search backwards for a global declaration to start processing the syntax.
+"syn sync match	vSync grouphere NONE /^\(const\|var\|type\|func\)\>/
+
+" There's a bug in the implementation of grouphere. For now, use the
+" following as a more expensive/less precise workaround.
+syn sync minlines=500
+
+let b:current_syntax = 'vlang'
+
+" vim: sw=2 sts=2 et
+
+endif