From 5cdf3c2ac184282f8ab72114dbd0bd81bdf87490 Mon Sep 17 00:00:00 2001
From: Eric Davis <edavis@insanum.com>
Date: Sat, 18 Apr 2020 18:46:21 -0700
Subject: [PATCH 1/3] Added the following formula functions:   - Min: get the
 lowest value   - Max: get the highest value   - CountE: count the number of
 empty cells   - CountNE: count the number of non-empty cells   - PercentE:
 percent of empty cells   - PercentNE: percent of non-empty cells   -
 AverageNE: average over non-empty cells

Also added a subtle tweak that ignores an HTML comment tag ('<!--')
found between the table and the starting formula line. Being able to
wrap all the formula lines with an HTML comment prevents the formulas
from being rendered in Markdown/ReST output.
---
 autoload/tablemode/spreadsheet.vim         | 118 +++++++++++++++++++++
 autoload/tablemode/spreadsheet/formula.vim |  37 +++++++
 doc/table-mode.txt                         |   7 +-
 3 files changed, 160 insertions(+), 2 deletions(-)

diff --git a/autoload/tablemode/spreadsheet.vim b/autoload/tablemode/spreadsheet.vim
index f617809..005272e 100644
--- a/autoload/tablemode/spreadsheet.vim
+++ b/autoload/tablemode/spreadsheet.vim
@@ -1,4 +1,76 @@
 " Private Functions {{{1
+function! s:Min(list) "{{{2
+  let result = v:null
+  for item in a:list
+    if empty(item)
+      continue
+    endif
+    if type(item) == type(1) || type(item) == type(1.0)
+      if result == v:null || item < result
+        let result = item
+      endif
+    elseif type(item) == type('')
+      let val = str2float(item)
+      if result == v:null || val < result
+        let result = val
+      endif
+    elseif type(item) == type([])
+      let val = s:Sum(item)
+      if result == v:null || val < result
+        let result = val
+      endif
+    endif
+  endfor
+  return result == v:null ? 0 : result
+endfunction
+
+function! s:Max(list) "{{{2
+  let result = v:null
+  for item in a:list
+    if empty(item)
+      continue
+    endif
+    if type(item) == type(1) || type(item) == type(1.0)
+      if result == v:null || item > result
+        let result = item
+      endif
+    elseif type(item) == type('')
+      let val = str2float(item)
+      if result == v:null || val > result
+        let result = val
+      endif
+    elseif type(item) == type([])
+      let val = s:Sum(item)
+      if result == v:null || val > result
+        let result = val
+      endif
+    endif
+  endfor
+  return result == v:null ? 0 : result
+endfunction
+
+function! s:CountE(list) "{{{2
+  let result = 0
+  for item in a:list
+    if empty(item)
+      let result += 1
+    endif
+  endfor
+  return result
+endfunction
+
+function! s:CountNE(list) "{{{2
+  return len(a:list)-s:CountE(a:list)
+endfunction
+
+function! s:PercentE(list) "{{{2
+  return (s:CountE(a:list)*100)/len(a:list)
+endfunction
+
+function! s:PercentNE(list) "{{{2
+  return (s:CountNE(a:list)*100)/len(a:list)
+endfunction
+
 function! s:Sum(list) "{{{2
   let result = 0.0
   for item in a:list
@@ -17,6 +89,10 @@ function! s:Average(list) "{{{2
   return s:Sum(a:list)/len(a:list)
 endfunction
 
+function! s:AverageNE(list) "{{{2
+  return s:Sum(a:list)/s:CountNE(a:list)
+endfunction
+
 " Public Functions {{{1
 function! tablemode#spreadsheet#GetFirstRow(line) "{{{2
   if tablemode#table#IsRow(a:line)
@@ -244,6 +320,42 @@ function! tablemode#spreadsheet#InsertColumn(after) "{{{2
   endif
 endfunction
 
+function! tablemode#spreadsheet#Min(range, ...) abort "{{{2
+  let args = copy(a:000)
+  call insert(args, a:range)
+  return s:Min(call('tablemode#spreadsheet#cell#GetCellRange', args))
+endfunction
+
+function! tablemode#spreadsheet#Max(range, ...) abort "{{{2
+  let args = copy(a:000)
+  call insert(args, a:range)
+  return s:Max(call('tablemode#spreadsheet#cell#GetCellRange', args))
+endfunction
+
+function! tablemode#spreadsheet#CountE(range, ...) abort "{{{2
+  let args = copy(a:000)
+  call insert(args, a:range)
+  return s:CountE(call('tablemode#spreadsheet#cell#GetCellRange', args))
+endfunction
+
+function! tablemode#spreadsheet#CountNE(range, ...) abort "{{{2
+  let args = copy(a:000)
+  call insert(args, a:range)
+  return s:CountNE(call('tablemode#spreadsheet#cell#GetCellRange', args))
+endfunction
+
+function! tablemode#spreadsheet#PercentE(range, ...) abort "{{{2
+  let args = copy(a:000)
+  call insert(args, a:range)
+  return s:PercentE(call('tablemode#spreadsheet#cell#GetCellRange', args))
+endfunction
+
+function! tablemode#spreadsheet#PercentNE(range, ...) abort "{{{2
+  let args = copy(a:000)
+  call insert(args, a:range)
+  return s:PercentNE(call('tablemode#spreadsheet#cell#GetCellRange', args))
+endfunction
+
 function! tablemode#spreadsheet#Sum(range, ...) abort "{{{2
   let args = copy(a:000)
   call insert(args, a:range)
@@ -256,6 +368,12 @@ function! tablemode#spreadsheet#Average(range, ...) abort "{{{2
   return s:Average(call('tablemode#spreadsheet#cell#GetCellRange', args))
 endfunction
 
+function! tablemode#spreadsheet#AverageNE(range, ...) abort "{{{2
+  let args = copy(a:000)
+  call insert(args, a:range)
+  return s:AverageNE(call('tablemode#spreadsheet#cell#GetCellRange', args))
+endfunction
+
 function! tablemode#spreadsheet#Sort(bang, ...) range "{{{2
   if exists('*getcurpos')
     let col = getcurpos()[4] " curswant
diff --git a/autoload/tablemode/spreadsheet/formula.vim b/autoload/tablemode/spreadsheet/formula.vim
index cfe3337..85e840f 100644
--- a/autoload/tablemode/spreadsheet/formula.vim
+++ b/autoload/tablemode/spreadsheet/formula.vim
@@ -15,6 +15,9 @@ function! tablemode#spreadsheet#formula#Add(...) "{{{2
     let fr = '$' . row . ',' . colm . '=' . fr
     let fline = tablemode#spreadsheet#GetLastRow('.') + 1
     if tablemode#table#IsBorder(fline) | let fline += 1 | endif
+    if getline(fline) =~# '^\s*<!--' " ignore line with an HTML comment tag
+      let fline += 1
+    endif
     let cursor_pos = [line('.'), col('.')]
     if getline(fline) =~# 'tmf: '
       " Comment line correctly
@@ -55,6 +58,30 @@ function! tablemode#spreadsheet#formula#EvaluateExpr(expr, line) abort "{{{2
     let [row, colm] = [0, str2nr(cell)]
   endif
 
+  if expr =~# 'Min(.*)'
+    let expr = substitute(expr, 'Min(\([^)]*\))', 'tablemode#spreadsheet#Min("\1",'.line.','.colm.')', 'g')
+  endif
+
+  if expr =~# 'Max(.*)'
+    let expr = substitute(expr, 'Max(\([^)]*\))', 'tablemode#spreadsheet#Max("\1",'.line.','.colm.')', 'g')
+  endif
+
+  if expr =~# 'CountE(.*)'
+    let expr = substitute(expr, 'CountE(\([^)]*\))', 'tablemode#spreadsheet#CountE("\1",'.line.','.colm.')', 'g')
+  endif
+
+  if expr =~# 'CountNE(.*)'
+    let expr = substitute(expr, 'CountNE(\([^)]*\))', 'tablemode#spreadsheet#CountNE("\1",'.line.','.colm.')', 'g')
+  endif
+
+  if expr =~# 'PercentE(.*)'
+    let expr = substitute(expr, 'PercentE(\([^)]*\))', 'tablemode#spreadsheet#PercentE("\1",'.line.','.colm.')', 'g')
+  endif
+
+  if expr =~# 'PercentNE(.*)'
+    let expr = substitute(expr, 'PercentNE(\([^)]*\))', 'tablemode#spreadsheet#PercentNE("\1",'.line.','.colm.')', 'g')
+  endif
+
   if expr =~# 'Sum(.*)'
     let expr = substitute(expr, 'Sum(\([^)]*\))', 'tablemode#spreadsheet#Sum("\1",'.line.','.colm.')', 'g')
   endif
@@ -63,6 +90,10 @@ function! tablemode#spreadsheet#formula#EvaluateExpr(expr, line) abort "{{{2
     let expr = substitute(expr, 'Average(\([^)]*\))', 'tablemode#spreadsheet#Average("\1",'.line.','.colm.')', 'g')
   endif
 
+  if expr =~# 'AverageNE(.*)'
+    let expr = substitute(expr, 'AverageNE(\([^)]*\))', 'tablemode#spreadsheet#AverageNE("\1",'.line.','.colm.')', 'g')
+  endif
+
   if expr =~# '\$\-\?\d\+,\-\?\d\+'
     let expr = substitute(expr, '\$\(\-\?\d\+\),\(\-\?\d\+\)',
           \ '\=str2float(tablemode#spreadsheet#cell#GetCells(line, submatch(1), submatch(2)))', 'g')
@@ -107,6 +138,9 @@ function! tablemode#spreadsheet#formula#EvaluateFormulaLine() abort "{{{2
   if tablemode#table#IsRow('.') " We're inside the table
     let line = tablemode#spreadsheet#GetLastRow('.')
     let fline = line + 1
+    if getline(fline) =~# '^\s*<!--' " ignore line with an HTML comment tag
+      let fline += 1
+    endif
     if tablemode#table#IsBorder(fline) | let fline += 1 | endif
     while s:IsFormulaLine(fline)
       let exprs += split(matchstr(getline(fline), matchexpr), ';')
@@ -116,6 +150,9 @@ function! tablemode#spreadsheet#formula#EvaluateFormulaLine() abort "{{{2
     let fline = line('.')
     let line = line('.') - 1
     while s:IsFormulaLine(line) | let fline = line | let line -= 1 | endwhile
+    if getline(fline) =~# '^\s*<!--' " ignore line with an HTML comment tag
+      let line -= 1
+    endif
     if tablemode#table#IsBorder(line) | let line -= 1 | endif
     if tablemode#table#IsRow(line)
       " let exprs = split(matchstr(getline('.'), matchexpr), ';')
diff --git a/doc/table-mode.txt b/doc/table-mode.txt
index ae9a407..3544ec6 100644
--- a/doc/table-mode.txt
+++ b/doc/table-mode.txt
@@ -120,8 +120,11 @@ Formula Expressions :
 	The formula can be a simple mathematical expression involving cells
 	which are also defined by the same format as that of the target cell.
 	Apart from basic mathematical expressions, table mode also provides
-	special functions 'Sum' and 'Average'. Both these functions take a
-	range as input. A range can be of two forms :
+	special functions 'Min', 'Max', 'CountE' (number of empty cells),
+        'CountNE' (number of non-empty cells), 'PercentE' (percent of empty
+        cells), 'PercentNE' (percent of non-empty cells), 'Sum', 'Average',
+        and 'AverageNE' (average over non-empty cells). All these functions
+        take a range as input. A range can be of two forms :
 
 		'n:m': This represents cells in the current column from row
 		'n' through 'm'. If 'm' is negative it represents 'm' row

From f755285cf33f98f50fd16ae89a5bd413a255f3b1 Mon Sep 17 00:00:00 2001
From: Eric Davis <edavis@insanum.com>
Date: Sat, 18 Apr 2020 21:47:22 -0700
Subject: [PATCH 2/3] simplified the CountE function cleanup for HTML comment
 tag checks

---
 autoload/tablemode/spreadsheet.vim         |  8 +-------
 autoload/tablemode/spreadsheet/formula.vim | 16 +++++++---------
 2 files changed, 8 insertions(+), 16 deletions(-)

diff --git a/autoload/tablemode/spreadsheet.vim b/autoload/tablemode/spreadsheet.vim
index 005272e..8abcc94 100644
--- a/autoload/tablemode/spreadsheet.vim
+++ b/autoload/tablemode/spreadsheet.vim
@@ -50,13 +50,7 @@ function! s:Max(list) "{{{2
 endfunction
 
 function! s:CountE(list) "{{{2
-  let result = 0
-  for item in a:list
-    if empty(item)
-      let result += 1
-    endif
-  endfor
-  return result
+  return len(filter(copy(a:list), {_,l -> empty(l)}))
 endfunction
 
 function! s:CountNE(list) "{{{2
diff --git a/autoload/tablemode/spreadsheet/formula.vim b/autoload/tablemode/spreadsheet/formula.vim
index 85e840f..5d9b230 100644
--- a/autoload/tablemode/spreadsheet/formula.vim
+++ b/autoload/tablemode/spreadsheet/formula.vim
@@ -1,4 +1,8 @@
 " Private Functions {{{1
+function! s:IsHTMLComment(line) "{{{2
+  return getline(a:line) =~# '^\s*<!--'
+endfunction
+
 function! s:IsFormulaLine(line) "{{{2
   return getline(a:line) =~# 'tmf: '
 endfunction
@@ -15,9 +19,7 @@ function! tablemode#spreadsheet#formula#Add(...) "{{{2
     let fr = '$' . row . ',' . colm . '=' . fr
     let fline = tablemode#spreadsheet#GetLastRow('.') + 1
     if tablemode#table#IsBorder(fline) | let fline += 1 | endif
-    if getline(fline) =~# '^\s*<!--' " ignore line with an HTML comment tag
-      let fline += 1
-    endif
+    if s:IsHTMLComment(fline) | let fline += 1 | endif
     let cursor_pos = [line('.'), col('.')]
     if getline(fline) =~# 'tmf: '
       " Comment line correctly
@@ -138,9 +140,7 @@ function! tablemode#spreadsheet#formula#EvaluateFormulaLine() abort "{{{2
   if tablemode#table#IsRow('.') " We're inside the table
     let line = tablemode#spreadsheet#GetLastRow('.')
     let fline = line + 1
-    if getline(fline) =~# '^\s*<!--' " ignore line with an HTML comment tag
-      let fline += 1
-    endif
+    if s:IsHTMLComment(fline) | let fline += 1 | endif
     if tablemode#table#IsBorder(fline) | let fline += 1 | endif
     while s:IsFormulaLine(fline)
       let exprs += split(matchstr(getline(fline), matchexpr), ';')
@@ -150,9 +150,7 @@ function! tablemode#spreadsheet#formula#EvaluateFormulaLine() abort "{{{2
     let fline = line('.')
     let line = line('.') - 1
     while s:IsFormulaLine(line) | let fline = line | let line -= 1 | endwhile
-    if getline(fline) =~# '^\s*<!--' " ignore line with an HTML comment tag
-      let line -= 1
-    endif
+    if s:IsHTMLComment(line) | let line -= 1 | endif
     if tablemode#table#IsBorder(line) | let line -= 1 | endif
     if tablemode#table#IsRow(line)
       " let exprs = split(matchstr(getline('.'), matchexpr), ';')

From 2e5713ae6adb353776dfbe065700e1c1187e258b Mon Sep 17 00:00:00 2001
From: Eric Davis <edavis@insanum.com>
Date: Sun, 19 Apr 2020 00:20:55 -0700
Subject: [PATCH 3/3] fixed the Average function and test case when spanning
 rows/columns fixed a Vim error(E907) in Min/Max when comparing v:null to a
 float fixed CountE/CountNE/PercentE/PercentNE to support spanning
 rows/columns added test cases for all the new formula functions

---
 autoload/tablemode/spreadsheet.vim | 70 +++++++++++++++++++------
 t/fixtures/cell/counts.txt         |  3 ++
 t/spreadsheet.vim                  | 84 +++++++++++++++++++++++++++++-
 3 files changed, 139 insertions(+), 18 deletions(-)
 create mode 100644 t/fixtures/cell/counts.txt

diff --git a/autoload/tablemode/spreadsheet.vim b/autoload/tablemode/spreadsheet.vim
index 8abcc94..cea5773 100644
--- a/autoload/tablemode/spreadsheet.vim
+++ b/autoload/tablemode/spreadsheet.vim
@@ -1,68 +1,104 @@
 " Private Functions {{{1
+function! s:TotalCells(list) "{{{2
+  let result = 0
+  for item in a:list
+    if type(item) == type([])
+      let result += s:TotalCells(item)
+    else
+      let result += 1
+    endif
+  endfor
+  return result
+endfunction
+
 function! s:Min(list) "{{{2
-  let result = v:null
+  let found = v:false
+  let result = 0
   for item in a:list
     if empty(item)
       continue
     endif
     if type(item) == type(1) || type(item) == type(1.0)
-      if result == v:null || item < result
+      if found == v:false || item < result
+        let found = v:true
         let result = item
       endif
     elseif type(item) == type('')
       let val = str2float(item)
-      if result == v:null || val < result
+      if found == v:false || val < result
+        let found = v:true
         let result = val
       endif
     elseif type(item) == type([])
-      let val = s:Sum(item)
-      if result == v:null || val < result
+      let val = s:Min(item)
+      if found == v:false || val < result
+        let found = v:true
         let result = val
       endif
     endif
   endfor
-  return result == v:null ? 0 : result
+  return result
 endfunction
 
 function! s:Max(list) "{{{2
-  let result = v:null
+  let found = v:false
+  let result = 0
   for item in a:list
     if empty(item)
       continue
     endif
     if type(item) == type(1) || type(item) == type(1.0)
-      if result == v:null || item > result
+      if found == v:false || item > result
+        let found = v:true
         let result = item
       endif
     elseif type(item) == type('')
       let val = str2float(item)
-      if result == v:null || val > result
+      if found == v:false || val > result
+        let found = v:true
         let result = val
       endif
     elseif type(item) == type([])
-      let val = s:Sum(item)
-      if result == v:null || val > result
+      let val = s:Max(item)
+      if found == v:false || val > result
+        let found = v:true
         let result = val
       endif
     endif
   endfor
-  return result == v:null ? 0 : result
+  return result
 endfunction
 
 function! s:CountE(list) "{{{2
-  return len(filter(copy(a:list), {_,l -> empty(l)}))
+  let result = 0
+  for item in a:list
+    if empty(item)
+      let result += 1
+    elseif type(item) == type([])
+      let result += s:CountE(item)
+    endif
+  endfor
+  return result
 endfunction
 
 function! s:CountNE(list) "{{{2
-  return len(a:list)-s:CountE(a:list)
+  let result = 0
+  for item in a:list
+    if type(item) == type([])
+      let result += s:CountNE(item)
+    elseif !empty(item)
+      let result += 1
+    endif
+  endfor
+  return result
 endfunction
 
 function! s:PercentE(list) "{{{2
-  return (s:CountE(a:list)*100)/len(a:list)
+  return (s:CountE(a:list)*100)/s:TotalCells(a:list)
 endfunction
 
 function! s:PercentNE(list) "{{{2
-  return (s:CountNE(a:list)*100)/len(a:list)
+  return (s:CountNE(a:list)*100)/s:TotalCells(a:list)
 endfunction
 
 function! s:Sum(list) "{{{2
@@ -80,7 +116,7 @@ function! s:Sum(list) "{{{2
 endfunction
 
 function! s:Average(list) "{{{2
-  return s:Sum(a:list)/len(a:list)
+  return s:Sum(a:list)/s:TotalCells(a:list)
 endfunction
 
 function! s:AverageNE(list) "{{{2
diff --git a/t/fixtures/cell/counts.txt b/t/fixtures/cell/counts.txt
new file mode 100644
index 0000000..dd0e502
--- /dev/null
+++ b/t/fixtures/cell/counts.txt
@@ -0,0 +1,3 @@
+| 1 | 2 | 3 |
+|   | 0 |   |
+| 4 | 5 | 6 |
diff --git a/t/spreadsheet.vim b/t/spreadsheet.vim
index f119080..db8e2ff 100644
--- a/t/spreadsheet.vim
+++ b/t/spreadsheet.vim
@@ -74,11 +74,93 @@ describe 'spreadsheet'
         call cursor(1,3)
         Expect tablemode#spreadsheet#Average('1:2') == 2.0
         Expect tablemode#spreadsheet#Average('1,1:1,2') == 1.5
-        Expect tablemode#spreadsheet#Average('1,1:2,2') == 5.0
+        Expect tablemode#spreadsheet#Average('1,1:2,2') == 2.5
         call cursor(2,7)
         Expect tablemode#spreadsheet#Average('1:2') == 3.0
         Expect tablemode#spreadsheet#Average('2,1:2,2') == 3.5
       end
+
+      it 'should return the min of cell range'
+        call cursor(1,3)
+        Expect tablemode#spreadsheet#Min('1:2') == 1.0
+        Expect tablemode#spreadsheet#Min('1,1:1,2') == 1.0
+        Expect tablemode#spreadsheet#Min('1,1:2,2') == 1.0
+        call cursor(2,7)
+        Expect tablemode#spreadsheet#Min('1:2') == 2.0
+        Expect tablemode#spreadsheet#Min('2,1:2,2') == 3.0
+      end
+
+      it 'should return the max of cell range'
+        call cursor(1,3)
+        Expect tablemode#spreadsheet#Max('1:2') == 3.0
+        Expect tablemode#spreadsheet#Max('1,1:1,2') == 2.0
+        Expect tablemode#spreadsheet#Max('1,1:2,2') == 4.0
+        call cursor(2,7)
+        Expect tablemode#spreadsheet#Max('1:2') == 4.0
+        Expect tablemode#spreadsheet#Max('2,1:2,2') == 4.0
+      end
+    end
+
+    describe 'Count'
+      before
+        new
+        read t/fixtures/cell/counts.txt
+      end
+
+      it 'should return the count of empty cell range'
+        call cursor(1,3)
+        Expect tablemode#spreadsheet#CountE('1:3') == 1
+        Expect tablemode#spreadsheet#CountE('1,1:1,3') == 0
+        Expect tablemode#spreadsheet#CountE('2,1:2,3') == 2
+        Expect tablemode#spreadsheet#CountE('1,1:3,3') == 2
+        call cursor(3,11)
+        Expect tablemode#spreadsheet#CountE('1:3') == 1
+        Expect tablemode#spreadsheet#CountE('3,1:3,3') == 0
+      end
+
+      it 'should return the count of not-empty cell range'
+        call cursor(1,3)
+        Expect tablemode#spreadsheet#CountNE('1:3') == 2
+        Expect tablemode#spreadsheet#CountNE('1,1:1,3') == 3
+        Expect tablemode#spreadsheet#CountNE('2,1:2,3') == 1
+        Expect tablemode#spreadsheet#CountNE('1,1:3,3') == 7
+        call cursor(3,11)
+        Expect tablemode#spreadsheet#CountNE('1:3') == 2
+        Expect tablemode#spreadsheet#CountNE('3,1:3,3') == 3
+      end
+
+      it 'should return the percent count of empty cell range'
+        call cursor(1,3)
+        Expect tablemode#spreadsheet#PercentE('1:3') == 33
+        Expect tablemode#spreadsheet#PercentE('1,1:1,3') == 0
+        Expect tablemode#spreadsheet#PercentE('2,1:2,3') == 66
+        Expect tablemode#spreadsheet#PercentE('1,1:3,3') == 22
+        call cursor(3,11)
+        Expect tablemode#spreadsheet#PercentE('1:3') == 33
+        Expect tablemode#spreadsheet#PercentE('3,1:3,3') == 0
+      end
+
+      it 'should return the percent count of not-empty cell range'
+        call cursor(1,3)
+        Expect tablemode#spreadsheet#PercentNE('1:3') == 66
+        Expect tablemode#spreadsheet#PercentNE('1,1:1,3') == 100
+        Expect tablemode#spreadsheet#PercentNE('2,1:2,3') == 33
+        Expect tablemode#spreadsheet#PercentNE('1,1:3,3') == 77
+        call cursor(3,11)
+        Expect tablemode#spreadsheet#PercentNE('1:3') == 66
+        Expect tablemode#spreadsheet#PercentNE('3,1:3,3') == 100
+      end
+
+      it 'should return the average of not-empty cell range'
+        call cursor(1,3)
+        Expect tablemode#spreadsheet#AverageNE('1:3') == 2.5
+        Expect tablemode#spreadsheet#AverageNE('1,1:1,3') == 2.0
+        Expect tablemode#spreadsheet#AverageNE('2,1:2,3') == 0.0
+        Expect tablemode#spreadsheet#AverageNE('1,1:3,3') == 3.0
+        call cursor(3,11)
+        Expect tablemode#spreadsheet#AverageNE('1:3') == 4.5
+        Expect tablemode#spreadsheet#AverageNE('3,1:3,3') == 5.0
+      end
     end
   end