Change python syntax providers, closes #209

README.md

@@ -46,6 +46,7 @@ If you need full functionality of any plugin, please use it directly with your p
 - [c++11](https://github.com/octol/vim-cpp-enhanced-highlight) (syntax)
 - [c/c++](https://github.com/vim-jp/vim-cpp) (syntax)
 - [caddyfile](https://github.com/isobit/vim-caddyfile) (syntax, indent, ftplugin)
+- [carp](https://github.com/hellerve/carp-vim) (syntax)
 - [cjsx](https://github.com/mtscout6/vim-cjsx) (syntax, ftplugin)
 - [clojure](https://github.com/guns/vim-clojure-static) (syntax, indent, autoload, ftplugin)
 - [cmake](https://github.com/pboettch/vim-cmake-syntax) (syntax, indent)
@@ -78,12 +79,13 @@ If you need full functionality of any plugin, please use it directly with your p
 - [jasmine](https://github.com/glanotte/vim-jasmine) (syntax)
 - [javascript](https://github.com/pangloss/vim-javascript) (syntax, indent, compiler, ftplugin, extras)
 - [jenkins](https://github.com/martinda/Jenkinsfile-vim-syntax) (syntax, indent)
+- [json5](https://github.com/GutenYe/json5.vim) (syntax)
 - [json](https://github.com/elzr/vim-json) (syntax, indent, ftplugin)
 - [jst](https://github.com/briancollins/vim-jst) (syntax, indent)
 - [jsx](https://github.com/mxw/vim-jsx) (after)
 - [julia](https://github.com/JuliaEditorSupport/julia-vim) (syntax, indent, autoload, ftplugin)
 - [kotlin](https://github.com/udalov/kotlin-vim) (syntax, indent)
-- [latex](https://github.com/LaTeX-Box-Team/LaTeX-Box) ()
+- [latex](https://github.com/LaTeX-Box-Team/LaTeX-Box) (syntax, indent, ftplugin)
 - [less](https://github.com/groenewege/vim-less) (syntax, indent, ftplugin)
 - [liquid](https://github.com/tpope/vim-liquid) (syntax, indent, ftplugin)
 - [livescript](https://github.com/gkz/vim-ls) (syntax, indent, compiler, ftplugin)
@@ -108,7 +110,8 @@ If you need full functionality of any plugin, please use it directly with your p
 - [puppet](https://github.com/voxpupuli/vim-puppet) (syntax, indent, ftplugin)
 - [purescript](https://github.com/purescript-contrib/purescript-vim) (syntax, indent, ftplugin)
 - [python-compiler](https://github.com/aliev/vim-compiler-python) (compiler, autoload)
-- [python](https://github.com/mitsuhiko/vim-python-combined) (syntax, indent)
+- [python-ident](https://github.com/Vimjas/vim-python-pep8-indent) (indent)
+- [python](https://github.com/vim-python/python-syntax) (syntax)
 - [qml](https://github.com/peterhoeg/vim-qml) (syntax, indent, ftplugin)
 - [r-lang](https://github.com/vim-scripts/R.vim) (syntax, ftplugin)
 - [racket](https://github.com/wlangstroth/vim-racket) (syntax, indent, autoload, ftplugin)

after/syntax/tex.vim

@@ -0,0 +1,13 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" adds support for cleverref package
+" \Cref, \cref, \cpageref, \labelcref, \labelcpageref
+syn region texRefZone		matchgroup=texStatement start="\\Cref{"				end="}\|%stopzone\>"	contains=@texRefGroup
+syn region texRefZone		matchgroup=texStatement start="\\\(label\|\)c\(page\|\)ref{"	end="}\|%stopzone\>"	contains=@texRefGroup
+
+" adds support for listings package
+syn region texZone start="\\begin{lstlisting}" end="\\end{lstlisting}\|%stopzone\>"
+syn match texInputFile  "\\lstinputlisting\s*\(\[.*\]\)\={.\{-}}" contains=texStatement,texInputCurlies,texInputFileOpt
+syn match texZone "\\lstinline\s*\(\[.*\]\)\={.\{-}}"
+
+endif

autoload/vital/crystal.vital

@@ -0,0 +1,10 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'crystal') == -1
+  
+crystal
+a977489
+
+Process
+Web.JSON
+ColorEcho
+
+endif

build

@@ -80,7 +80,7 @@ extract() {
 }
 
 copy_dir() {
-  for file in $(find "$1/$2" -name '*.vim'); do
+  for file in $(find "$1/$2" -name '*.vim' -o -name '*.vital'); do
     file_path="$(dirname "${file##$1/}")"
     mkdir -p "$file_path"
     touch "$file_path/$(basename "$file")"
@@ -118,6 +118,7 @@ PACKS="
   c++11:octol/vim-cpp-enhanced-highlight
   c/c++:vim-jp/vim-cpp
   caddyfile:isobit/vim-caddyfile
+  carp:hellerve/carp-vim
   cjsx:mtscout6/vim-cjsx
   clojure:guns/vim-clojure-static
   cmake:pboettch/vim-cmake-syntax
@@ -151,6 +152,7 @@ PACKS="
   javascript:pangloss/vim-javascript:_JAVASCRIPT
   jenkins:martinda/Jenkinsfile-vim-syntax
   json:elzr/vim-json
+  json5:GutenYe/json5.vim
   jst:briancollins/vim-jst
   jsx:mxw/vim-jsx:_ALL
   julia:JuliaEditorSupport/julia-vim
@@ -179,8 +181,9 @@ PACKS="
   pug:digitaltoad/vim-pug
   puppet:voxpupuli/vim-puppet
   purescript:purescript-contrib/purescript-vim
-  python:mitsuhiko/vim-python-combined
+  python:vim-python/python-syntax
   python-compiler:aliev/vim-compiler-python
+  python-ident:Vimjas/vim-python-pep8-indent
   qml:peterhoeg/vim-qml
   r-lang:vim-scripts/R.vim
   racket:wlangstroth/vim-racket

config.vim

@@ -13,3 +13,5 @@ let g:filetype_euphoria = 'elixir'
 augroup filetypedetect
   autocmd BufNewFile,BufReadPost *.vb setlocal filetype=vbnet
 augroup END
+
+let g:python_highlight_all = 1

ftdetect/polyglot.vim

@@ -13,6 +13,8 @@ let g:filetype_euphoria = 'elixir'
 augroup filetypedetect
   autocmd BufNewFile,BufReadPost *.vb setlocal filetype=vbnet
 augroup END
+
+let g:python_highlight_all = 1
 augroup filetypedetect
 " apiblueprint:sheerun/apiblueprint.vim
 autocmd BufReadPost,BufNewFile *.apib set filetype=apiblueprint
@@ -82,6 +84,11 @@ augroup filetypedetect
 au BufNewFile,BufRead Caddyfile set ft=caddyfile
 augroup END
 
+augroup filetypedetect
+" carp:hellerve/carp-vim
+au BufRead,BufNewFile *.carp set filetype=carp
+augroup END
+
 augroup filetypedetect
 " cjsx:mtscout6/vim-cjsx
 augroup CJSX
@@ -237,7 +244,7 @@ augroup END
 
 augroup filetypedetect
 " erlang:vim-erlang/vim-erlang-runtime
-au BufNewFile,BufRead *.erl,*.hrl,rebar.config,*.app,*.app.src,*.yaws,*.xrl set ft=erlang
+au BufNewFile,BufRead *.erl,*.hrl,rebar.config,*.app,*.app.src,*.yaws,*.xrl,*.escript set ft=erlang
 augroup END
 
 augroup filetypedetect
@@ -442,6 +449,11 @@ autocmd BufNewFile,BufRead *.geojson setlocal filetype=json
 autocmd BufNewFile,BufRead *.template setlocal filetype=json
 augroup END
 
+augroup filetypedetect
+" json5:GutenYe/json5.vim
+au BufNewFile,BufRead *.json5 setfiletype json5
+augroup END
+
 augroup filetypedetect
 " jst:briancollins/vim-jst
 au BufNewFile,BufRead *.ejs set filetype=jst
@@ -770,7 +782,7 @@ au FileType purescript let &l:commentstring='{--%s--}'
 augroup END
 
 augroup filetypedetect
-" python:mitsuhiko/vim-python-combined
+" python:vim-python/python-syntax
 augroup END
 
 augroup filetypedetect
@@ -783,6 +795,10 @@ augroup filetypedetect
 autocmd FileType python compiler python
 augroup END
 
+augroup filetypedetect
+" python-ident:Vimjas/vim-python-pep8-indent
+augroup END
+
 augroup filetypedetect
 " qml:peterhoeg/vim-qml
 autocmd BufRead,BufNewFile *.qml setfiletype qml

ftplugin/ansible.vim

@@ -4,6 +4,6 @@ if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'ansible') == -1
 if exists('+regexpengine') && ('&regexpengine' == 0)
   setlocal regexpengine=1
 endif
-set path+=./../templates,./../files
+set path+=./../templates,./../files,templates,files
 
 endif

ftplugin/latex-box/common.vim

@@ -0,0 +1,417 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" LaTeX Box common functions
+
+" Error Format {{{
+" Note: The error formats assume we're using the -file-line-error with
+"       [pdf]latex.
+" Note: See |errorformat-LaTeX| for more info.
+
+" Check for options
+if !exists("g:LatexBox_show_warnings")
+	let g:LatexBox_show_warnings=1
+endif
+if !exists("g:LatexBox_ignore_warnings")
+	let g:LatexBox_ignore_warnings =
+				\['Underfull',
+				\ 'Overfull',
+				\ 'specifier changed to']
+endif
+
+" Standard error message formats
+" Note: We consider statements that starts with "!" as errors
+setlocal efm=%E!\ LaTeX\ %trror:\ %m
+setlocal efm+=%E%f:%l:\ %m
+setlocal efm+=%E!\ %m
+
+" More info for undefined control sequences
+setlocal efm+=%Z<argument>\ %m
+
+" More info for some errors
+setlocal efm+=%Cl.%l\ %m
+
+" Show or ignore warnings
+if g:LatexBox_show_warnings
+	" Parse biblatex warnings
+	setlocal efm+=%-C(biblatex)%.%#in\ t%.%#
+	setlocal efm+=%-C(biblatex)%.%#Please\ v%.%#
+	setlocal efm+=%-C(biblatex)%.%#LaTeX\ a%.%#
+	setlocal efm+=%-Z(biblatex)%m
+
+	" Parse hyperref warnings
+	setlocal efm+=%-C(hyperref)%.%#on\ input\ line\ %l.
+
+	for w in g:LatexBox_ignore_warnings
+		let warning = escape(substitute(w, '[\,]', '%\\\\&', 'g'), ' ')
+		exe 'setlocal efm+=%-G%.%#'. warning .'%.%#'
+	endfor
+	setlocal efm+=%+WLaTeX\ %.%#Warning:\ %.%#line\ %l%.%#
+	setlocal efm+=%+W%.%#\ at\ lines\ %l--%*\\d
+	setlocal efm+=%+WLaTeX\ %.%#Warning:\ %m
+	setlocal efm+=%+W%.%#Warning:\ %m
+else
+	setlocal efm+=%-WLaTeX\ %.%#Warning:\ %.%#line\ %l%.%#
+	setlocal efm+=%-W%.%#\ at\ lines\ %l--%*\\d
+	setlocal efm+=%-WLaTeX\ %.%#Warning:\ %m
+	setlocal efm+=%-W%.%#Warning:\ %m
+endif
+
+" Push file to file stack
+setlocal efm+=%+P**%f
+setlocal efm+=%+P**\"%f\"
+
+" Ignore unmatched lines
+setlocal efm+=%-G%.%#
+" }}}
+
+" Vim Windows {{{
+
+" Type of split, "new" for horiz. "vnew" for vert.
+if !exists('g:LatexBox_split_type')
+	let g:LatexBox_split_type = "vnew"
+endif
+
+" Length of vertical splits
+if !exists('g:LatexBox_split_length')
+	let g:LatexBox_split_length = 15
+endif
+
+" Width of horizontal splits
+if !exists('g:LatexBox_split_width')
+	let g:LatexBox_split_width = 30
+endif
+
+" Where splits appear
+if !exists('g:LatexBox_split_side')
+	let g:LatexBox_split_side = "aboveleft"
+endif
+
+" Resize when split?
+if !exists('g:LatexBox_split_resize')
+	let g:LatexBox_split_resize = 0
+endif
+
+" Toggle help info
+if !exists('g:LatexBox_toc_hidehelp')
+	let g:LatexBox_toc_hidehelp = 0
+endif
+" }}}
+
+" Filename utilities {{{
+function! LatexBox_GetMainTexFile()
+
+	" 1. check for the b:main_tex_file variable
+	if exists('b:main_tex_file') && filereadable(b:main_tex_file)
+		return b:main_tex_file
+	endif
+
+
+	" 2. scan the first few lines of the file for root = filename
+	for linenum in range(1,5)
+		let linecontents = getline(linenum)
+		if linecontents =~ 'root\s*='
+			" Remove everything but the filename
+			let b:main_tex_file = substitute(linecontents,
+						\ '.*root\s*=\s*', "", "")
+			let b:main_tex_file = substitute(b:main_tex_file, '\s*$', "", "")
+			" Prepend current directory if this isn't an absolute path
+			if b:main_tex_file !~ '^/'
+				let b:main_tex_file = expand('%:p:h') . '/' . b:main_tex_file
+			endif
+			let b:main_tex_file = fnamemodify(b:main_tex_file, ":p")
+			if b:main_tex_file !~ '\.tex$'
+				let b:main_tex_file .= '.tex'
+			endif
+			return b:main_tex_file
+		endif
+	endfor
+
+	" 3. scan current file for "\begin{document}"
+	if &filetype == 'tex' && search('\m\C\\begin\_\s*{document}', 'nw') != 0
+		return expand('%:p')
+	endif
+
+	" 4. use 'main.tex' if it exists in the same directory (and is readable)
+	let s:main_dot_tex_file=expand('%:p:h') . '/main.tex'
+	if filereadable(s:main_dot_tex_file)
+		let b:main_tex_file=s:main_dot_tex_file
+		return b:main_tex_file
+	endif
+
+	" 5. borrow the Vim-Latex-Suite method of finding it
+	if LatexBox_GetMainFileName() != expand('%:p')
+		let b:main_tex_file = LatexBox_GetMainFileName()
+		return b:main_tex_file
+	endif
+
+	" 6. prompt for file with completion
+	let b:main_tex_file = s:PromptForMainFile()
+	return b:main_tex_file
+endfunction
+
+function! s:PromptForMainFile()
+	let saved_dir = getcwd()
+	execute 'cd ' . fnameescape(expand('%:p:h'))
+
+	" Prompt for file
+	let l:file = ''
+	while !filereadable(l:file)
+		let l:file = input('main LaTeX file: ', '', 'file')
+		if l:file !~ '\.tex$'
+			let l:file .= '.tex'
+		endif
+	endwhile
+	let l:file = fnamemodify(l:file, ':p')
+
+	" Make persistent
+	let l:persistent = ''
+	while l:persistent !~ '\v^(y|n)'
+		let l:persistent = input('make choice persistent? (y, n) ')
+		if l:persistent == 'y'
+			call writefile([], l:file . '.latexmain')
+		endif
+	endwhile
+
+	execute 'cd ' . fnameescape(saved_dir)
+	return l:file
+endfunction
+
+" Return the directory of the main tex file
+function! LatexBox_GetTexRoot()
+	return fnamemodify(LatexBox_GetMainTexFile(), ':h')
+endfunction
+
+function! LatexBox_GetBuildBasename(with_dir)
+	" 1. Check for g:LatexBox_jobname
+	if exists('g:LatexBox_jobname')
+		return g:LatexBox_jobname
+	endif
+
+	" 2. Get the basename from the main tex file
+	if a:with_dir
+		return fnamemodify(LatexBox_GetMainTexFile(), ':r')
+	else
+		return fnamemodify(LatexBox_GetMainTexFile(), ':t:r')
+	endif
+endfunction
+
+function! LatexBox_GetAuxFile()
+	" 1. check for b:build_dir variable
+	if exists('b:build_dir') && isdirectory(b:build_dir)
+		return b:build_dir . '/' . LatexBox_GetBuildBasename(0) . '.aux'
+	endif
+
+	" 2. check for g:LatexBox_build_dir variable
+	if exists('g:LatexBox_build_dir') && isdirectory(g:LatexBox_build_dir)
+		return g:LatexBox_build_dir . '/' . LatexBox_GetBuildBasename(0) . '.aux'
+	endif
+
+	" 3. use the base name of main tex file
+	return LatexBox_GetBuildBasename(1) . '.aux'
+endfunction
+
+function! LatexBox_GetLogFile()
+	" 1. check for b:build_dir variable
+	if exists('b:build_dir') && isdirectory(b:build_dir)
+		return b:build_dir . '/' . LatexBox_GetBuildBasename(0) . '.log'
+	endif
+
+	" 2. check for g:LatexBox_build_dir variable
+	if exists('g:LatexBox_build_dir') && isdirectory(g:LatexBox_build_dir)
+		return g:LatexBox_build_dir . '/' . LatexBox_GetBuildBasename(0) . '.log'
+	endif
+
+	" 3. use the base name of main tex file
+	return LatexBox_GetBuildBasename(1) . '.log'
+endfunction
+
+function! LatexBox_GetOutputFile()
+	" 1. check for b:build_dir variable
+	if exists('b:build_dir') && isdirectory(b:build_dir)
+		return b:build_dir . '/' . LatexBox_GetBuildBasename(0)
+					\ . '.' . g:LatexBox_output_type
+	endif
+
+	" 2. check for g:LatexBox_build_dir variable
+	if exists('g:LatexBox_build_dir') && isdirectory(g:LatexBox_build_dir)
+		return g:LatexBox_build_dir . '/' . LatexBox_GetBuildBasename(0)
+					\ . '.' . g:LatexBox_output_type
+	endif
+
+	" 3. use the base name of main tex file
+	return LatexBox_GetBuildBasename(1) . '.' . g:LatexBox_output_type
+endfunction
+" }}}
+
+" View Output {{{
+
+" Default pdf viewer
+if !exists('g:LatexBox_viewer')
+	" On windows, 'running' a file will open it with the default program
+	let s:viewer = ''
+	if has('unix')
+	  " echo -n necessary as uname -s will append \n otherwise
+      let s:uname = system('echo -n $(uname -s)')
+	  if s:uname == "Darwin"
+		  let s:viewer = 'open'
+	  else
+		  let s:viewer = 'xdg-open'
+	  endif
+	endif
+	let g:LatexBox_viewer = s:viewer
+endif
+
+function! LatexBox_View(...)
+	let lvargs = join(a:000, ' ')
+	let outfile = LatexBox_GetOutputFile()
+	if !filereadable(outfile)
+		echomsg fnamemodify(outfile, ':.') . ' is not readable'
+		return
+	endif
+	let cmd = g:LatexBox_viewer . ' ' . lvargs . ' ' . shellescape(outfile)
+	if has('win32')
+		let cmd = '!start /b ' . cmd . ' >nul'
+	else
+		let cmd = '!' . cmd . ' '
+		if fnamemodify(&shell, ':t') ==# 'fish'
+			let cmd .= ' >/dev/null ^/dev/null &'
+		else
+			let cmd .= ' &>/dev/null &'
+		endif
+	endif
+	silent execute cmd
+	if !has("gui_running")
+		redraw!
+	endif
+endfunction
+
+command! -nargs=* LatexView call LatexBox_View('<args>')
+" }}}
+
+" In Comment {{{
+
+" LatexBox_InComment([line], [col])
+" return true if inside comment
+function! LatexBox_InComment(...)
+	let line = a:0 >= 1 ? a:1 : line('.')
+	let col = a:0 >= 2 ? a:2 : col('.')
+	return synIDattr(synID(line, col, 0), "name") =~# '^texComment'
+endfunction
+" }}}
+
+" Get Current Environment {{{
+
+" LatexBox_GetCurrentEnvironment([with_pos])
+" Returns:
+" - environment
+"	  if with_pos is not given
+" - [envirnoment, lnum_begin, cnum_begin, lnum_end, cnum_end]
+"	  if with_pos is nonzero
+function! LatexBox_GetCurrentEnvironment(...)
+	if a:0 > 0
+		let with_pos = a:1
+	else
+		let with_pos = 0
+	endif
+
+	let begin_pat = '\C\\begin\_\s*{[^}]*}\|\\\@<!\\\[\|\\\@<!\\('
+	let end_pat = '\C\\end\_\s*{[^}]*}\|\\\@<!\\\]\|\\\@<!\\)'
+	let saved_pos = getpos('.')
+
+	" move to the left until on a backslash
+	let [bufnum, lnum, cnum, off] = getpos('.')
+	let line = getline(lnum)
+	while cnum > 1 && line[cnum - 1] != '\'
+		let cnum -= 1
+	endwhile
+	call cursor(lnum, cnum)
+
+	" match begin/end pairs but skip comments
+	let flags = 'bnW'
+	if strpart(getline('.'), col('.') - 1) =~ '^\%(' . begin_pat . '\)'
+		let flags .= 'c'
+	endif
+	let [lnum1, cnum1] = searchpairpos(begin_pat, '', end_pat, flags,
+				\ 'LatexBox_InComment()')
+
+	let env = ''
+
+	if lnum1
+		let line = strpart(getline(lnum1), cnum1 - 1)
+
+		if empty(env)
+			let env = matchstr(line, '^\C\\begin\_\s*{\zs[^}]*\ze}')
+		endif
+		if empty(env)
+			let env = matchstr(line, '^\\\[')
+		endif
+		if empty(env)
+			let env = matchstr(line, '^\\(')
+		endif
+	endif
+
+	if with_pos == 1
+		let flags = 'nW'
+		if !(lnum1 == lnum && cnum1 == cnum)
+			let flags .= 'c'
+		endif
+
+		let [lnum2, cnum2] = searchpairpos(begin_pat, '', end_pat, flags,
+					\ 'LatexBox_InComment()')
+
+		call setpos('.', saved_pos)
+		return [env, lnum1, cnum1, lnum2, cnum2]
+	else
+		call setpos('.', saved_pos)
+		return env
+	endif
+endfunction
+" }}}
+
+" Tex To Tree {{{
+" stores nested braces in a tree structure
+function! LatexBox_TexToTree(str)
+	let tree = []
+	let i1 = 0
+	let i2 = -1
+	let depth = 0
+	while i2 < len(a:str)
+		let i2 = match(a:str, '[{}]', i2 + 1)
+		if i2 < 0
+			let i2 = len(a:str)
+		endif
+		if i2 >= len(a:str) || a:str[i2] == '{'
+			if depth == 0
+				let item = substitute(strpart(a:str, i1, i2 - i1),
+							\ '^\s*\|\s*$', '', 'g')
+				if !empty(item)
+					call add(tree, item)
+				endif
+				let i1 = i2 + 1
+			endif
+			let depth += 1
+		else
+			let depth -= 1
+			if depth == 0
+				call add(tree, LatexBox_TexToTree(strpart(a:str, i1, i2 - i1)))
+				let i1 = i2 + 1
+			endif
+		endif
+	endwhile
+	return tree
+endfunction
+" }}}
+
+" Tree To Tex {{{
+function! LatexBox_TreeToTex(tree)
+	if type(a:tree) == type('')
+		return a:tree
+	else
+		return '{' . join(map(a:tree, 'LatexBox_TreeToTex(v:val)'), '') . '}'
+	endif
+endfunction
+" }}}
+
+" vim:fdm=marker:ff=unix:noet:ts=4:sw=4
+
+endif

ftplugin/latex-box/complete.vim

@@ -0,0 +1,936 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" LaTeX Box completion
+
+setlocal omnifunc=LatexBox_Complete
+
+" <SID> Wrap {{{
+function! s:GetSID()
+	return matchstr(expand('<sfile>'), '\zs<SNR>\d\+_\ze.*$')
+endfunction
+let s:SID = s:GetSID()
+function! s:SIDWrap(func)
+	return s:SID . a:func
+endfunction
+" }}}
+
+" Completion {{{
+if !exists('g:LatexBox_completion_close_braces')
+	let g:LatexBox_completion_close_braces = 1
+endif
+if !exists('g:LatexBox_bibtex_wild_spaces')
+	let g:LatexBox_bibtex_wild_spaces = 1
+endif
+
+if !exists('g:LatexBox_cite_pattern')
+	let g:LatexBox_cite_pattern = '\C\\\a*cite\a*\*\?\(\[[^\]]*\]\)*\_\s*{'
+endif
+if !exists('g:LatexBox_ref_pattern')
+	let g:LatexBox_ref_pattern = '\C\\v\?\(eq\|page\|[cC]\|labelc\|name\|auto\)\?ref\*\?\_\s*{'
+endif
+
+if !exists('g:LatexBox_completion_environments')
+	let g:LatexBox_completion_environments = [
+		\ {'word': 'itemize',		'menu': 'bullet list' },
+		\ {'word': 'enumerate',		'menu': 'numbered list' },
+		\ {'word': 'description',	'menu': 'description' },
+		\ {'word': 'center',		'menu': 'centered text' },
+		\ {'word': 'figure',		'menu': 'floating figure' },
+		\ {'word': 'table',			'menu': 'floating table' },
+		\ {'word': 'equation',		'menu': 'equation (numbered)' },
+		\ {'word': 'align',			'menu': 'aligned equations (numbered)' },
+		\ {'word': 'align*',		'menu': 'aligned equations' },
+		\ {'word': 'document' },
+		\ {'word': 'abstract' },
+		\ ]
+endif
+
+if !exists('g:LatexBox_completion_commands')
+	let g:LatexBox_completion_commands = [
+		\ {'word': '\begin{' },
+		\ {'word': '\end{' },
+		\ {'word': '\item' },
+		\ {'word': '\label{' },
+		\ {'word': '\ref{' },
+		\ {'word': '\eqref{eq:' },
+		\ {'word': '\cite{' },
+		\ {'word': '\chapter{' },
+		\ {'word': '\section{' },
+		\ {'word': '\subsection{' },
+		\ {'word': '\subsubsection{' },
+		\ {'word': '\paragraph{' },
+		\ {'word': '\nonumber' },
+		\ {'word': '\bibliography' },
+		\ {'word': '\bibliographystyle' },
+		\ ]
+endif
+
+if !exists('g:LatexBox_complete_inlineMath')
+	let g:LatexBox_complete_inlineMath = 0
+endif
+
+if !exists('g:LatexBox_eq_env_patterns')
+	let g:LatexBox_eq_env_patterns = 'equation\|gather\|multiline\|align\|flalign\|alignat\|eqnarray'
+endif
+
+" }}}
+
+"LatexBox_kpsewhich {{{
+function! LatexBox_kpsewhich(file)
+	let old_dir = getcwd()
+	execute 'lcd ' . fnameescape(LatexBox_GetTexRoot())
+	let out = system('kpsewhich "' . a:file . '"')
+
+	" If kpsewhich has found something, it returns a non-empty string with a
+	" newline at the end; otherwise the string is empty
+	if len(out)
+		" Remove the trailing newline
+		let out = fnamemodify(out[:-2], ':p')
+	endif
+
+	execute 'lcd ' . fnameescape(old_dir)
+
+	return out
+endfunction
+"}}}
+
+" Omni Completion {{{
+
+let s:completion_type = ''
+
+function! LatexBox_Complete(findstart, base)
+	if a:findstart
+		" return the starting position of the word
+		let line = getline('.')
+		let pos = col('.') - 1
+		while pos > 0 && line[pos - 1] !~ '\\\|{'
+			let pos -= 1
+		endwhile
+
+		let line_start = line[:pos-1]
+		if line_start =~ '\m\C\\begin\_\s*{$'
+			let s:completion_type = 'begin'
+		elseif line_start =~ '\m\C\\end\_\s*{$'
+			let s:completion_type = 'end'
+		elseif line_start =~ '\m' . g:LatexBox_ref_pattern . '$'
+			let s:completion_type = 'ref'
+		elseif line_start =~ '\m' . g:LatexBox_cite_pattern . '$'
+			let s:completion_type = 'bib'
+			" check for multiple citations
+			let pos = col('.') - 1
+			while pos > 0 && line[pos - 1] !~ '{\|,'
+				let pos -= 1
+			endwhile
+		elseif s:LatexBox_complete_inlineMath_or_not()
+			let s:completion_type = 'inlineMath'
+			let pos = s:eq_pos
+		else
+			let s:completion_type = 'command'
+			if line[pos - 1] == '\'
+				let pos -= 1
+			endif
+		endif
+		return pos
+	else
+		" return suggestions in an array
+		let suggestions = []
+
+		if s:completion_type == 'begin'
+			" suggest known environments
+			for entry in g:LatexBox_completion_environments
+				if entry.word =~ '^' . escape(a:base, '\')
+					if g:LatexBox_completion_close_braces && !s:NextCharsMatch('^}')
+						" add trailing '}'
+						let entry = copy(entry)
+						let entry.abbr = entry.word
+						let entry.word = entry.word . '}'
+					endif
+					call add(suggestions, entry)
+				endif
+			endfor
+		elseif s:completion_type == 'end'
+			" suggest known environments
+			let env = LatexBox_GetCurrentEnvironment()
+			if env != ''
+				if g:LatexBox_completion_close_braces && !s:NextCharsMatch('^\s*[,}]')
+					call add(suggestions, {'word': env . '}', 'abbr': env})
+				else
+					call add(suggestions, env)
+				endif
+			endif
+		elseif s:completion_type == 'command'
+			" suggest known commands
+			for entry in g:LatexBox_completion_commands
+				if entry.word =~ '^' . escape(a:base, '\')
+					" do not display trailing '{'
+					if entry.word =~ '{'
+						let entry.abbr = entry.word[0:-2]
+					endif
+					call add(suggestions, entry)
+				endif
+			endfor
+		elseif s:completion_type == 'ref'
+			let suggestions = s:CompleteLabels(a:base)
+		elseif s:completion_type == 'bib'
+			" suggest BibTeX entries
+			let suggestions = LatexBox_BibComplete(a:base)
+		elseif s:completion_type == 'inlineMath'
+			let suggestions = s:LatexBox_inlineMath_completion(a:base)
+		endif
+		if !has('gui_running')
+			redraw!
+		endif
+		return suggestions
+	endif
+endfunction
+" }}}
+
+" BibTeX search {{{
+
+" find the \bibliography{...} commands
+" the optional argument is the file name to be searched
+
+function! s:FindBibData(...)
+	if a:0 == 0
+		let file = LatexBox_GetMainTexFile()
+	else
+		let file = a:1
+	endif
+
+	if !filereadable(file)
+		return []
+	endif
+	let lines = readfile(file)
+	let bibdata_list = []
+
+	"
+	" Search for added bibliographies
+	"
+	let bibliography_cmds = [
+				\ '\\bibliography',
+				\ '\\addbibresource',
+				\ '\\addglobalbib',
+				\ '\\addsectionbib',
+				\ ]
+	for cmd in bibliography_cmds
+		let filtered = filter(copy(lines),
+					\ 'v:val =~ ''\C' . cmd . '\s*{[^}]\+}''')
+		let files = map(filtered,
+					\ 'matchstr(v:val, ''\C' . cmd . '\s*{\zs[^}]\+\ze}'')')
+		for file in files
+			let bibdata_list += map(split(file, ','),
+						\ 'fnamemodify(v:val, '':r'')')
+		endfor
+	endfor
+
+	"
+	" Also search included files
+	"
+	for input in filter(lines,
+				\ 'v:val =~ ''\C\\\%(input\|include\)\s*{[^}]\+}''')
+		let bibdata_list += s:FindBibData(LatexBox_kpsewhich(
+					\ matchstr(input,
+						\ '\C\\\%(input\|include\)\s*{\zs[^}]\+\ze}')))
+	endfor
+
+	return bibdata_list
+endfunction
+
+let s:bstfile = expand('<sfile>:p:h') . '/vimcomplete'
+
+function! LatexBox_BibSearch(regexp)
+	let res = []
+
+	" Find data from bib files
+	let bibdata = join(s:FindBibData(), ',')
+	if bibdata != ''
+
+		" write temporary aux file
+		let tmpbase = LatexBox_GetTexRoot() . '/_LatexBox_BibComplete'
+		let auxfile = tmpbase . '.aux'
+		let bblfile = tmpbase . '.bbl'
+		let blgfile = tmpbase . '.blg'
+
+		call writefile(['\citation{*}', '\bibstyle{' . s:bstfile . '}',
+					\ '\bibdata{' . bibdata . '}'], auxfile)
+
+		if has('win32')
+			let l:old_shellslash = &l:shellslash
+			setlocal noshellslash
+			call system('cd ' . shellescape(LatexBox_GetTexRoot()) .
+						\ ' & bibtex -terse '
+						\ . fnamemodify(auxfile, ':t') . ' >nul')
+			let &l:shellslash = l:old_shellslash
+		else
+			call system('cd ' . shellescape(LatexBox_GetTexRoot()) .
+						\ ' ; bibtex -terse '
+						\ . fnamemodify(auxfile, ':t') . ' >/dev/null')
+		endif
+
+		let lines = split(substitute(join(readfile(bblfile), "\n"),
+					\ '\n\n\@!\(\s\=\)\s*\|{\|}', '\1', 'g'), "\n")
+
+		for line in filter(lines, 'v:val =~ a:regexp')
+			let matches = matchlist(line,
+						\ '^\(.*\)||\(.*\)||\(.*\)||\(.*\)||\(.*\)')
+			if !empty(matches) && !empty(matches[1])
+				let s:type_length = max([s:type_length,
+							\ len(matches[2]) + 3])
+				call add(res, {
+							\ 'key': matches[1],
+							\ 'type': matches[2],
+							\ 'author': matches[3],
+							\ 'year': matches[4],
+							\ 'title': matches[5],
+							\ })
+			endif
+		endfor
+
+		call delete(auxfile)
+		call delete(bblfile)
+		call delete(blgfile)
+	endif
+
+	" Find data from 'thebibliography' environments
+	let lines = readfile(LatexBox_GetMainTexFile())
+	if match(lines, '\C\\begin{thebibliography}') >= 0
+		for line in filter(filter(lines, 'v:val =~ ''\C\\bibitem'''),
+					\ 'v:val =~ a:regexp')
+			let match = matchlist(line, '\\bibitem{\([^}]*\)')[1]
+			call add(res, {
+						\ 'key': match,
+						\ 'type': '',
+						\ 'author': '',
+						\ 'year': '',
+						\ 'title': match,
+						\ })
+		endfor
+	endif
+
+	return res
+endfunction
+" }}}
+
+" BibTeX completion {{{
+let s:type_length=0
+function! LatexBox_BibComplete(regexp)
+
+	" treat spaces as '.*' if needed
+	if g:LatexBox_bibtex_wild_spaces
+		"let regexp = substitute(a:regexp, '\s\+', '.*', 'g')
+		let regexp = '.*' . substitute(a:regexp, '\s\+', '\\\&.*', 'g')
+	else
+		let regexp = a:regexp
+	endif
+
+	let res = []
+	let s:type_length = 4
+	for m in LatexBox_BibSearch(regexp)
+		let type = m['type']   == '' ? '[-]' : '[' . m['type']   . '] '
+		let type = printf('%-' . s:type_length . 's', type)
+		let auth = m['author'] == '' ? ''    :       m['author'][:20] . ' '
+		let auth = substitute(auth, '\~', ' ', 'g')
+		let auth = substitute(auth, ',.*\ze', ' et al. ', '')
+		let year = m['year']   == '' ? ''    : '(' . m['year']   . ')'
+		let w = { 'word': m['key'],
+				\ 'abbr': type . auth . year,
+				\ 'menu': m['title'] }
+
+		" close braces if needed
+		if g:LatexBox_completion_close_braces && !s:NextCharsMatch('^\s*[,}]')
+			let w.word = w.word . '}'
+		endif
+
+		call add(res, w)
+	endfor
+	return res
+endfunction
+" }}}
+
+" ExtractLabels {{{
+" Generate list of \newlabel commands in current buffer.
+"
+" Searches the current buffer for commands of the form
+"	\newlabel{name}{{number}{page}.*
+" and returns list of [ name, number, page ] tuples.
+function! s:ExtractLabels()
+	call cursor(1,1)
+
+	let matches = []
+	let [lblline, lblbegin] = searchpos( '\\newlabel{', 'ecW' )
+
+	while [lblline, lblbegin] != [0,0]
+		let [nln, nameend] = searchpairpos( '{', '', '}', 'W' )
+		if nln != lblline
+			let [lblline, lblbegin] = searchpos( '\\newlabel{', 'ecW' )
+			continue
+		endif
+		let curname = strpart( getline( lblline ), lblbegin, nameend - lblbegin - 1 )
+
+		" Ignore cref entries (because they are duplicates)
+		if curname =~# "@cref$"
+		    let [lblline, lblbegin] = searchpos( '\\newlabel{', 'ecW' )
+			continue
+		endif
+
+		if 0 == search( '\m{\w*{', 'ce', lblline )
+		    let [lblline, lblbegin] = searchpos( '\\newlabel{', 'ecW' )
+		    continue
+		endif
+
+		let numberbegin = getpos('.')[2]
+		let [nln, numberend]  = searchpairpos( '{', '', '}', 'W' )
+		if nln != lblline
+			let [lblline, lblbegin] = searchpos( '\\newlabel{', 'ecW' )
+			continue
+		endif
+		let curnumber = strpart( getline( lblline ), numberbegin, numberend - numberbegin - 1 )
+
+		if 0 == search( '\m\w*{', 'ce', lblline )
+		    let [lblline, lblbegin] = searchpos( '\\newlabel{', 'ecW' )
+		    continue
+		endif
+
+		let pagebegin = getpos('.')[2]
+		let [nln, pageend]  = searchpairpos( '{', '', '}', 'W' )
+		if nln != lblline
+			let [lblline, lblbegin] = searchpos( '\\newlabel{', 'ecW' )
+			continue
+		endif
+		let curpage = strpart( getline( lblline ), pagebegin, pageend - pagebegin - 1 )
+
+		let matches += [ [ curname, curnumber, curpage ] ]
+
+		let [lblline, lblbegin] = searchpos( '\\newlabel{', 'ecW' )
+	endwhile
+
+	return matches
+endfunction
+"}}}
+
+" ExtractInputs {{{
+" Generate list of \@input commands in current buffer.
+"
+" Searches the current buffer for \@input{file} entries and
+" returns list of all files.
+function! s:ExtractInputs()
+	call cursor(1,1)
+
+	let matches = []
+	let [inline, inbegin] = searchpos( '\\@input{', 'ecW' )
+
+	while [inline, inbegin] != [0,0]
+		let [nln, inend] = searchpairpos( '{', '', '}', 'W' )
+		if nln != inline
+			let [inline, inbegin] = searchpos( '\\@input{', 'ecW' )
+			continue
+		endif
+		let matches += [ LatexBox_kpsewhich(strpart( getline( inline ), inbegin, inend - inbegin - 1 )) ]
+
+		let [inline, inbegin] = searchpos( '\\@input{', 'ecW' )
+	endwhile
+
+	" Remove empty strings for nonexistant .aux files
+	return filter(matches, 'v:val != ""')
+endfunction
+"}}}
+
+" LabelCache {{{
+" Cache of all labels.
+"
+" LabelCache is a dictionary mapping filenames to tuples
+" [ time, labels, inputs ]
+" where
+" * time is modification time of the cache entry
+" * labels is a list like returned by ExtractLabels
+" * inputs is a list like returned by ExtractInputs
+let s:LabelCache = {}
+"}}}
+
+" GetLabelCache {{{
+" Extract labels from LabelCache and update it.
+"
+" Compares modification time of each entry in the label
+" cache and updates it, if necessary. During traversal of
+" the LabelCache, all current labels are collected and
+" returned.
+function! s:GetLabelCache(file)
+	if !filereadable(a:file)
+		return []
+	endif
+
+	if !has_key(s:LabelCache , a:file) || s:LabelCache[a:file][0] != getftime(a:file)
+		" Open file in temporary split window for label extraction.
+		let main_tex_file = LatexBox_GetMainTexFile()
+		silent execute '1sp +let\ b:main_tex_file=main_tex_file|let\ labels=s:ExtractLabels()|let\ inputs=s:ExtractInputs()|quit! ' . fnameescape(a:file)
+		let s:LabelCache[a:file] = [ getftime(a:file), labels, inputs ]
+	endif
+
+	" We need to create a copy of s:LabelCache[fid][1], otherwise all inputs'
+	" labels would be added to the current file's label cache upon each
+	" completion call, leading to duplicates/triplicates/etc. and decreased
+	" performance.
+	" Also, because we don't anything with the list besides matching copies,
+	" we can get away with a shallow copy for now.
+	let labels = copy(s:LabelCache[a:file][1])
+
+	for input in s:LabelCache[a:file][2]
+		let labels += s:GetLabelCache(input)
+	endfor
+
+	return labels
+endfunction
+"}}}
+
+" Complete Labels {{{
+function! s:CompleteLabels(regex)
+	let labels = s:GetLabelCache(LatexBox_GetAuxFile())
+
+	let matches = filter( copy(labels), 'match(v:val[0], "' . a:regex . '") != -1' )
+	if empty(matches)
+		" also try to match label and number
+		let regex_split = split(a:regex)
+		if len(regex_split) > 1
+			let base = regex_split[0]
+			let number = escape(join(regex_split[1:], ' '), '.')
+			let matches = filter( copy(labels), 'match(v:val[0], "' . base . '") != -1 && match(v:val[1], "' . number . '") != -1' )
+		endif
+	endif
+	if empty(matches)
+		" also try to match number
+		let matches = filter( copy(labels), 'match(v:val[1], "' . a:regex . '") != -1' )
+	endif
+
+	let suggestions = []
+	for m in matches
+		let entry = {'word': m[0], 'menu': printf("%7s [p. %s]", '('.m[1].')', m[2])}
+		if g:LatexBox_completion_close_braces && !s:NextCharsMatch('^\s*[,}]')
+			" add trailing '}'
+			let entry = copy(entry)
+			let entry.abbr = entry.word
+			let entry.word = entry.word . '}'
+		endif
+		call add(suggestions, entry)
+	endfor
+
+	return suggestions
+endfunction
+" }}}
+
+" Complete Inline Math Or Not {{{
+" Return 1, when cursor is in a math env:
+" 	1, there is a single $ in the current line on the left of cursor
+" 	2, there is an open-eq-env on/above the current line
+" 		(open-eq-env : \(, \[, and \begin{eq-env} )
+" Return 0, when cursor is not in a math env
+function! s:LatexBox_complete_inlineMath_or_not()
+
+	" switch of inline math completion feature
+	if g:LatexBox_complete_inlineMath == 0
+		return 0
+	endif
+
+    " env names that can't appear in an eq env
+	if !exists('s:LatexBox_doc_structure_patterns')
+		let s:LatexBox_doc_structure_patterns = '\%(' .  '\\begin\s*{document}\|' .
+					\ '\\\%(chapter\|section\|subsection\|subsubsection\)\*\?\s*{' . '\)'
+	endif
+
+	if !exists('s:LatexBox_eq_env_open_patterns')
+		let s:LatexBox_eq_env_open_patterns = ['\\(','\\\[']
+	endif
+	if !exists('s:LatexBox_eq_env_close_patterns')
+		let s:LatexBox_eq_env_close_patterns = ['\\)','\\\]']
+	endif
+
+	let notcomment = '\%(\%(\\\@<!\%(\\\\\)*\)\@<=%.*\)\@<!'
+
+	let lnum_saved = line('.')
+    let cnum_saved = col('.') -1
+
+    let line = getline('.')
+	let line_start_2_cnum_saved = line[:cnum_saved]
+
+	" determine whether there is a single $ before cursor
+	let cursor_dollar_pair = 0
+	while matchend(line_start_2_cnum_saved, '\$[^$]\+\$', cursor_dollar_pair) >= 0
+		" find the end of dollar pair
+		let cursor_dollar_pair = matchend(line_start_2_cnum_saved, '\$[^$]\+\$', cursor_dollar_pair)
+	endwhile
+	" find single $ after cursor_dollar_pair
+	let cursor_single_dollar = matchend(line_start_2_cnum_saved, '\$', cursor_dollar_pair)
+
+	" if single $ is found
+	if cursor_single_dollar >= 0
+		" check whether $ is in \(...\), \[...\], or \begin{eq}...\end{eq}
+
+		" check current line,
+		" search for LatexBox_eq_env_close_patterns: \[ and \(
+		let lnum = line('.')
+		for i in range(0, (len(s:LatexBox_eq_env_open_patterns)-1))
+			call cursor(lnum_saved, cnum_saved)
+			let cnum_close = searchpos(''. s:LatexBox_eq_env_close_patterns[i].'', 'cbW', lnum_saved)[1]
+			let cnum_open = matchend(line_start_2_cnum_saved, s:LatexBox_eq_env_open_patterns[i], cnum_close)
+			if cnum_open >= 0
+				let s:eq_dollar_parenthesis_bracket_empty = ''
+				let s:eq_pos = cursor_single_dollar - 1
+				return 1
+			end
+		endfor
+
+		" check the lines above
+		" search for s:LatexBox_doc_structure_patterns, and end-of-math-env
+		let lnum -= 1
+		while lnum > 0
+			let line = getline(lnum)
+			if line =~ notcomment . '\(' . s:LatexBox_doc_structure_patterns .
+						\ '\|' . '\\end\s*{\(' . g:LatexBox_eq_env_patterns . '\)\*\?}\)'
+				" when s:LatexBox_doc_structure_patterns or g:LatexBox_eq_env_patterns
+				" are found first, complete math, leave with $ at both sides
+				let s:eq_dollar_parenthesis_bracket_empty = '$'
+				let s:eq_pos = cursor_single_dollar
+				break
+			elseif line =~ notcomment . '\\begin\s*{\(' . g:LatexBox_eq_env_patterns . '\)\*\?}'
+				" g:LatexBox_eq_env_patterns is found, complete math, remove $
+				let s:eq_dollar_parenthesis_bracket_empty = ''
+				let s:eq_pos = cursor_single_dollar - 1
+				break
+			endif
+			let lnum -= 1
+		endwhile
+
+		return 1
+	else
+		" no $ is found, then search for \( or \[ in current line
+		" 1, whether there is \(
+		call cursor(lnum_saved, cnum_saved)
+		let cnum_parenthesis_close = searchpos('\\)', 'cbW', lnum_saved)[1]
+		let cnum_parenthesis_open = matchend(line_start_2_cnum_saved, '\\(', cnum_parenthesis_close)
+		if cnum_parenthesis_open >= 0
+			let s:eq_dollar_parenthesis_bracket_empty = '\)'
+			let s:eq_pos = cnum_parenthesis_open
+			return 1
+		end
+
+		" 2, whether there is \[
+		call cursor(lnum_saved, cnum_saved)
+		let cnum_bracket_close = searchpos('\\\]', 'cbW', lnum_saved)[1]
+		let cnum_bracket_open = matchend(line_start_2_cnum_saved, '\\\[', cnum_bracket_close)
+		if cnum_bracket_open >= 0
+			let s:eq_dollar_parenthesis_bracket_empty = '\]'
+			let s:eq_pos = cnum_bracket_open
+			return 1
+		end
+
+		" not inline math completion
+		return 0
+	endif
+
+endfunction
+" }}}
+
+" Complete inline euqation{{{
+function! s:LatexBox_inlineMath_completion(regex, ...)
+
+	if a:0 == 0
+		let file = LatexBox_GetMainTexFile()
+	else
+		let file = a:1
+	endif
+
+	if empty(glob(file, 1))
+		return ''
+	endif
+
+	if empty(s:eq_dollar_parenthesis_bracket_empty)
+		let inline_pattern1 = '\$\s*\(' . escape(substitute(a:regex[1:], '^\s\+', '', ""), '\.*^') . '[^$]*\)\s*\$'
+		let inline_pattern2 = '\\(\s*\(' . escape(substitute(a:regex[1:], '^\s\+', '', ""), '\.*^') . '.*\)\s*\\)'
+	else
+		let inline_pattern1 = '\$\s*\(' . escape(substitute(a:regex, '^\s\+', '', ""), '\.*^') . '[^$]*\)\s*\$'
+		let inline_pattern2 = '\\(\s*\(' . escape(substitute(a:regex, '^\s\+', '', ""), '\.*^') . '.*\)\s*\\)'
+	endif
+
+
+	let suggestions = []
+	let line_num = 0
+	for line in readfile(file)
+		let line_num = line_num + 1
+
+		let suggestions += s:LatexBox_inlineMath_mathlist(line,inline_pattern1 , line_num) +  s:LatexBox_inlineMath_mathlist( line,inline_pattern2, line_num)
+
+ 		" search for included files
+ 		let included_file = matchstr(line, '^\\@input{\zs[^}]*\ze}')
+ 		if included_file != ''
+ 			let included_file = LatexBox_kpsewhich(included_file)
+ 			call extend(suggestions, s:LatexBox_inlineMath_completion(a:regex, included_file))
+ 		endif
+ 	endfor
+
+	return suggestions
+endfunction
+" }}}
+
+" Search for inline maths {{{
+" search for $ ... $ and \( ... \) in each line
+function! s:LatexBox_inlineMath_mathlist(line,inline_pattern, line_num)
+	let col_start = 0
+	let suggestions = []
+	while 1
+		let matches = matchlist(a:line, a:inline_pattern, col_start)
+		if !empty(matches)
+
+			" show line number of inline math
+			let entry = {'word': matches[1], 'menu': '[' . a:line_num . ']'}
+
+            if  s:eq_dollar_parenthesis_bracket_empty != ''
+                let entry = copy(entry)
+                let entry.abbr = entry.word
+                let entry.word = entry.word . s:eq_dollar_parenthesis_bracket_empty
+            endif
+			call add(suggestions, entry)
+
+			" update col_start
+			let col_start = matchend(a:line, a:inline_pattern, col_start)
+		else
+			break
+		endif
+	endwhile
+
+	return suggestions
+endfunction
+" }}}
+
+" Close Current Environment {{{
+function! s:CloseCurEnv()
+	" first, try with \left/\right pairs
+	let [lnum, cnum] = searchpairpos('\C\\left\>', '', '\C\\right\>', 'bnW', 'LatexBox_InComment()')
+	if lnum
+		let line = strpart(getline(lnum), cnum - 1)
+		let bracket = matchstr(line, '^\\left\zs\((\|\[\|\\{\||\|\.\)\ze')
+		for [open, close] in [['(', ')'], ['\[', '\]'], ['\\{', '\\}'], ['|', '|'], ['\.', '|']]
+			let bracket = substitute(bracket, open, close, 'g')
+		endfor
+		return '\right' . bracket
+	endif
+
+	" second, try with environments
+	let env = LatexBox_GetCurrentEnvironment()
+	if env == '\['
+		return '\]'
+	elseif env == '\('
+		return '\)'
+	elseif env != ''
+		return '\end{' . env . '}'
+	endif
+	return ''
+endfunction
+" }}}
+
+" Wrap Selection {{{
+function! s:WrapSelection(wrapper)
+	keepjumps normal! `>a}
+	execute 'keepjumps normal! `<i\' . a:wrapper . '{'
+endfunction
+" }}}
+
+" Wrap Selection in Environment with Prompt {{{
+function! s:PromptEnvWrapSelection(...)
+	let env = input('environment: ', '', 'customlist,' . s:SIDWrap('GetEnvironmentList'))
+	if empty(env)
+		return
+	endif
+	" LaTeXBox's custom indentation can interfere with environment
+	" insertion when environments are indented (common for nested
+	" environments).  Temporarily disable it for this operation:
+	let ieOld = &indentexpr
+	setlocal indentexpr=""
+	if visualmode() ==# 'V'
+		execute 'keepjumps normal! `>o\end{' . env . '}'
+		execute 'keepjumps normal! `<O\begin{' . env . '}'
+		" indent and format, if requested.
+		if a:0 && a:1
+			normal! gv>
+			normal! gvgq
+		endif
+	else
+		execute 'keepjumps normal! `>a\end{' . env . '}'
+		execute 'keepjumps normal! `<i\begin{' . env . '}'
+	endif
+	exe "setlocal indentexpr=" . ieOld
+endfunction
+" }}}
+
+" List Labels with Prompt {{{
+function! s:PromptLabelList(...)
+	" Check if window already exists
+	let winnr = bufwinnr(bufnr('LaTeX Labels'))
+	if winnr >= 0
+		if a:0 == 0
+			silent execute winnr . 'wincmd w'
+		else
+			" Supplying an argument to this function causes toggling instead
+			" of jumping to the labels window
+			if g:LatexBox_split_resize
+				silent exe "set columns-=" . g:LatexBox_split_width
+			endif
+			silent execute 'bwipeout' . bufnr('LaTeX Labels')
+		endif
+		return
+	endif
+
+	" Get label suggestions
+	let regexp = input('filter labels with regexp: ', '')
+	let labels = s:CompleteLabels(regexp)
+
+	let calling_buf = bufnr('%')
+
+	" Create labels window and set local settings
+	if g:LatexBox_split_resize
+		silent exe "set columns+=" . g:LatexBox_split_width
+	endif
+	silent exe g:LatexBox_split_side g:LatexBox_split_width . 'vnew LaTeX\ Labels'
+	let b:toc = []
+	let b:toc_numbers = 1
+	let b:calling_win = bufwinnr(calling_buf)
+	setlocal filetype=latextoc
+
+	" Add label entries and jump to the closest section
+	for entry in labels
+		let number = matchstr(entry['menu'], '^\s*(\zs[^)]\+\ze)')
+		let page = matchstr(entry['menu'], '^[^)]*)\s*\[\zs[^]]\+\ze\]')
+		let e = {'file': bufname(calling_buf),
+					\ 'level': 'label',
+					\ 'number': number,
+					\ 'text': entry['abbr'],
+					\ 'page': page}
+		call add(b:toc, e)
+		if b:toc_numbers
+			call append('$', e['number'] . "\t" . e['text'])
+		else
+			call append('$', e['text'])
+		endif
+	endfor
+	if !g:LatexBox_toc_hidehelp
+		call append('$', "")
+		call append('$', "<Esc>/q: close")
+		call append('$', "<Space>: jump")
+		call append('$', "<Enter>: jump and close")
+		call append('$', "s:       hide numbering")
+	endif
+	0delete _
+
+	" Lock buffer
+	setlocal nomodifiable
+endfunction
+" }}}
+
+" Change Environment {{{
+function! s:ChangeEnvPrompt()
+
+	let [env, lnum, cnum, lnum2, cnum2] = LatexBox_GetCurrentEnvironment(1)
+
+	let new_env = input('change ' . env . ' for: ', '', 'customlist,' . s:SIDWrap('GetEnvironmentList'))
+	if empty(new_env)
+		return
+	endif
+
+	if new_env == '\[' || new_env == '['
+		let begin = '\['
+		let end = '\]'
+	elseif new_env == '\(' || new_env == '('
+		let begin = '\('
+		let end = '\)'
+	else
+		let l:begin = '\begin{' . new_env . '}'
+		let l:end = '\end{' . new_env . '}'
+	endif
+
+	if env == '\[' || env == '\('
+		let line = getline(lnum2)
+		let line = strpart(line, 0, cnum2 - 1) . l:end . strpart(line, cnum2 + 1)
+		call setline(lnum2, line)
+
+		let line = getline(lnum)
+		let line = strpart(line, 0, cnum - 1) . l:begin . strpart(line, cnum + 1)
+		call setline(lnum, line)
+	else
+		let line = getline(lnum2)
+		let line = strpart(line, 0, cnum2 - 1) . l:end . strpart(line, cnum2 + len(env) + 5)
+		call setline(lnum2, line)
+
+		let line = getline(lnum)
+		let line = strpart(line, 0, cnum - 1) . l:begin . strpart(line, cnum + len(env) + 7)
+		call setline(lnum, line)
+	endif
+endfunction
+
+function! s:GetEnvironmentList(lead, cmdline, pos)
+	let suggestions = []
+	for entry in g:LatexBox_completion_environments
+		let env = entry.word
+		if env =~ '^' . a:lead
+			call add(suggestions, env)
+		endif
+	endfor
+	return suggestions
+endfunction
+
+function! s:LatexToggleStarEnv()
+	let [env, lnum, cnum, lnum2, cnum2] = LatexBox_GetCurrentEnvironment(1)
+
+	if env == '\('
+		return
+	elseif env == '\['
+		let begin = '\begin{equation}'
+		let end = '\end{equation}'
+	elseif env[-1:] == '*'
+		let begin = '\begin{' . env[:-2] . '}'
+		let end   = '\end{'   . env[:-2] . '}'
+	else
+		let begin = '\begin{' . env . '*}'
+		let end   = '\end{'   . env . '*}'
+	endif
+
+	if env == '\['
+		let line = getline(lnum2)
+		let line = strpart(line, 0, cnum2 - 1) . l:end . strpart(line, cnum2 + 1)
+		call setline(lnum2, line)
+
+		let line = getline(lnum)
+		let line = strpart(line, 0, cnum - 1) . l:begin . strpart(line, cnum + 1)
+		call setline(lnum, line)
+	else
+		let line = getline(lnum2)
+		let line = strpart(line, 0, cnum2 - 1) . l:end . strpart(line, cnum2 + len(env) + 5)
+		call setline(lnum2, line)
+
+		let line = getline(lnum)
+		let line = strpart(line, 0, cnum - 1) . l:begin . strpart(line, cnum + len(env) + 7)
+		call setline(lnum, line)
+	endif
+endfunction
+" }}}
+
+" Next Charaters Match {{{
+function! s:NextCharsMatch(regex)
+	let rest_of_line = strpart(getline('.'), col('.') - 1)
+	return rest_of_line =~ a:regex
+endfunction
+" }}}
+
+" Mappings {{{
+inoremap <silent> <Plug>LatexCloseCurEnv			<C-R>=<SID>CloseCurEnv()<CR>
+vnoremap <silent> <Plug>LatexWrapSelection			:<c-u>call <SID>WrapSelection('')<CR>i
+vnoremap <silent> <Plug>LatexEnvWrapSelection		:<c-u>call <SID>PromptEnvWrapSelection()<CR>
+vnoremap <silent> <Plug>LatexEnvWrapFmtSelection	:<c-u>call <SID>PromptEnvWrapSelection(1)<CR>
+nnoremap <silent> <Plug>LatexChangeEnv				:call <SID>ChangeEnvPrompt()<CR>
+nnoremap <silent> <Plug>LatexToggleStarEnv			:call <SID>LatexToggleStarEnv()<CR>
+" }}}
+
+" Commands {{{
+command! LatexLabels call <SID>PromptLabelList()
+" }}}
+
+" vim:fdm=marker:ff=unix:noet:ts=4:sw=4
+
+endif

ftplugin/latex-box/findmain.vim

@@ -0,0 +1,66 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" LatexBox_GetMainFileName: gets the name of the main file being compiled. {{{
+" Description:  returns the full path name of the main file.
+"               This function checks for the existence of a .latexmain file
+"               which might point to the location of a "main" latex file.
+"               If .latexmain exists, then return the full path name of the
+"               file being pointed to by it.
+"
+"               Otherwise, return the full path name of the current buffer.
+"
+"               You can supply an optional "modifier" argument to the
+"               function, which will optionally modify the file name before
+"               returning.
+"               NOTE: From version 1.6 onwards, this function always trims
+"               away the .latexmain part of the file name before applying the
+"               modifier argument.
+"               NOTE: This function is copied from the Latex-Suite project!
+function! LatexBox_GetMainFileName(...)
+	if a:0 > 0
+		let modifier = a:1
+	else
+		let modifier = ':p'
+	endif
+
+	let s:origdir = fnameescape(getcwd())
+
+	let dirmodifier = '%:p:h'
+	let dirLast = fnameescape(expand(dirmodifier))
+	exe 'cd '.dirLast
+
+	" move up the directory tree until we find a .latexmain file.
+	" TODO: Should we be doing this recursion by default, or should there be a
+	"       setting?
+	while glob('*.latexmain',1) == ''
+		let dirmodifier = dirmodifier.':h'
+		let dirNew = fnameescape(expand(dirmodifier))
+		" break from the loop if we cannot go up any further.
+		if dirNew == dirLast
+			break
+		endif
+		let dirLast = dirNew
+		exe 'cd '.dirLast
+	endwhile
+
+	let lheadfile = glob('*.latexmain',1)
+	if lheadfile != ''
+		" Remove the trailing .latexmain part of the filename... We never want
+		" that.
+		let lheadfile = fnamemodify(substitute(lheadfile, '\.latexmain$', '', ''), modifier)
+	else
+		" If we cannot find any main file, just modify the filename of the
+		" current buffer.
+		let lheadfile = expand('%'.modifier)
+	endif
+
+	exe 'cd '.s:origdir
+
+	" NOTE: The caller of this function needs to escape the file name with
+	"       fnameescape() . The reason its not done here is that escaping is not
+	"       safe if this file is to be used as part of an external command on
+	"       certain platforms.
+	return lheadfile
+endfunction
+
+endif

ftplugin/latex-box/folding.vim

@@ -0,0 +1,382 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" Folding support for LaTeX
+
+"
+" Options
+" g:LatexBox_Folding         - Turn on/off folding
+" g:LatexBox_fold_text       - Turn on/off LatexBox fold text function
+" g:LatexBox_fold_preamble   - Turn on/off folding of preamble
+" g:LatexBox_fold_parts      - Define parts (eq. appendix, frontmatter) to fold
+" g:LatexBox_fold_sections   - Define section levels to fold
+" g:LatexBox_fold_envs       - Turn on/off folding of environments
+" g:LatexBox_fold_toc        - Turn on/off folding of TOC
+" g:LatexBox_fold_toc_levels - Set max TOC fold level
+"
+" {{{1 Initialize options to default values.
+if !exists('g:LatexBox_Folding')
+	let g:LatexBox_Folding=0
+endif
+if !exists('g:LatexBox_fold_text')
+    let g:LatexBox_fold_text=1
+endif
+if !exists('g:LatexBox_fold_preamble')
+    let g:LatexBox_fold_preamble=1
+endif
+if !exists('g:LatexBox_fold_envs')
+    let g:LatexBox_fold_envs=1
+endif
+if !exists('g:LatexBox_fold_envs_force')
+    let g:LatexBox_fold_envs_force = []
+endif
+if !exists('g:LatexBox_fold_parts')
+    let g:LatexBox_fold_parts=[
+                \ "appendix",
+                \ "frontmatter",
+                \ "mainmatter",
+                \ "backmatter"
+                \ ]
+endif
+if !exists('g:LatexBox_fold_sections')
+    let g:LatexBox_fold_sections=[
+                \ "part",
+                \ "chapter",
+                \ "section",
+                \ "subsection",
+                \ "subsubsection"
+                \ ]
+endif
+if !exists('g:LatexBox_fold_toc')
+    let g:LatexBox_fold_toc=0
+endif
+if !exists('g:LatexBox_fold_toc_levels')
+    let g:LatexBox_fold_toc_levels=1
+endif
+if !exists('g:LatexBox_fold_automatic')
+	let g:LatexBox_fold_automatic=1
+endif
+" }}}1
+
+if g:LatexBox_Folding == 0
+    finish
+endif
+
+" {{{1 Set folding options for vim
+setl foldexpr=LatexBox_FoldLevel(v:lnum)
+if g:LatexBox_fold_text == 1
+    setl foldtext=LatexBox_FoldText()
+endif
+if g:LatexBox_fold_automatic == 1
+    setl foldmethod=expr
+
+	"
+	" The foldexpr function returns "=" for most lines, which means it can become
+	" slow for large files.  The following is a hack that is based on this reply to
+	" a discussion on the Vim Developer list:
+	" http://permalink.gmane.org/gmane.editors.vim.devel/14100
+	"
+	augroup FastFold
+		autocmd!
+		autocmd InsertEnter *.tex if !&diff | setlocal foldmethod=manual | endif
+		autocmd InsertLeave *.tex if !&diff | setlocal foldmethod=expr | endif
+	augroup end
+else
+	setl foldmethod=manual
+endif
+
+function! LatexBox_FoldOnDemand()
+	setl foldmethod=expr
+	normal! zx
+	setl foldmethod=manual
+endfunction
+
+command! LatexFold  call LatexBox_FoldOnDemand()
+
+" {{{1 LatexBox_FoldLevel help functions
+
+" This function parses the tex file to find the sections that are to be folded
+" and their levels, and then predefines the patterns for optimized folding.
+function! s:FoldSectionLevels()
+    " Initialize
+    let level = 1
+    let foldsections = []
+
+    " If we use two or more of the *matter commands, we need one more foldlevel
+    let nparts = 0
+    for part in g:LatexBox_fold_parts
+        let i = 1
+        while i < line("$")
+            if getline(i) =~ '^\s*\\' . part . '\>'
+                let nparts += 1
+                break
+            endif
+            let i += 1
+        endwhile
+        if nparts > 1
+            let level = 2
+            break
+        endif
+    endfor
+
+    " Combine sections and levels, but ignore unused section commands:  If we
+    " don't use the part command, then chapter should have the highest
+    " level.  If we don't use the chapter command, then section should be the
+    " highest level.  And so on.
+    let ignore = 1
+    for part in g:LatexBox_fold_sections
+        " For each part, check if it is used in the file.  We start adding the
+        " part patterns to the fold sections array whenever we find one.
+        let partpattern = '^\s*\(\\\|% Fake\)' . part . '\>'
+        if ignore
+            let i = 1
+            while i < line("$")
+                if getline(i) =~# partpattern
+                    call insert(foldsections, [partpattern, level])
+                    let level += 1
+                    let ignore = 0
+                    break
+                endif
+                let i += 1
+            endwhile
+        else
+            call insert(foldsections, [partpattern, level])
+            let level += 1
+        endif
+    endfor
+
+    return foldsections
+endfunction
+
+" {{{1 LatexBox_FoldLevel
+
+" Parse file to dynamically set the sectioning fold levels
+let b:LatexBox_FoldSections = s:FoldSectionLevels()
+
+" Optimize by predefine common patterns
+let s:notbslash = '\%(\\\@<!\%(\\\\\)*\)\@<='
+let s:notcomment = '\%(\%(\\\@<!\%(\\\\\)*\)\@<=%.*\)\@<!'
+let s:envbeginpattern = s:notcomment . s:notbslash . '\\begin\s*{.\{-}}'
+let s:envendpattern = s:notcomment . s:notbslash . '\\end\s*{.\{-}}'
+let s:foldparts = '^\s*\\\%(' . join(g:LatexBox_fold_parts, '\|') . '\)'
+let s:folded = '\(% Fake\|\\\(document\|begin\|end\|paragraph\|'
+            \ . 'front\|main\|back\|app\|sub\|section\|chapter\|part\)\)'
+
+function! LatexBox_FoldLevel(lnum)
+    " Check for normal lines first (optimization)
+    let line  = getline(a:lnum)
+    if line !~ s:folded
+        return "="
+    endif
+
+    " Fold preamble
+    if g:LatexBox_fold_preamble == 1
+        if line =~# s:notcomment . s:notbslash . '\s*\\documentclass'
+            return ">1"
+        elseif line =~# s:notcomment . s:notbslash . '\s*\\begin\s*{\s*document\s*}'
+            return "0"
+        endif
+    endif
+
+    " Fold parts (\frontmatter, \mainmatter, \backmatter, and \appendix)
+    if line =~# s:foldparts
+        return ">1"
+    endif
+
+    " Fold chapters and sections
+    for [part, level] in b:LatexBox_FoldSections
+        if line =~# part
+            return ">" . level
+        endif
+    endfor
+
+    " Never fold \end{document}
+    if line =~# '^\s*\\end{document}'
+        return 0
+    endif
+
+    " Fold environments
+    if line =~# s:envbeginpattern && line =~# s:envendpattern
+        " If the begin and end pattern are on the same line , do not fold
+        return "="
+    else
+        if line =~# s:envbeginpattern
+            if g:LatexBox_fold_envs == 1
+                return "a1"
+            else
+                let env = matchstr(line,'\\begin\*\?{\zs\w*\*\?\ze}')
+                if index(g:LatexBox_fold_envs_force, env) >= 0
+                    return "a1"
+                else
+                    return "="
+                endif
+            endif
+        elseif line =~# s:envendpattern
+            if g:LatexBox_fold_envs == 1
+                return "s1"
+            else
+                let env = matchstr(line,'\\end\*\?{\zs\w*\*\?\ze}')
+                if index(g:LatexBox_fold_envs_force, env) >= 0
+                    return "s1"
+                else
+                    return "="
+                endif
+            endif
+        endif
+    endif
+
+    " Return foldlevel of previous line
+    return "="
+endfunction
+
+" {{{1 LatexBox_FoldText help functions
+function! s:LabelEnv()
+    let i = v:foldend
+    while i >= v:foldstart
+        if getline(i) =~ '^\s*\\label'
+            return matchstr(getline(i), '^\s*\\label{\zs.*\ze}')
+        end
+        let i -= 1
+    endwhile
+    return ""
+endfunction
+
+function! s:CaptionEnv()
+    let i = v:foldend
+    while i >= v:foldstart
+        if getline(i) =~ '^\s*\\caption'
+            return matchstr(getline(i), '^\s*\\caption\(\[.*\]\)\?{\zs.\+')
+        end
+        let i -= 1
+    endwhile
+    return ""
+endfunction
+
+function! s:CaptionTable()
+    let i = v:foldstart
+    while i <= v:foldend
+        if getline(i) =~ '^\s*\\caption'
+            return matchstr(getline(i), '^\s*\\caption\(\[.*\]\)\?{\zs.\+')
+        end
+        let i += 1
+    endwhile
+    return ""
+endfunction
+
+function! s:CaptionFrame(line)
+    " Test simple variants first
+    let caption1 = matchstr(a:line,'\\begin\*\?{.*}{\zs.\+\ze}')
+    let caption2 = matchstr(a:line,'\\begin\*\?{.*}{\zs.\+')
+
+    if len(caption1) > 0
+        return caption1
+    elseif len(caption2) > 0
+        return caption2
+    else
+        let i = v:foldstart
+        while i <= v:foldend
+            if getline(i) =~ '^\s*\\frametitle'
+                return matchstr(getline(i),
+                            \ '^\s*\\frametitle\(\[.*\]\)\?{\zs.\+')
+            end
+            let i += 1
+        endwhile
+
+        return ""
+    endif
+endfunction
+
+function! LatexBox_FoldText_title()
+    let line = getline(v:foldstart)
+    let title = 'Not defined'
+
+    " Preamble
+    if line =~ '\s*\\documentclass'
+        return "Preamble"
+    endif
+
+    " Parts, sections and fakesections
+    let sections = '\(\(sub\)*\(section\|paragraph\)\|part\|chapter\)'
+    let secpat1 = '^\s*\\' . sections . '\*\?\s*{'
+    let secpat2 = '^\s*\\' . sections . '\*\?\s*\['
+    if line =~ '\\frontmatter'
+        let title = "Frontmatter"
+    elseif line =~ '\\mainmatter'
+        let title = "Mainmatter"
+    elseif line =~ '\\backmatter'
+        let title = "Backmatter"
+    elseif line =~ '\\appendix'
+        let title = "Appendix"
+    elseif line =~ secpat1 . '.*}'
+        let title =  matchstr(line, secpat1 . '\zs.\{-}\ze}')
+    elseif line =~ secpat1
+        let title =  matchstr(line, secpat1 . '\zs.*')
+    elseif line =~ secpat2 . '.*\]'
+        let title =  matchstr(line, secpat2 . '\zs.\{-}\ze\]')
+    elseif line =~ secpat2
+        let title =  matchstr(line, secpat2 . '\zs.*')
+    elseif line =~ 'Fake' . sections . ':'
+        let title =  matchstr(line,'Fake' . sections . ':\s*\zs.*')
+    elseif line =~ 'Fake' . sections
+        let title =  matchstr(line, 'Fake' . sections)
+    endif
+
+    " Environments
+    if line =~ '\\begin'
+        " Capture environment name
+        let env = matchstr(line,'\\begin\*\?{\zs\w*\*\?\ze}')
+
+        " Set caption based on type of environment
+        if env == 'frame'
+            let label = ''
+            let caption = s:CaptionFrame(line)
+        elseif env == 'table'
+            let label = s:LabelEnv()
+            let caption = s:CaptionTable()
+        else
+            let label = s:LabelEnv()
+            let caption = s:CaptionEnv()
+        endif
+
+        " If no caption found, check for a caption comment
+        if caption == ''
+            let caption = matchstr(line,'\\begin\*\?{.*}\s*%\s*\zs.*')
+        endif
+
+        " Create title based on caption and label
+        if caption . label == ''
+            let title = env
+        elseif label == ''
+            let title = printf('%-12s%s', env . ':',
+                        \ substitute(caption, '}\s*$', '',''))
+        elseif caption == ''
+            let title = printf('%-12s%56s', env, '(' . label . ')')
+        else
+            let title = printf('%-12s%-30s %21s', env . ':',
+                        \ strpart(substitute(caption, '}\s*$', '',''),0,34),
+                        \ '(' . label . ')')
+        endif
+    endif
+
+    return title
+endfunction
+
+" {{{1 LatexBox_FoldText
+function! LatexBox_FoldText()
+    let nlines = v:foldend - v:foldstart + 1
+    let title = strpart(LatexBox_FoldText_title(), 0, 68)
+    let level = ''
+
+    " Fold level
+    let level = strpart(repeat('-', v:foldlevel-1) . '*',0,3)
+    if v:foldlevel > 3
+        let level = strpart(level, 1) . v:foldlevel
+    endif
+    let level = printf('%-3s', level)
+
+    return printf('%-3s %-68s #%5d', level, title, nlines)
+endfunction
+
+" {{{1 Footer
+" vim:fdm=marker:ff=unix:ts=4:sw=4
+
+endif

ftplugin/latex-box/latexmk.vim

@@ -0,0 +1,558 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" LaTeX Box latexmk functions
+
+" Options and variables {{{
+
+if !exists('g:LatexBox_latexmk_options')
+	let g:LatexBox_latexmk_options = ''
+endif
+if !exists('g:LatexBox_latexmk_env')
+	let g:LatexBox_latexmk_env = ''
+endif
+if !exists('g:LatexBox_latexmk_async')
+	let g:LatexBox_latexmk_async = 0
+endif
+if !exists('g:LatexBox_latexmk_preview_continuously')
+	let g:LatexBox_latexmk_preview_continuously = 0
+endif
+if !exists('g:LatexBox_output_type')
+	let g:LatexBox_output_type = 'pdf'
+endif
+if !exists('g:LatexBox_autojump')
+	let g:LatexBox_autojump = 0
+endif
+if ! exists('g:LatexBox_quickfix')
+	let g:LatexBox_quickfix = 1
+endif
+if ! exists('g:LatexBox_personal_latexmkrc')
+	let g:LatexBox_personal_latexmkrc = 0
+endif
+
+" }}}
+
+" Process ID management (used for asynchronous and continuous mode) {{{
+
+" A dictionary of latexmk PID's (basename: pid)
+if !exists('g:latexmk_running_pids')
+	let g:latexmk_running_pids = {}
+endif
+
+" Set PID {{{
+function! s:LatexmkSetPID(basename, pid)
+	let g:latexmk_running_pids[a:basename] = a:pid
+endfunction
+" }}}
+
+" kill_latexmk_process {{{
+function! s:kill_latexmk_process(pid)
+	if has('win32')
+		silent execute '!taskkill /PID ' . a:pid . ' /T /F'
+	else
+		if g:LatexBox_latexmk_async
+			" vim-server mode
+			let pids = []
+			let tmpfile = tempname()
+			silent execute '!ps x -o pgid,pid > ' . tmpfile
+			for line in readfile(tmpfile)
+				let new_pid = matchstr(line, '^\s*' . a:pid . '\s\+\zs\d\+\ze')
+				if !empty(new_pid)
+					call add(pids, new_pid)
+				endif
+			endfor
+			call delete(tmpfile)
+			if !empty(pids)
+				silent execute '!kill ' . join(pids)
+			endif
+		else
+			" single background process
+			silent execute '!kill ' . a:pid
+		endif
+	endif
+	if !has('gui_running')
+		redraw!
+	endif
+endfunction
+" }}}
+
+" kill_all_latexmk_processes {{{
+function! s:kill_all_latexmk_processes()
+	for pid in values(g:latexmk_running_pids)
+		call s:kill_latexmk_process(pid)
+	endfor
+endfunction
+" }}}
+
+" }}}
+
+" Setup for vim-server {{{
+function! s:SIDWrap(func)
+	if !exists('s:SID')
+		let s:SID = matchstr(expand('<sfile>'), '\zs<SNR>\d\+_\ze.*$')
+	endif
+	return s:SID . a:func
+endfunction
+
+function! s:LatexmkCallback(basename, status)
+	" Only remove the pid if not in continuous mode
+	if !g:LatexBox_latexmk_preview_continuously
+		call remove(g:latexmk_running_pids, a:basename)
+	endif
+	call LatexBox_LatexErrors(a:status, a:basename)
+endfunction
+
+function! s:setup_vim_server()
+	if !exists('g:vim_program')
+
+		" attempt autodetection of vim executable
+		let g:vim_program = ''
+		if has('win32')
+			" Just drop through to the default for windows
+		else
+			if match(&shell, '\(bash\|zsh\)$') >= 0
+				let ppid = '$PPID'
+			else
+				let ppid = '$$'
+			endif
+
+			let tmpfile = tempname()
+			silent execute '!ps -o command= -p ' . ppid . ' > ' . tmpfile
+			for line in readfile(tmpfile)
+				let line = matchstr(line, '^\S\+\>')
+				if !empty(line) && executable(line)
+					let g:vim_program = line . ' -g'
+					break
+				endif
+			endfor
+			call delete(tmpfile)
+		endif
+
+		if empty(g:vim_program)
+			if has('gui_macvim')
+				let g:vim_program
+						\ = '/Applications/MacVim.app/Contents/MacOS/Vim -g'
+			else
+				let g:vim_program = v:progname
+			endif
+		endif
+	endif
+endfunction
+" }}}
+
+" Latexmk {{{
+
+function! LatexBox_Latexmk(force)
+	" Define often used names
+	let basepath = LatexBox_GetBuildBasename(1)
+	let basename = fnamemodify(basepath, ':t')
+	let texroot = shellescape(LatexBox_GetTexRoot())
+	let mainfile = fnameescape(fnamemodify(LatexBox_GetMainTexFile(), ':t'))
+
+	" Check if latexmk is installed
+	if !executable('latexmk')
+		echomsg "Error: LaTeX-Box relies on latexmk for compilation, but it" .
+					\ " is not installed!"
+		return
+	endif
+
+	" Check if already running
+	if has_key(g:latexmk_running_pids, basepath)
+		echomsg "latexmk is already running for `" . basename . "'"
+		return
+	endif
+
+	" Set wrap width in log file
+	let max_print_line = 2000
+	if has('win32')
+		let env = 'set max_print_line=' . max_print_line . ' & '
+	elseif match(&shell, '/tcsh$') >= 0
+		let env = 'setenv max_print_line ' . max_print_line . '; '
+	else
+		if fnamemodify(&shell, ':t') ==# 'fish'
+			let env = 'set max_print_line ' . max_print_line . '; and '
+		else
+			let env = 'max_print_line=' . max_print_line
+		endif
+	endif
+
+	" Set environment options
+	let env .= ' ' . g:LatexBox_latexmk_env . ' '
+
+	" Set latexmk command with options
+	if has('win32')
+		" Make sure to switch drive as well as directory
+		let cmd = 'cd /D ' . texroot . ' && '
+	else
+		if fnamemodify(&shell, ':t') ==# 'fish'
+			let cmd = 'cd ' . texroot . '; and '
+		else
+			let cmd = 'cd ' . texroot . ' && '
+		endif
+	endif
+	let cmd .= env . ' latexmk'
+	if ! g:LatexBox_personal_latexmkrc
+		let cmd .= ' -' . g:LatexBox_output_type
+	endif
+	let cmd .= ' -quiet '
+	let cmd .= g:LatexBox_latexmk_options
+	if a:force
+		let cmd .= ' -g'
+	endif
+	if g:LatexBox_latexmk_preview_continuously
+		let cmd .= ' -pvc'
+	endif
+	let cmd .= ' -e ' . shellescape('$pdflatex =~ s/ / -file-line-error /')
+	let cmd .= ' -e ' . shellescape('$latex =~ s/ / -file-line-error /')
+	if g:LatexBox_latexmk_preview_continuously
+		let cmd .= ' -e ' . shellescape('$success_cmd = $ENV{SUCCESSCMD}')
+		let cmd .= ' -e ' . shellescape('$failure_cmd = $ENV{FAILURECMD}')
+	endif
+	let cmd .= ' ' . mainfile
+
+	" Redirect output to null
+	if has('win32')
+		let cmd .= ' >nul'
+	else
+		if fnamemodify(&shell, ':t') ==# 'fish'
+			let cmd .= ' >/dev/null ^/dev/null'
+		else
+			let cmd .= ' &>/dev/null'
+		endif
+	endif
+
+	if g:LatexBox_latexmk_async
+		" Check if VIM server exists
+		if empty(v:servername)
+			echoerr "cannot run latexmk in background without a VIM server"
+			echoerr "set g:LatexBox_latexmk_async to 0 to change compiling mode"
+			return
+		endif
+
+		" Start vim server if necessary
+		call s:setup_vim_server()
+
+		let setpidfunc = s:SIDWrap('LatexmkSetPID')
+		let callbackfunc = s:SIDWrap('LatexmkCallback')
+		if has('win32')
+			let vim_program = substitute(g:vim_program,
+						\ 'gvim\.exe$', 'vim.exe', '')
+
+			" Define callback to set the pid
+			let callsetpid = setpidfunc . '(''' . basepath . ''', %CMDPID%)'
+			let vimsetpid = vim_program . ' --servername ' . v:servername
+						\ . ' --remote-expr ' . shellescape(callsetpid)
+
+			" Define callback after latexmk is finished
+			let callback = callbackfunc . '(''' . basepath . ''', %LATEXERR%)'
+			let vimcmd = vim_program . ' --servername ' . v:servername
+						\ . ' --remote-expr ' . shellescape(callback)
+			let scallback = callbackfunc . '(''' . basepath . ''', 0)'
+			let svimcmd = vim_program . ' --servername ' . v:servername
+						\ . ' --remote-expr ' . shellescape(scallback)
+			let fcallback = callbackfunc . '(''' . basepath . ''', 1)'
+			let fvimcmd = vim_program . ' --servername ' . v:servername
+						\ . ' --remote-expr ' . shellescape(fcallback)
+
+			let asyncbat = tempname() . '.bat'
+			if g:LatexBox_latexmk_preview_continuously
+				call writefile(['setlocal',
+							\ 'set T=%TEMP%\sthUnique.tmp',
+							\ 'wmic process where (Name="WMIC.exe" AND CommandLine LIKE "%%%TIME%%%") '
+							\ . 'get ParentProcessId /value | find "ParentProcessId" >%T%',
+							\ 'set /P A=<%T%',
+							\ 'set CMDPID=%A:~16% & del %T%',
+							\ vimsetpid,
+							\ 'set SUCCESSCMD='.svimcmd,
+							\ 'set FAILURECMD='.fvimcmd,
+							\ cmd,
+							\ 'endlocal'], asyncbat)
+			else
+				call writefile(['setlocal',
+							\ 'set T=%TEMP%\sthUnique.tmp',
+							\ 'wmic process where (Name="WMIC.exe" AND CommandLine LIKE "%%%TIME%%%") '
+							\ . 'get ParentProcessId /value | find "ParentProcessId" >%T%',
+							\ 'set /P A=<%T%',
+							\ 'set CMDPID=%A:~16% & del %T%',
+							\ vimsetpid,
+							\ cmd,
+							\ 'set LATEXERR=%ERRORLEVEL%',
+							\ vimcmd,
+							\ 'endlocal'], asyncbat)
+			endif
+
+			" Define command
+			let cmd = '!start /b ' . asyncbat . ' & del ' . asyncbat
+		else
+			" Define callback to set the pid
+			let callsetpid = shellescape(setpidfunc).'"(\"'.basepath.'\",$$)"'
+			let vimsetpid = g:vim_program . ' --servername ' . v:servername
+			                        \ . ' --remote-expr ' . callsetpid
+
+			" Define callback after latexmk is finished
+			let callback = shellescape(callbackfunc).'"(\"'.basepath.'\",$?)"'
+			let vimcmd = g:vim_program . ' --servername ' . v:servername
+									\ . ' --remote-expr ' . callback
+			let scallback = shellescape(callbackfunc).'"(\"'.basepath.'\",0)"'
+			let svimcmd = g:vim_program . ' --servername ' . v:servername
+			                        \ . ' --remote-expr ' . scallback
+			let fcallback = shellescape(callbackfunc).'"(\"'.basepath.'\",1)"'
+			let fvimcmd = g:vim_program . ' --servername ' . v:servername
+			                        \ . ' --remote-expr ' . fcallback
+
+			" Define command
+			" Note: Here we escape '%' because it may be given as a user option
+			" through g:LatexBox_latexmk_options, for instance with
+			" g:Latex..._options = "-pdflatex='pdflatex -synctex=1 \%O \%S'"
+			if g:LatexBox_latexmk_preview_continuously
+				let cmd = vimsetpid . ' ; '
+						\ . 'export SUCCESSCMD=' . shellescape(svimcmd) . ' '
+						\ . '       FAILURECMD=' . shellescape(fvimcmd) . ' ; '
+						\ . escape(cmd, '%')
+			else
+				let cmd = vimsetpid . ' ; ' . escape(cmd, '%') . ' ; ' . vimcmd
+			endif
+			let cmd = '! (' . cmd . ') >/dev/null &'
+		endif
+
+		if g:LatexBox_latexmk_preview_continuously
+			echo 'Compiling to ' . g:LatexBox_output_type
+						\ . ' with continuous preview.'
+		else
+			echo 'Compiling to ' . g:LatexBox_output_type . ' ...'
+		endif
+		silent execute cmd
+	else
+		if g:LatexBox_latexmk_preview_continuously
+			if has('win32')
+				let cmd = '!start /b cmd /s /c "' . cmd . '"'
+			else
+				let cmd = '!' . cmd . ' &'
+			endif
+			echo 'Compiling to ' . g:LatexBox_output_type . ' ...'
+			silent execute cmd
+
+			" Save PID in order to be able to kill the process when wanted.
+			if has('win32')
+				let tmpfile = tempname()
+				let pidcmd = 'cmd /c "wmic process where '
+							\ . '(CommandLine LIKE "latexmk\%'.mainfile.'\%") '
+							\ . 'get ProcessId /value | find "ProcessId" '
+							\ . '>'.tmpfile.' "'
+				silent execute '! ' . pidcmd
+				let pids = readfile(tmpfile)
+				let pid = strpart(pids[0], 10)
+				let g:latexmk_running_pids[basepath] = pid
+			else
+				let pid = substitute(system('pgrep -f "perl.*'
+							\ . mainfile . '" | head -n 1'),'\D','','')
+				let g:latexmk_running_pids[basepath] = pid
+			endif
+		else
+			" Execute command and check for errors
+			echo 'Compiling to ' . g:LatexBox_output_type . ' ... (async off!)'
+			call system(cmd)
+			call LatexBox_LatexErrors(v:shell_error)
+		endif
+	endif
+
+	" Redraw screen if necessary
+	if !has("gui_running")
+		redraw!
+	endif
+endfunction
+" }}}
+
+" LatexmkClean {{{
+function! LatexBox_LatexmkClean(cleanall)
+	" Check if latexmk is installed
+	if !executable('latexmk')
+		echomsg "Error: LaTeX-Box relies on latexmk for compilation, but it" .
+					\ " is not installed!"
+		return
+	endif
+
+	let basename = LatexBox_GetBuildBasename(1)
+
+	if has_key(g:latexmk_running_pids, basename)
+		echomsg "don't clean when latexmk is running"
+		return
+	endif
+
+	if has('win32')
+		let cmd = 'cd /D ' . shellescape(LatexBox_GetTexRoot()) . ' & '
+	else
+		let cmd = 'cd ' . shellescape(LatexBox_GetTexRoot()) . ';'
+	endif
+	if a:cleanall
+		let cmd .= 'latexmk -C '
+	else
+		let cmd .= 'latexmk -c '
+	endif
+	let cmd .= shellescape(LatexBox_GetMainTexFile())
+	if has('win32')
+		let cmd .= ' >nul'
+	else
+		let cmd .= ' >&/dev/null'
+	endif
+
+	call system(cmd)
+	if !has('gui_running')
+		redraw!
+	endif
+
+	echomsg "latexmk clean finished"
+endfunction
+" }}}
+
+" LatexErrors {{{
+function! LatexBox_LatexErrors(status, ...)
+	if a:0 >= 1
+		let log = a:1 . '.log'
+	else
+		let log = LatexBox_GetLogFile()
+	endif
+
+	cclose
+
+	" set cwd to expand error file correctly
+	let l:cwd = fnamemodify(getcwd(), ':p')
+	execute 'lcd ' . fnameescape(LatexBox_GetTexRoot())
+	try
+		if g:LatexBox_autojump
+			execute 'cfile ' . fnameescape(log)
+		else
+			execute 'cgetfile ' . fnameescape(log)
+		endif
+	finally
+		" restore cwd
+		execute 'lcd ' . fnameescape(l:cwd)
+	endtry
+
+	" Always open window if started by LatexErrors command
+	if a:status < 0
+		botright copen
+	else
+		" Only open window when an error/warning is detected
+		if g:LatexBox_quickfix >= 3
+					\ ? s:log_contains_error(log)
+					\ : g:LatexBox_quickfix > 0
+			belowright cw
+			if g:LatexBox_quickfix == 2 || g:LatexBox_quickfix == 4
+				wincmd p
+			endif
+		endif
+		redraw
+
+		" Write status message to screen
+		if a:status > 0 || len(getqflist())>1
+			if s:log_contains_error(log)
+				let l:status_msg = ' ... failed!'
+			else
+				let l:status_msg = ' ... there were warnings!'
+			endif
+		else
+			let l:status_msg = ' ... success!'
+		endif
+		echomsg 'Compiling to ' . g:LatexBox_output_type . l:status_msg
+	endif
+endfunction
+
+" Redefine uniq() for compatibility with older Vim versions (< 7.4.218)
+function! s:uniq(list)
+        if exists('*uniq')
+                return uniq(a:list)
+        elseif len(a:list) <= 1
+                return a:list
+        endif
+
+        let last_element = get(a:list,0)
+        let uniq_list = [last_element]
+
+        for i in range(1, len(a:list)-1)
+                let next_element = get(a:list, i)
+                if last_element == next_element
+                        continue
+                endif
+                let last_element = next_element
+                call add(uniq_list, next_element)
+        endfor
+        return uniq_list
+endfunction
+
+function! s:log_contains_error(file)
+	let lines = readfile(a:file)
+	let lines = filter(lines, 'v:val =~ ''^.*:\d\+: ''')
+	let lines = s:uniq(map(lines, 'matchstr(v:val, ''^.*\ze:\d\+:'')'))
+	let lines = filter(lines, 'filereadable(fnameescape(v:val))')
+	return len(lines) > 0
+endfunction
+" }}}
+
+" LatexmkStatus {{{
+function! LatexBox_LatexmkStatus(detailed)
+	if a:detailed
+		if empty(g:latexmk_running_pids)
+			echo "latexmk is not running"
+		else
+			let plist = ""
+			for [basename, pid] in items(g:latexmk_running_pids)
+				if !empty(plist)
+					let plist .= '; '
+				endif
+				let plist .= fnamemodify(basename, ':t') . ':' . pid
+			endfor
+			echo "latexmk is running (" . plist . ")"
+		endif
+	else
+		let basename = LatexBox_GetBuildBasename(1)
+		if has_key(g:latexmk_running_pids, basename)
+			echo "latexmk is running"
+		else
+			echo "latexmk is not running"
+		endif
+	endif
+endfunction
+" }}}
+
+" LatexmkStop {{{
+function! LatexBox_LatexmkStop(silent)
+	if empty(g:latexmk_running_pids)
+		if !a:silent
+			let basepath = LatexBox_GetBuildBasename(1)
+			let basename = fnamemodify(basepath, ':t')
+			echoerr "latexmk is not running for `" . basename . "'"
+		endif
+	else
+		let basepath = LatexBox_GetBuildBasename(1)
+		let basename = fnamemodify(basepath, ':t')
+		if has_key(g:latexmk_running_pids, basepath)
+			call s:kill_latexmk_process(g:latexmk_running_pids[basepath])
+			call remove(g:latexmk_running_pids, basepath)
+			if !a:silent
+				echomsg "latexmk stopped for `" . basename . "'"
+			endif
+		elseif !a:silent
+			echoerr "latexmk is not running for `" . basename . "'"
+		endif
+	endif
+endfunction
+" }}}
+
+" Commands {{{
+
+command! -bang	Latexmk			call LatexBox_Latexmk(<q-bang> == "!")
+command! -bang	LatexmkClean	call LatexBox_LatexmkClean(<q-bang> == "!")
+command! -bang	LatexmkStatus	call LatexBox_LatexmkStatus(<q-bang> == "!")
+command! LatexmkStop			call LatexBox_LatexmkStop(0)
+command! LatexErrors			call LatexBox_LatexErrors(-1)
+
+if g:LatexBox_latexmk_async || g:LatexBox_latexmk_preview_continuously
+	autocmd BufUnload <buffer> 	call LatexBox_LatexmkStop(1)
+	autocmd VimLeave * 			call <SID>kill_all_latexmk_processes()
+endif
+
+" }}}
+
+" vim:fdm=marker:ff=unix:noet:ts=4:sw=4
+
+endif

ftplugin/latex-box/mappings.vim

@@ -0,0 +1,110 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" LaTeX Box mappings
+
+if exists("g:LatexBox_no_mappings")
+	finish
+endif
+
+" latexmk {{{
+noremap <buffer> <LocalLeader>ll :Latexmk<CR>
+noremap <buffer> <LocalLeader>lL :Latexmk!<CR>
+noremap <buffer> <LocalLeader>lc :LatexmkClean<CR>
+noremap <buffer> <LocalLeader>lC :LatexmkClean!<CR>
+noremap <buffer> <LocalLeader>lg :LatexmkStatus<CR>
+noremap <buffer> <LocalLeader>lG :LatexmkStatus!<CR>
+noremap <buffer> <LocalLeader>lk :LatexmkStop<CR>
+noremap <buffer> <LocalLeader>le :LatexErrors<CR>
+" }}}
+
+" View {{{
+noremap <buffer> <LocalLeader>lv :LatexView<CR>
+" }}}
+
+" TOC {{{
+noremap <silent> <buffer> <LocalLeader>lt :LatexTOC<CR>
+" }}}
+
+" List of labels {{{
+noremap <silent> <buffer> <LocalLeader>lj :LatexLabels<CR>
+" }}}
+
+" Folding {{{
+if g:LatexBox_Folding == 1
+	noremap <buffer> <LocalLeader>lf :LatexFold<CR>
+endif
+" }}}
+
+" Jump to match {{{
+if !exists('g:LatexBox_loaded_matchparen')
+	nmap <buffer> % <Plug>LatexBox_JumpToMatch
+	vmap <buffer> % <Plug>LatexBox_JumpToMatch
+	omap <buffer> % <Plug>LatexBox_JumpToMatch
+endif
+" }}}
+
+" Define text objects {{{
+vmap <buffer> ie <Plug>LatexBox_SelectCurrentEnvInner
+vmap <buffer> ae <Plug>LatexBox_SelectCurrentEnvOuter
+onoremap <buffer> ie :normal vie<CR>
+onoremap <buffer> ae :normal vae<CR>
+vmap <buffer> i$ <Plug>LatexBox_SelectInlineMathInner
+vmap <buffer> a$ <Plug>LatexBox_SelectInlineMathOuter
+onoremap <buffer> i$ :normal vi$<CR>
+onoremap <buffer> a$ :normal va$<CR>
+" }}}
+
+" Jump between sections {{{
+function! s:LatexBoxNextSection(type, backwards, visual)
+	" Restore visual mode if desired
+	if a:visual
+		normal! gv
+	endif
+
+	" For the [] and ][ commands we move up or down before the search
+	if a:type == 1
+		if a:backwards
+			normal! k
+		else
+			normal! j
+		endif
+	endif
+
+	" Define search pattern and do the search while preserving "/
+	let save_search = @/
+	let flags = 'W'
+	if a:backwards
+		let flags = 'b' . flags
+	endif
+	let notcomment = '\%(\%(\\\@<!\%(\\\\\)*\)\@<=%.*\)\@<!'
+	let pattern = notcomment . '\v\s*\\(' . join([
+				\ '(sub)*section',
+				\ 'chapter',
+				\ 'part',
+				\ 'appendix',
+				\ '(front|back|main)matter'], '|') . ')>'
+	call search(pattern, flags)
+	let @/ = save_search
+
+	" For the [] and ][ commands we move down or up after the search
+	if a:type == 1
+		if a:backwards
+			normal! j
+		else
+			normal! k
+		endif
+	endif
+endfunction
+noremap  <buffer> <silent> ]] :call <SID>LatexBoxNextSection(0,0,0)<CR>
+noremap  <buffer> <silent> ][ :call <SID>LatexBoxNextSection(1,0,0)<CR>
+noremap  <buffer> <silent> [] :call <SID>LatexBoxNextSection(1,1,0)<CR>
+noremap  <buffer> <silent> [[ :call <SID>LatexBoxNextSection(0,1,0)<CR>
+vnoremap <buffer> <silent> ]] :<c-u>call <SID>LatexBoxNextSection(0,0,1)<CR>
+vnoremap <buffer> <silent> ][ :<c-u>call <SID>LatexBoxNextSection(1,0,1)<CR>
+vnoremap <buffer> <silent> [] :<c-u>call <SID>LatexBoxNextSection(1,1,1)<CR>
+vnoremap <buffer> <silent> [[ :<c-u>call <SID>LatexBoxNextSection(0,1,1)<CR>
+" }}}
+
+" vim:fdm=marker:ff=unix:noet:ts=4:sw=4
+
+endif

ftplugin/latex-box/motion.vim

@@ -0,0 +1,548 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" LaTeX Box motion functions
+
+" Motion options {{{
+" Opening and closing patterns
+if !exists('g:LatexBox_open_pats')
+	let g:LatexBox_open_pats  = [ '\\{','{','\\(','(','\\\[','\[',
+				\ '\\begin\s*{.\{-}}', '\\left\s*\%([^\\]\|\\.\|\\\a*\)']
+	let g:LatexBox_close_pats = [ '\\}','}','\\)',')','\\\]','\]',
+				\ '\\end\s*{.\{-}}',   '\\right\s*\%([^\\]\|\\.\|\\\a*\)']
+endif
+" }}}
+
+" HasSyntax {{{
+" s:HasSyntax(syntaxName, [line], [col])
+function! s:HasSyntax(syntaxName, ...)
+	let line = a:0 >= 1 ? a:1 : line('.')
+	let col  = a:0 >= 2 ? a:2 : col('.')
+	return index(map(synstack(line, col),
+				\ 'synIDattr(v:val, "name") == "' . a:syntaxName . '"'),
+				\ 1) >= 0
+endfunction
+" }}}
+
+" Search and Skip Comments {{{
+" s:SearchAndSkipComments(pattern, [flags], [stopline])
+function! s:SearchAndSkipComments(pat, ...)
+	let flags		= a:0 >= 1 ? a:1 : ''
+	let stopline	= a:0 >= 2 ? a:2 : 0
+	let saved_pos = getpos('.')
+
+	" search once
+	let ret = search(a:pat, flags, stopline)
+
+	if ret
+		" do not match at current position if inside comment
+		let flags = substitute(flags, 'c', '', 'g')
+
+		" keep searching while in comment
+		while LatexBox_InComment()
+			let ret = search(a:pat, flags, stopline)
+			if !ret
+				break
+			endif
+		endwhile
+	endif
+
+	if !ret
+		" if no match found, restore position
+		call setpos('.', saved_pos)
+	endif
+
+	return ret
+endfunction
+" }}}
+
+" Finding Matching Pair {{{
+function! s:FindMatchingPair(mode)
+
+	if a:mode =~ 'h\|i'
+		2match none
+	elseif a:mode == 'v'
+		normal! gv
+	endif
+
+	if LatexBox_InComment() | return | endif
+
+	" open/close pairs (dollars signs are treated apart)
+	let dollar_pat = '\$'
+	let notbslash = '\%(\\\@<!\%(\\\\\)*\)\@<='
+	let notcomment = '\%(\%(\\\@<!\%(\\\\\)*\)\@<=%.*\)\@<!'
+	let anymatch =  '\('
+				\ . join(g:LatexBox_open_pats + g:LatexBox_close_pats, '\|')
+				\ . '\|' . dollar_pat . '\)'
+
+	let lnum = line('.')
+	let cnum = searchpos('\A', 'cbnW', lnum)[1]
+	" if the previous char is a backslash
+	if strpart(getline(lnum), cnum-2, 1) == '\'
+		let cnum = cnum-1
+	endif
+	let delim = matchstr(getline(lnum), '\C^'. anymatch , cnum - 1)
+
+	if empty(delim) || strlen(delim)+cnum-1< col('.')
+		if a:mode =~ 'n\|v\|o'
+			" if not found, search forward
+			let cnum = match(getline(lnum), '\C'. anymatch , col('.') - 1) + 1
+			if cnum == 0 | return | endif
+			call cursor(lnum, cnum)
+			let delim = matchstr(getline(lnum), '\C^'. anymatch , cnum - 1)
+		elseif a:mode =~ 'i'
+			" if not found, move one char bacward and search
+			let cnum = searchpos('\A', 'bnW', lnum)[1]
+			" if the previous char is a backslash
+			if strpart(getline(lnum), cnum-2, 1) == '\'
+				let cnum = cnum-1
+			endif
+			let delim = matchstr(getline(lnum), '\C^'. anymatch , cnum - 1)
+			if empty(delim) || strlen(delim)+cnum< col('.') | return | endif
+		elseif a:mode =~ 'h'
+			return
+		endif
+	endif
+
+	if delim =~ '^\$'
+
+		" match $-pairs
+		" check if next character is in inline math
+		let [lnum0, cnum0] = searchpos('.', 'nW')
+		if lnum0 && s:HasSyntax('texMathZoneX', lnum0, cnum0)
+			let [lnum2, cnum2] = searchpos(notcomment . notbslash. dollar_pat, 'nW', line('w$')*(a:mode =~ 'h\|i') , 200)
+		else
+			let [lnum2, cnum2] = searchpos('\%(\%'. lnum . 'l\%' . cnum . 'c\)\@!'. notcomment . notbslash . dollar_pat, 'bnW', line('w0')*(a:mode =~ 'h\|i') , 200)
+		endif
+
+		if a:mode =~ 'h\|i'
+			execute '2match MatchParen /\%(\%' . lnum . 'l\%' . cnum . 'c\$' . '\|\%' . lnum2 . 'l\%' . cnum2 . 'c\$\)/'
+		elseif a:mode =~ 'n\|v\|o'
+			call cursor(lnum2,cnum2)
+		endif
+
+	else
+		" match other pairs
+		for i in range(len(g:LatexBox_open_pats))
+			let open_pat = notbslash . g:LatexBox_open_pats[i]
+			let close_pat = notbslash . g:LatexBox_close_pats[i]
+
+			if delim =~# '^' . open_pat
+				" if on opening pattern, search for closing pattern
+				let [lnum2, cnum2] = searchpairpos('\C' . open_pat, '', '\C'
+							\ . close_pat, 'nW', 'LatexBox_InComment()',
+							\ line('w$')*(a:mode =~ 'h\|i') , 200)
+				if a:mode =~ 'h\|i'
+					execute '2match MatchParen /\%(\%' . lnum . 'l\%' . cnum
+								\ . 'c' . g:LatexBox_open_pats[i] . '\|\%'
+								\ . lnum2 . 'l\%' . cnum2 . 'c'
+								\ . g:LatexBox_close_pats[i] . '\)/'
+				elseif a:mode =~ 'n\|v\|o'
+					call cursor(lnum2,cnum2)
+					if strlen(close_pat)>1 && a:mode =~ 'o'
+						call cursor(lnum2, matchend(getline('.'), '\C'
+									\ . close_pat, col('.')-1))
+					endif
+				endif
+				break
+			elseif delim =~# '^' . close_pat
+				" if on closing pattern, search for opening pattern
+				let [lnum2, cnum2] =  searchpairpos('\C' . open_pat, '',
+							\ '\C\%(\%'. lnum . 'l\%' . cnum . 'c\)\@!'
+							\ . close_pat, 'bnW', 'LatexBox_InComment()',
+							\ line('w0')*(a:mode =~ 'h\|i') , 200)
+				if a:mode =~ 'h\|i'
+					execute '2match MatchParen /\%(\%' . lnum2 . 'l\%' . cnum2
+								\ . 'c' . g:LatexBox_open_pats[i] . '\|\%'
+								\ . lnum . 'l\%' . cnum . 'c'
+								\ . g:LatexBox_close_pats[i] . '\)/'
+				elseif a:mode =~ 'n\|v\|o'
+					call cursor(lnum2,cnum2)
+				endif
+				break
+			endif
+		endfor
+
+	endif
+endfunction
+
+" Allow to disable functionality if desired
+if !exists('g:LatexBox_loaded_matchparen')
+	" Disable matchparen autocommands
+	augroup LatexBox_HighlightPairs
+		autocmd BufEnter * if !exists("g:loaded_matchparen") || !g:loaded_matchparen | runtime plugin/matchparen.vim | endif
+		autocmd BufEnter *.tex 3match none | unlet! g:loaded_matchparen | au! matchparen
+		autocmd! CursorMoved *.tex call s:FindMatchingPair('h')
+		autocmd! CursorMovedI *.tex call s:FindMatchingPair('i')
+	augroup END
+endif
+
+" Use LatexBox'es FindMatchingPair as '%' (enable jump between e.g. $'s)
+nnoremap <silent> <Plug>LatexBox_JumpToMatch	:call <SID>FindMatchingPair('n')<CR>
+vnoremap <silent> <Plug>LatexBox_JumpToMatch	:call <SID>FindMatchingPair('v')<CR>
+onoremap <silent> <Plug>LatexBox_JumpToMatch	v:call <SID>FindMatchingPair('o')<CR>
+
+" }}}
+
+" select inline math {{{
+" s:SelectInlineMath(seltype)
+" where seltype is either 'inner' or 'outer'
+function! s:SelectInlineMath(seltype)
+
+	let dollar_pat = '\\\@<!\$'
+
+	if s:HasSyntax('texMathZoneX')
+		call s:SearchAndSkipComments(dollar_pat, 'cbW')
+	elseif getline('.')[col('.') - 1] == '$'
+		call s:SearchAndSkipComments(dollar_pat, 'bW')
+	else
+		return
+	endif
+
+	if a:seltype == 'inner'
+		normal! l
+	endif
+
+	if visualmode() ==# 'V'
+		normal! V
+	else
+		normal! v
+	endif
+
+	call s:SearchAndSkipComments(dollar_pat, 'W')
+
+	if a:seltype == 'inner'
+		normal! h
+	endif
+endfunction
+
+vnoremap <silent> <Plug>LatexBox_SelectInlineMathInner
+			\ :<C-U>call <SID>SelectInlineMath('inner')<CR>
+vnoremap <silent> <Plug>LatexBox_SelectInlineMathOuter
+			\ :<C-U>call <SID>SelectInlineMath('outer')<CR>
+" }}}
+
+" select current environment {{{
+function! s:SelectCurrentEnv(seltype)
+	let [env, lnum, cnum, lnum2, cnum2] = LatexBox_GetCurrentEnvironment(1)
+	call cursor(lnum, cnum)
+	if a:seltype == 'inner'
+		if env =~ '^\'
+			call search('\\.\_\s*\S', 'eW')
+		else
+			call search('}\(\_\s*\[\_[^]]*\]\)\?\_\s*\S', 'eW')
+		endif
+	endif
+	if visualmode() ==# 'V'
+		normal! V
+	else
+		normal! v
+	endif
+	call cursor(lnum2, cnum2)
+	if a:seltype == 'inner'
+		call search('\S\_\s*', 'bW')
+	else
+		if env =~ '^\'
+			normal! l
+		else
+			call search('}', 'eW')
+		endif
+	endif
+endfunction
+vnoremap <silent> <Plug>LatexBox_SelectCurrentEnvInner :<C-U>call <SID>SelectCurrentEnv('inner')<CR>
+vnoremap <silent> <Plug>LatexBox_SelectCurrentEnvOuter :<C-U>call <SID>SelectCurrentEnv('outer')<CR>
+" }}}
+
+" Jump to the next braces {{{
+"
+function! LatexBox_JumpToNextBraces(backward)
+	let flags = ''
+	if a:backward
+		normal h
+		let flags .= 'b'
+	else
+		let flags .= 'c'
+	endif
+	if search('[][}{]', flags) > 0
+		normal l
+	endif
+	let prev = strpart(getline('.'), col('.') - 2, 1)
+	let next = strpart(getline('.'), col('.') - 1, 1)
+	if next =~ '[]}]' && prev !~ '[][{}]'
+		return "\<Right>"
+	else
+		return ''
+	endif
+endfunction
+" }}}
+
+" Table of Contents {{{
+
+" Special UTF-8 conversion
+function! s:ConvertBack(line)
+	let line = a:line
+	if exists('g:LatexBox_plaintext_toc')
+		"
+		" Substitute stuff like '\IeC{\"u}' to plain 'u'
+		"
+		let line = substitute(line, '\\IeC\s*{\\.\(.\)}', '\1', 'g')
+	else
+		"
+		" Substitute stuff like '\IeC{\"u}' to corresponding unicode symbols
+		"
+		for [pat, symbol] in s:ConvBackPats
+			let line = substitute(line, pat, symbol, 'g')
+		endfor
+	endif
+	return line
+endfunction
+
+function! s:ReadTOC(auxfile, texfile, ...)
+	let texfile = a:texfile
+	let prefix = fnamemodify(a:auxfile, ':p:h')
+
+	if a:0 != 2
+		let toc = []
+		let fileindices = { texfile : [] }
+	else
+		let toc = a:1
+		let fileindices = a:2
+		let fileindices[ texfile ] = []
+	endif
+
+	for line in readfile(a:auxfile)
+		let included = matchstr(line, '^\\@input{\zs[^}]*\ze}')
+		if included != ''
+			" append the input TOX to `toc` and `fileindices`
+			let newaux = prefix . '/' . included
+			let newtex = fnamemodify(newaux, ':r') . '.tex'
+			call s:ReadTOC(newaux, newtex, toc, fileindices)
+			continue
+		endif
+
+		" Parse statements like:
+		" \@writefile{toc}{\contentsline {section}{\numberline {secnum}Section Title}{pagenumber}}
+		" \@writefile{toc}{\contentsline {section}{\tocsection {}{1}{Section Title}}{pagenumber}}
+		" \@writefile{toc}{\contentsline {section}{\numberline {secnum}Section Title}{pagenumber}{otherstuff}}
+
+		let line = matchstr(line,
+					\ '\\@writefile{toc}{\\contentsline\s*\zs.*\ze}\s*$')
+		if empty(line)
+			continue
+		endif
+
+		let tree = LatexBox_TexToTree(s:ConvertBack(line))
+
+		if len(tree) < 3
+			" unknown entry type: just skip it
+			continue
+		endif
+
+		" parse level
+		let level = tree[0][0]
+		" parse page
+		if !empty(tree[2])
+			let page = tree[2][0]
+		else
+			let page = ''
+		endif
+		" parse section number
+		let secnum = ''
+		let tree = tree[1]
+		if len(tree) > 3 && empty(tree[1])
+			call remove(tree, 1)
+		endif
+		if len(tree) > 1 && type(tree[0]) == type("") && tree[0] =~ '^\\\(\(chapter\)\?numberline\|tocsection\)'
+			let secnum = LatexBox_TreeToTex(tree[1])
+			let secnum = substitute(secnum, '\\\S\+\s', '', 'g')
+			let secnum = substitute(secnum, '\\\S\+{\(.\{-}\)}', '\1', 'g')
+			let secnum = substitute(secnum, '^{\+\|}\+$', '', 'g')
+			call remove(tree, 1)
+		endif
+		" parse section title
+		let text = LatexBox_TreeToTex(tree)
+		let text = substitute(text, '^{\+\|}\+$',                 '', 'g')
+		let text = substitute(text, '\m^\\\(no\)\?\(chapter\)\?numberline\s*', '', '')
+		let text = substitute(text, '\*',                         '', 'g')
+
+		" add TOC entry
+		call add(fileindices[texfile], len(toc))
+		call add(toc, {'file': texfile,
+					\ 'level': level,
+					\ 'number': secnum,
+					\ 'text': text,
+					\ 'page': page})
+	endfor
+
+	return [toc, fileindices]
+
+endfunction
+
+function! LatexBox_TOC(...)
+
+	" Check if window already exists
+	let winnr = bufwinnr(bufnr('LaTeX TOC'))
+	" Two types of splits, horizontal and vertical
+	let l:hori = "new"
+	let l:vert = "vnew"
+
+	" Set General Vars and initialize size
+	let l:type = g:LatexBox_split_type
+	let l:size = 10
+
+	" Size detection
+	if l:type == l:hori
+	  let l:size = g:LatexBox_split_length
+	elseif l:type == l:vert
+	  let l:size = g:LatexBox_split_width
+	endif
+
+	if winnr >= 0
+		if a:0 == 0
+			silent execute winnr . 'wincmd w'
+		else
+			" Supplying an argument to this function causes toggling instead
+			" of jumping to the TOC window
+			if g:LatexBox_split_resize
+				silent exe "set columns-=" . l:size
+			endif
+			silent execute 'bwipeout' . bufnr('LaTeX TOC')
+		endif
+		return
+	endif
+	" Read TOC
+	let [toc, fileindices] = s:ReadTOC(LatexBox_GetAuxFile(),
+									 \ LatexBox_GetMainTexFile())
+	let calling_buf = bufnr('%')
+
+	" Find closest section in current buffer
+	let closest_index = s:FindClosestSection(toc,fileindices)
+
+	" Create TOC window and set local settings
+	if g:LatexBox_split_resize
+		silent exe "set columns+=" . l:size
+	endif
+	silent exe g:LatexBox_split_side l:size . l:type . ' LaTeX\ TOC'
+
+	let b:toc = toc
+	let b:toc_numbers = 1
+	let b:calling_win = bufwinnr(calling_buf)
+	setlocal filetype=latextoc
+
+	" Add TOC entries and jump to the closest section
+	for entry in toc
+		call append('$', entry['number'] . "\t" . entry['text'])
+	endfor
+	if !g:LatexBox_toc_hidehelp
+		call append('$', "")
+		call append('$', "<Esc>/q: close")
+		call append('$', "<Space>: jump")
+		call append('$', "<Enter>: jump and close")
+		call append('$', "s:       hide numbering")
+	endif
+	0delete _
+
+	execute 'normal! ' . (closest_index + 1) . 'G'
+
+	" Lock buffer
+	setlocal nomodifiable
+endfunction
+
+" Binary search for the closest section
+" return the index of the TOC entry
+function! s:FindClosestSection(toc, fileindices)
+	let file = expand('%:p')
+	if !has_key(a:fileindices, file)
+		return 0
+	endif
+
+	let imax = len(a:fileindices[file])
+	if imax > 0
+		let imin = 0
+		while imin < imax - 1
+			let i = (imax + imin) / 2
+			let tocindex = a:fileindices[file][i]
+			let entry = a:toc[tocindex]
+			let titlestr = entry['text']
+			let titlestr = escape(titlestr, '\')
+			let titlestr = substitute(titlestr, ' ', '\\_\\s\\+', 'g')
+			let [lnum, cnum] = searchpos('\\' . entry['level'] . '\_\s*{' . titlestr . '}', 'nW')
+			if lnum
+				let imax = i
+			else
+				let imin = i
+			endif
+		endwhile
+		return a:fileindices[file][imin]
+	else
+		return 0
+	endif
+endfunction
+
+let s:ConvBackPats = map([
+			\ ['\\''A}'        , 'Á'],
+			\ ['\\`A}'         , 'À'],
+			\ ['\\^A}'         , 'À'],
+			\ ['\\¨A}'         , 'Ä'],
+			\ ['\\"A}'         , 'Ä'],
+			\ ['\\''a}'        , 'á'],
+			\ ['\\`a}'         , 'à'],
+			\ ['\\^a}'         , 'à'],
+			\ ['\\¨a}'         , 'ä'],
+			\ ['\\"a}'         , 'ä'],
+			\ ['\\''E}'        , 'É'],
+			\ ['\\`E}'         , 'È'],
+			\ ['\\^E}'         , 'Ê'],
+			\ ['\\¨E}'         , 'Ë'],
+			\ ['\\"E}'         , 'Ë'],
+			\ ['\\''e}'        , 'é'],
+			\ ['\\`e}'         , 'è'],
+			\ ['\\^e}'         , 'ê'],
+			\ ['\\¨e}'         , 'ë'],
+			\ ['\\"e}'         , 'ë'],
+			\ ['\\''I}'        , 'Í'],
+			\ ['\\`I}'         , 'Î'],
+			\ ['\\^I}'         , 'Ì'],
+			\ ['\\¨I}'         , 'Ï'],
+			\ ['\\"I}'         , 'Ï'],
+			\ ['\\''i}'        , 'í'],
+			\ ['\\`i}'         , 'î'],
+			\ ['\\^i}'         , 'ì'],
+			\ ['\\¨i}'         , 'ï'],
+			\ ['\\"i}'         , 'ï'],
+			\ ['\\''{\?\\i }'  , 'í'],
+			\ ['\\''O}'        , 'Ó'],
+			\ ['\\`O}'         , 'Ò'],
+			\ ['\\^O}'         , 'Ô'],
+			\ ['\\¨O}'         , 'Ö'],
+			\ ['\\"O}'         , 'Ö'],
+			\ ['\\''o}'        , 'ó'],
+			\ ['\\`o}'         , 'ò'],
+			\ ['\\^o}'         , 'ô'],
+			\ ['\\¨o}'         , 'ö'],
+			\ ['\\"o}'         , 'ö'],
+			\ ['\\''U}'        , 'Ú'],
+			\ ['\\`U}'         , 'Ù'],
+			\ ['\\^U}'         , 'Û'],
+			\ ['\\¨U}'         , 'Ü'],
+			\ ['\\"U}'         , 'Ü'],
+			\ ['\\''u}'        , 'ú'],
+			\ ['\\`u}'         , 'ù'],
+			\ ['\\^u}'         , 'û'],
+			\ ['\\¨u}'         , 'ü'],
+			\ ['\\"u}'         , 'ü'],
+			\ ['\\`N}'         , 'Ǹ'],
+			\ ['\\\~N}'        , 'Ñ'],
+			\ ['\\''n}'        , 'ń'],
+			\ ['\\`n}'         , 'ǹ'],
+			\ ['\\\~n}'        , 'ñ'],
+			\], '[''\C\(\\IeC\s*{\)\?'' . v:val[0], v:val[1]]')
+" }}}
+
+" TOC Command {{{
+command! LatexTOC call LatexBox_TOC()
+command! LatexTOCToggle call LatexBox_TOC(1)
+" }}}
+
+" vim:fdm=marker:ff=unix:noet:ts=4:sw=4
+
+endif

ftplugin/latextoc.vim

@@ -0,0 +1,206 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" {{{1 Settings
+setlocal buftype=nofile
+setlocal bufhidden=wipe
+setlocal nobuflisted
+setlocal noswapfile
+setlocal nowrap
+setlocal nospell
+setlocal cursorline
+setlocal nonumber
+setlocal nolist
+setlocal tabstop=8
+setlocal cole=0
+setlocal cocu=nvic
+if g:LatexBox_fold_toc
+    setlocal foldmethod=expr
+    setlocal foldexpr=TOCFoldLevel(v:lnum)
+    setlocal foldtext=TOCFoldText()
+endif
+" }}}1
+
+" {{{1 Functions
+" {{{2 TOCClose
+function! s:TOCClose()
+    if g:LatexBox_split_resize
+        silent exe "set columns-=" . g:LatexBox_split_width
+    endif
+    bwipeout
+endfunction
+
+" {{{2 TOCToggleNumbers
+function! s:TOCToggleNumbers()
+    if b:toc_numbers
+        setlocal conceallevel=3
+        let b:toc_numbers = 0
+    else
+        setlocal conceallevel=0
+        let b:toc_numbers = 1
+    endif
+endfunction
+
+" {{{2 EscapeTitle
+function! s:EscapeTitle(titlestr)
+    let titlestr = substitute(a:titlestr, '\\[a-zA-Z@]*\>\s*{\?', '.*', 'g')
+    let titlestr = substitute(titlestr, '}', '', 'g')
+    let titlestr = substitute(titlestr, '\%(\.\*\s*\)\{2,}', '.*', 'g')
+    return titlestr
+endfunction
+
+" {{{2 TOCActivate
+function! s:TOCActivate(close)
+    let n = getpos('.')[1] - 1
+
+    if n >= len(b:toc)
+        return
+    endif
+
+    let entry = b:toc[n]
+
+    let titlestr = s:EscapeTitle(entry['text'])
+
+    " Search for duplicates
+    "
+    let i=0
+    let entry_hash = entry['level'].titlestr
+    let duplicates = 0
+    while i<n
+        let i_entry = b:toc[n]
+        let i_hash = b:toc[i]['level'].s:EscapeTitle(b:toc[i]['text'])
+        if i_hash == entry_hash
+            let duplicates += 1
+        endif
+        let i += 1
+    endwhile
+    let toc_bnr = bufnr('%')
+    let toc_wnr = winnr()
+
+    execute b:calling_win . 'wincmd w'
+
+    let root = fnamemodify(entry['file'], ':h') . '/'
+    let files = [entry['file']]
+    for line in filter(readfile(entry['file']), 'v:val =~ ''\\input{''')
+        let file = matchstr(line, '{\zs.\{-}\ze\(\.tex\)\?}') . '.tex'
+        if file[0] != '/'
+            let file = root . file
+        endif
+        call add(files, file)
+    endfor
+
+    " Find section in buffer (or inputted files)
+    if entry['level'] == 'label'
+        let re = '\(\\label\_\s*{\|label\s*=\s*\)' . titlestr . '\>'
+    else
+        let re = '\\' . entry['level'] . '\_\s*{' . titlestr . '}'
+    endif
+    call s:TOCFindMatch(re, duplicates, files)
+
+    if a:close
+        if g:LatexBox_split_resize
+            silent exe "set columns-=" . g:LatexBox_split_width
+        endif
+        execute 'bwipeout ' . toc_bnr
+    else
+        execute toc_wnr . 'wincmd w'
+    endif
+endfunction
+
+" {{{2 TOCFindMatch
+function! s:TOCFindMatch(strsearch,duplicates,files)
+    if len(a:files) == 0
+        echoerr "Could not find: " . a:strsearch
+        return
+    endif
+
+    call s:TOCOpenBuf(a:files[0])
+    let dups = a:duplicates
+
+    " Skip duplicates
+    while dups > 0
+        if search(a:strsearch, 'w')
+            let dups -= 1
+        else
+            break
+        endif
+    endwhile
+
+    if search(a:strsearch, 'w')
+        normal! zv
+        return
+    endif
+
+    call s:TOCFindMatch(a:strsearch,dups,a:files[1:])
+endfunction
+
+" {{{2 TOCFoldLevel
+function! TOCFoldLevel(lnum)
+    let line  = getline(a:lnum)
+    let match_s1 = line =~# '^\w\+\s'
+    let match_s2 = line =~# '^\w\+\.\w\+\s'
+    let match_s3 = line =~# '^\w\+\.\w\+\.\w\+\s'
+
+    if g:LatexBox_fold_toc_levels >= 3
+        if match_s3
+            return ">3"
+        endif
+    endif
+
+    if g:LatexBox_fold_toc_levels >= 2
+        if match_s2
+            return ">2"
+        endif
+    endif
+
+    if match_s1
+        return ">1"
+    endif
+
+    " Don't fold options
+    if line =~# '^\s*$'
+        return 0
+    endif
+
+    " Return previous fold level
+    return "="
+endfunction
+
+" {{{2 TOCFoldText
+function! TOCFoldText()
+    let parts = matchlist(getline(v:foldstart), '^\(.*\)\t\(.*\)$')
+    return printf('%-8s%-72s', parts[1], parts[2])
+endfunction
+
+" {{{2 TOCOpenBuf
+function! s:TOCOpenBuf(file)
+
+    let bnr = bufnr(a:file)
+    if bnr == -1
+        execute 'badd ' . a:file
+        let bnr = bufnr(a:file)
+    endif
+    execute 'buffer! ' . bnr
+    normal! gg
+
+endfunction
+
+" }}}1
+
+" {{{1 Mappings
+nnoremap <buffer> <silent> s :call <SID>TOCToggleNumbers()<CR>
+nnoremap <buffer> <silent> q :call <SID>TOCClose()<CR>
+nnoremap <buffer> <silent> <Esc> :call <SID>TOCClose()<CR>
+nnoremap <buffer> <silent> <Space> :call <SID>TOCActivate(0)<CR>
+nnoremap <buffer> <silent> <CR> :call <SID>TOCActivate(1)<CR>
+nnoremap <buffer> <silent> <leftrelease> :call <SID>TOCActivate(0)<cr>
+nnoremap <buffer> <silent> <2-leftmouse> :call <SID>TOCActivate(1)<cr>
+nnoremap <buffer> <silent> G G4k
+nnoremap <buffer> <silent> <Esc>OA k
+nnoremap <buffer> <silent> <Esc>OB j
+nnoremap <buffer> <silent> <Esc>OC l
+nnoremap <buffer> <silent> <Esc>OD h
+" }}}1
+
+" vim:fdm=marker:ff=unix:et:ts=4:sw=4
+
+endif

ftplugin/tex_LatexBox.vim

@@ -0,0 +1,37 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" LaTeX Box plugin for Vim
+" Maintainer: David Munger
+" Email: mungerd@gmail.com
+" Version: 0.9.6
+
+if exists('*fnameescape')
+	function! s:FNameEscape(s)
+		return fnameescape(a:s)
+	endfunction
+else
+	function! s:FNameEscape(s)
+		return a:s
+	endfunction
+endif
+
+if !exists('b:LatexBox_loaded')
+
+	let prefix = expand('<sfile>:p:h') . '/latex-box/'
+
+	execute 'source ' . s:FNameEscape(prefix . 'common.vim')
+	execute 'source ' . s:FNameEscape(prefix . 'complete.vim')
+	execute 'source ' . s:FNameEscape(prefix . 'motion.vim')
+	execute 'source ' . s:FNameEscape(prefix . 'latexmk.vim')
+	execute 'source ' . s:FNameEscape(prefix . 'folding.vim')
+	" added by AH to add main.tex file finder
+	execute 'source ' . s:FNameEscape(prefix . 'findmain.vim')
+	execute 'source ' . s:FNameEscape(prefix . 'mappings.vim')
+
+	let b:LatexBox_loaded = 1
+
+endif
+
+" vim:fdm=marker:ff=unix:noet:ts=4:sw=4
+
+endif

ftplugin/vue.vim

@@ -13,6 +13,13 @@ runtime! ftplugin/html.vim
 
 setlocal suffixesadd+=.vue
 
+if !exists('g:no_plugin_maps') && !exists('g:no_vue_maps')
+  nnoremap <silent> <buffer> [[ :call search('^<\(template\<Bar>script\<Bar>style\)', 'bW')<CR>
+  nnoremap <silent> <buffer> ]] :call search('^<\(template\<Bar>script\<Bar>style\)', 'W')<CR>
+  nnoremap <silent> <buffer> [] :call search('^</\(template\<Bar>script\<Bar>style\)', 'bW')<CR>
+  nnoremap <silent> <buffer> ][ :call search('^</\(template\<Bar>script\<Bar>style\)', 'W')<CR>
+endif
+
 if exists('g:loaded_ale')
   let g:ale_linters = get(g:, 'ale_linters', {})
   let g:ale_linters.vue = get(g:ale_linters, 'vue', ['eslint'])

indent/cython.vim

@@ -0,0 +1,433 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'python-ident') == -1
+  
+" PEP8 compatible Python indent file
+" Language:         Python
+" Maintainer:       Daniel Hahler <https://daniel.hahler.de/>
+" Prev Maintainer:  Hynek Schlawack <hs@ox.cx>
+" Prev Maintainer:  Eric Mc Sween <em@tomcom.de> (address invalid)
+" Original Author:  David Bustos <bustos@caltech.edu> (address invalid)
+" License:          CC0
+"
+" vim-python-pep8-indent - A nicer Python indentation style for vim.
+" Written in 2004 by David Bustos <bustos@caltech.edu>
+" Maintained from 2004-2005 by Eric Mc Sween <em@tomcom.de>
+" Maintained from 2013 by Hynek Schlawack <hs@ox.cx>
+" Maintained from 2017 by Daniel Hahler <https://daniel.hahler.de/>
+"
+" To the extent possible under law, the author(s) have dedicated all copyright
+" and related and neighboring rights to this software to the public domain
+" worldwide. This software is distributed without any warranty.
+" You should have received a copy of the CC0 Public Domain Dedication along
+" with this software. If not, see
+" <http://creativecommons.org/publicdomain/zero/1.0/>.
+
+" Only load this indent file when no other was loaded.
+if exists('b:did_indent')
+    finish
+endif
+let b:did_indent = 1
+
+setlocal nolisp
+setlocal autoindent
+setlocal indentexpr=GetPythonPEPIndent(v:lnum)
+setlocal indentkeys=!^F,o,O,<:>,0),0],0},=elif,=except
+
+if !exists('g:python_pep8_indent_multiline_string')
+    let g:python_pep8_indent_multiline_string = 0
+endif
+
+let s:block_rules = {
+            \ '^\s*elif\>': ['if', 'elif'],
+            \ '^\s*except\>': ['try', 'except'],
+            \ '^\s*finally\>': ['try', 'except', 'else']
+            \ }
+let s:block_rules_multiple = {
+            \ '^\s*else\>': ['if', 'elif', 'for', 'try', 'except'],
+            \ }
+" Pairs to look for when searching for opening parenthesis.
+" The value is the maximum offset in lines.
+let s:paren_pairs = {'()': 50, '[]': 100, '{}': 1000}
+
+if &filetype ==# 'pyrex' || &filetype ==# 'cython'
+    let b:control_statement = '\v^\s*(class|def|if|while|with|for|except|cdef|cpdef)>'
+else
+    let b:control_statement = '\v^\s*(class|def|if|while|with|for|except)>'
+endif
+let s:stop_statement = '^\s*\(break\|continue\|raise\|return\|pass\)\>'
+
+" Skip strings and comments. Return 1 for chars to skip.
+" jedi* refers to syntax definitions from jedi-vim for call signatures, which
+" are inserted temporarily into the buffer.
+let s:skip_special_chars = 'synIDattr(synID(line("."), col("."), 0), "name") ' .
+            \ '=~? "\\vstring|comment|jedi\\S"'
+
+let s:skip_after_opening_paren = 'synIDattr(synID(line("."), col("."), 0), "name") ' .
+            \ '=~? "\\vcomment|jedi\\S"'
+
+" Also ignore anything concealed.
+" Wrapper around synconcealed for older Vim (7.3.429, used on Travis CI).
+function! s:is_concealed(line, col)
+    let concealed = synconcealed(a:line, a:col)
+    return len(concealed) && concealed[0]
+endfunction
+if has('conceal')
+    let s:skip_special_chars .= '|| s:is_concealed(line("."), col("."))'
+endif
+
+
+let s:skip_search = 'synIDattr(synID(line("."), col("."), 0), "name") ' .
+            \ '=~? "comment"'
+
+" Use 'shiftwidth()' instead of '&sw'.
+" (Since Vim patch 7.3.629, 'shiftwidth' can be set to 0 to follow 'tabstop').
+if exists('*shiftwidth')
+    function! s:sw()
+        return shiftwidth()
+    endfunction
+else
+    function! s:sw()
+        return &shiftwidth
+    endfunction
+endif
+
+function! s:pair_sort(x, y)
+    if a:x[0] == a:y[0]
+        return a:x[1] == a:y[1] ? 0 : a:x[1] > a:y[1] ? 1 : -1
+    else
+        return a:x[0] > a:y[0] ? 1 : -1
+    endif
+endfunction
+
+" Find backwards the closest open parenthesis/bracket/brace.
+function! s:find_opening_paren(...)
+    " optional arguments: line and column (defaults to 1) to search around
+    if a:0 > 0
+        let view = winsaveview()
+        call cursor(a:1, a:0 > 1 ? a:2 : 1)
+        let ret = s:find_opening_paren()
+        call winrestview(view)
+        return ret
+    endif
+
+    " Return if cursor is in a comment.
+    exe 'if' s:skip_search '| return [0, 0] | endif'
+
+    let nearest = [0, 0]
+    for [p, maxoff] in items(s:paren_pairs)
+        let stopline = max([0, line('.') - maxoff, nearest[0]])
+        let next = searchpairpos(
+           \ '\V'.p[0], '', '\V'.p[1], 'bnW', s:skip_special_chars, stopline)
+        if next[0] && (next[0] > nearest[0] || (next[0] == nearest[0] && next[1] > nearest[1]))
+            let nearest = next
+        endif
+    endfor
+    return nearest
+endfunction
+
+" Find the start of a multi-line statement
+function! s:find_start_of_multiline_statement(lnum)
+    let lnum = a:lnum
+    while lnum > 0
+        if getline(lnum - 1) =~# '\\$'
+            let lnum = prevnonblank(lnum - 1)
+        else
+            let [paren_lnum, _] = s:find_opening_paren(lnum)
+            if paren_lnum < 1
+                return lnum
+            else
+                let lnum = paren_lnum
+            endif
+        endif
+    endwhile
+endfunction
+
+" Find possible indent(s) of the block starter that matches the current line.
+function! s:find_start_of_block(lnum, types, multiple)
+    let r = []
+    let types = copy(a:types)
+    let re = '\V\^\s\*\('.join(a:types, '\|').'\)\>'
+    let lnum = a:lnum
+    let last_indent = indent(lnum) + 1
+    while lnum > 0 && last_indent > 0
+        let indent = indent(lnum)
+        if indent < last_indent
+            for type in types
+                let re = '\v^\s*'.type.'>'
+                if getline(lnum) =~# re
+                    if !a:multiple
+                        return [indent]
+                    endif
+                    if index(r, indent) == -1
+                        let r += [indent]
+                    endif
+                    " Remove any handled type, e.g. 'if'.
+                    call remove(types, index(types, type))
+                endif
+            endfor
+            let last_indent = indent(lnum)
+        endif
+        let lnum = prevnonblank(lnum - 1)
+    endwhile
+    return r
+endfunction
+
+" Is "expr" true for every position in "lnum", beginning at "start"?
+" (optionally up to a:1 / 4th argument)
+function! s:match_expr_on_line(expr, lnum, start, ...)
+    let text = getline(a:lnum)
+    let end = a:0 ? a:1 : len(text)
+    if a:start > end
+        return 1
+    endif
+    let save_pos = getpos('.')
+    let r = 1
+    for i in range(a:start, end)
+        call cursor(a:lnum, i)
+        if !(eval(a:expr) || text[i-1] =~# '\s')
+            let r = 0
+            break
+        endif
+    endfor
+    call setpos('.', save_pos)
+    return r
+endfunction
+
+" Line up with open parenthesis/bracket/brace.
+function! s:indent_like_opening_paren(lnum)
+    let [paren_lnum, paren_col] = s:find_opening_paren(a:lnum)
+    if paren_lnum <= 0
+        return -2
+    endif
+    let text = getline(paren_lnum)
+    let base = indent(paren_lnum)
+
+    let nothing_after_opening_paren = s:match_expr_on_line(
+                \ s:skip_after_opening_paren, paren_lnum, paren_col+1)
+    let starts_with_closing_paren = getline(a:lnum) =~# '^\s*[])}]'
+
+    if nothing_after_opening_paren
+        if starts_with_closing_paren
+            let res = base
+        else
+            let res = base + s:sw()
+        endif
+    else
+        " Indent to match position of opening paren.
+        let res = paren_col
+    endif
+
+    " If this line is the continuation of a control statement
+    " indent further to distinguish the continuation line
+    " from the next logical line.
+    if text =~# b:control_statement && res == base + s:sw()
+        return base + s:sw() * 2
+    else
+        return res
+    endif
+endfunction
+
+" Match indent of first block of this type.
+function! s:indent_like_block(lnum)
+    let text = getline(a:lnum)
+    for [multiple, block_rules] in [
+                \ [0, s:block_rules],
+                \ [1, s:block_rules_multiple]]
+        for [line_re, blocks] in items(block_rules)
+            if text !~# line_re
+                continue
+            endif
+
+            let indents = s:find_start_of_block(a:lnum - 1, blocks, multiple)
+            if !len(indents)
+                return -1
+            endif
+            if len(indents) == 1
+                return indents[0]
+            endif
+
+            " Multiple valid indents, e.g. for 'else' with both try and if.
+            let indent = indent(a:lnum)
+            if index(indents, indent) != -1
+                " The indent is valid, keep it.
+                return indent
+            endif
+            " Fallback to the first/nearest one.
+            return indents[0]
+        endfor
+    endfor
+    return -2
+endfunction
+
+function! s:indent_like_previous_line(lnum)
+    let lnum = prevnonblank(a:lnum - 1)
+
+    " No previous line, keep current indent.
+    if lnum < 1
+      return -1
+    endif
+
+    let text = getline(lnum)
+    let start = s:find_start_of_multiline_statement(lnum)
+    let base = indent(start)
+    let current = indent(a:lnum)
+
+    " Jump to last character in previous line.
+    call cursor(lnum, len(text))
+    let ignore_last_char = eval(s:skip_special_chars)
+
+    " Search for final colon that is not inside something to be ignored.
+    while 1
+        let curpos = getpos('.')[2]
+        if curpos == 1 | break | endif
+        if eval(s:skip_special_chars) || text[curpos-1] =~# '\s'
+            normal! h
+            continue
+        elseif text[curpos-1] ==# ':'
+            return base + s:sw()
+        endif
+        break
+    endwhile
+
+    if text =~# '\\$' && !ignore_last_char
+        " If this line is the continuation of a control statement
+        " indent further to distinguish the continuation line
+        " from the next logical line.
+        if getline(start) =~# b:control_statement
+            return base + s:sw() * 2
+        endif
+
+        " Nest (other) explicit continuations only one level deeper.
+        return base + s:sw()
+    endif
+
+    let empty = getline(a:lnum) =~# '^\s*$'
+
+    " Current and prev line are empty, next is not -> indent like next.
+    if empty && a:lnum > 1 &&
+          \ (getline(a:lnum - 1) =~# '^\s*$') &&
+          \ !(getline(a:lnum + 1) =~# '^\s*$')
+      return indent(a:lnum + 1)
+    endif
+
+    " If the previous statement was a stop-execution statement or a pass
+    if getline(start) =~# s:stop_statement
+        " Remove one level of indentation if the user hasn't already dedented
+        if empty || current > base - s:sw()
+            return base - s:sw()
+        endif
+        " Otherwise, trust the user
+        return -1
+    endif
+
+    if !empty && s:is_dedented_already(current, base)
+        return -1
+    endif
+
+    " In all other cases, line up with the start of the previous statement.
+    return base
+endfunction
+
+" If this line is dedented and the number of indent spaces is valid
+" (multiple of the indentation size), trust the user.
+function! s:is_dedented_already(current, base)
+    let dedent_size = a:current - a:base
+    return (dedent_size < 0 && a:current % s:sw() == 0) ? 1 : 0
+endfunction
+
+" Is the syntax at lnum (and optionally cnum) a python string?
+function! s:is_python_string(lnum, ...)
+    let line = getline(a:lnum)
+    let linelen = len(line)
+    if linelen < 1
+      let linelen = 1
+    endif
+    let cols = a:0 ? type(a:1) != type([]) ? [a:1] : a:1 : range(1, linelen)
+    for cnum in cols
+        if match(map(synstack(a:lnum, cnum),
+                    \ "synIDattr(v:val, 'name')"), 'python\S*String') == -1
+            return 0
+        end
+    endfor
+    return 1
+endfunction
+
+function! GetPythonPEPIndent(lnum)
+    " First line has indent 0
+    if a:lnum == 1
+        return 0
+    endif
+
+    let line = getline(a:lnum)
+    let prevline = getline(a:lnum-1)
+
+    " Multilinestrings: continous, docstring or starting.
+    if s:is_python_string(a:lnum-1, len(prevline))
+                \ && (s:is_python_string(a:lnum, 1)
+                \     || match(line, '^\%("""\|''''''\)') != -1)
+
+        " Indent closing quotes as the line with the opening ones.
+        let match_quotes = match(line, '^\s*\zs\%("""\|''''''\)')
+        if match_quotes != -1
+            " closing multiline string
+            let quotes = line[match_quotes:(match_quotes+2)]
+            let pairpos = searchpairpos(quotes, '', quotes, 'b')
+            if pairpos[0] != 0
+                return indent(pairpos[0])
+            else
+                " TODO: test to cover this!
+            endif
+        endif
+
+        if s:is_python_string(a:lnum-1)
+            " Previous line is (completely) a string.
+            return indent(a:lnum-1)
+        endif
+
+        if match(prevline, '^\s*\%("""\|''''''\)') != -1
+            " docstring.
+            return indent(a:lnum-1)
+        endif
+
+        let indent_multi = get(b:, 'python_pep8_indent_multiline_string',
+                    \ get(g:, 'python_pep8_indent_multiline_string', 0))
+        if match(prevline, '\v%("""|'''''')$') != -1
+            " Opening multiline string, started in previous line.
+            if (&autoindent && indent(a:lnum) == indent(a:lnum-1))
+                        \ || match(line, '\v^\s+$') != -1
+                " <CR> with empty line or to split up 'foo("""bar' into
+                " 'foo("""' and 'bar'.
+                if indent_multi == -2
+                    return indent(a:lnum-1) + s:sw()
+                endif
+                return indent_multi
+            endif
+        endif
+
+        " Keep existing indent.
+        if match(line, '\v^\s*\S') != -1
+            return -1
+        endif
+
+        if indent_multi != -2
+            return indent_multi
+        endif
+
+        return s:indent_like_opening_paren(a:lnum)
+    endif
+
+    " Parens: If we can find an open parenthesis/bracket/brace, line up with it.
+    let indent = s:indent_like_opening_paren(a:lnum)
+    if indent >= -1
+        return indent
+    endif
+
+    " Blocks: Match indent of first block of this type.
+    let indent = s:indent_like_block(a:lnum)
+    if indent >= -1
+        return indent
+    endif
+
+    return s:indent_like_previous_line(a:lnum)
+endfunction
+
+endif

indent/javascript.vim

@@ -360,10 +360,8 @@ function GetJavascriptIndent()
 
   " start with strings,comments,etc.
   if s:stack[-1] =~? 'comment\|doc'
-    if l:line =~ '^\s*\*'
-      return cindent(v:lnum)
-    elseif l:line !~ '^\s*\/[/*]'
-      return -1
+    if l:line !~ '^\s*\/[/*]'
+      return l:line =~ '^\s*\*' ? cindent(v:lnum) : -1
     endif
   elseif s:stack[-1] =~? b:syng_str
     if b:js_cache[0] == v:lnum - 1 && s:Balanced(v:lnum-1,getline(v:lnum-1))

indent/python.vim

@@ -1,217 +1,433 @@
-if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'python') == -1
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'python-ident') == -1
   
 " PEP8 compatible Python indent file
+" Language:         Python
+" Maintainer:       Daniel Hahler <https://daniel.hahler.de/>
+" Prev Maintainer:  Hynek Schlawack <hs@ox.cx>
+" Prev Maintainer:  Eric Mc Sween <em@tomcom.de> (address invalid)
+" Original Author:  David Bustos <bustos@caltech.edu> (address invalid)
+" License:          CC0
+"
+" vim-python-pep8-indent - A nicer Python indentation style for vim.
+" Written in 2004 by David Bustos <bustos@caltech.edu>
+" Maintained from 2004-2005 by Eric Mc Sween <em@tomcom.de>
+" Maintained from 2013 by Hynek Schlawack <hs@ox.cx>
+" Maintained from 2017 by Daniel Hahler <https://daniel.hahler.de/>
+"
+" To the extent possible under law, the author(s) have dedicated all copyright
+" and related and neighboring rights to this software to the public domain
+" worldwide. This software is distributed without any warranty.
+" You should have received a copy of the CC0 Public Domain Dedication along
+" with this software. If not, see
+" <http://creativecommons.org/publicdomain/zero/1.0/>.
+
 " Only load this indent file when no other was loaded.
-if exists("b:did_indent")
+if exists('b:did_indent')
     finish
 endif
 let b:did_indent = 1
 
-setlocal expandtab
 setlocal nolisp
 setlocal autoindent
 setlocal indentexpr=GetPythonPEPIndent(v:lnum)
 setlocal indentkeys=!^F,o,O,<:>,0),0],0},=elif,=except
 
-let s:maxoff = 50
+if !exists('g:python_pep8_indent_multiline_string')
+    let g:python_pep8_indent_multiline_string = 0
+endif
+
+let s:block_rules = {
+            \ '^\s*elif\>': ['if', 'elif'],
+            \ '^\s*except\>': ['try', 'except'],
+            \ '^\s*finally\>': ['try', 'except', 'else']
+            \ }
+let s:block_rules_multiple = {
+            \ '^\s*else\>': ['if', 'elif', 'for', 'try', 'except'],
+            \ }
+" Pairs to look for when searching for opening parenthesis.
+" The value is the maximum offset in lines.
+let s:paren_pairs = {'()': 50, '[]': 100, '{}': 1000}
+
+if &filetype ==# 'pyrex' || &filetype ==# 'cython'
+    let b:control_statement = '\v^\s*(class|def|if|while|with|for|except|cdef|cpdef)>'
+else
+    let b:control_statement = '\v^\s*(class|def|if|while|with|for|except)>'
+endif
+let s:stop_statement = '^\s*\(break\|continue\|raise\|return\|pass\)\>'
+
+" Skip strings and comments. Return 1 for chars to skip.
+" jedi* refers to syntax definitions from jedi-vim for call signatures, which
+" are inserted temporarily into the buffer.
+let s:skip_special_chars = 'synIDattr(synID(line("."), col("."), 0), "name") ' .
+            \ '=~? "\\vstring|comment|jedi\\S"'
+
+let s:skip_after_opening_paren = 'synIDattr(synID(line("."), col("."), 0), "name") ' .
+            \ '=~? "\\vcomment|jedi\\S"'
+
+" Also ignore anything concealed.
+" Wrapper around synconcealed for older Vim (7.3.429, used on Travis CI).
+function! s:is_concealed(line, col)
+    let concealed = synconcealed(a:line, a:col)
+    return len(concealed) && concealed[0]
+endfunction
+if has('conceal')
+    let s:skip_special_chars .= '|| s:is_concealed(line("."), col("."))'
+endif
+
+
+let s:skip_search = 'synIDattr(synID(line("."), col("."), 0), "name") ' .
+            \ '=~? "comment"'
+
+" Use 'shiftwidth()' instead of '&sw'.
+" (Since Vim patch 7.3.629, 'shiftwidth' can be set to 0 to follow 'tabstop').
+if exists('*shiftwidth')
+    function! s:sw()
+        return shiftwidth()
+    endfunction
+else
+    function! s:sw()
+        return &shiftwidth
+    endfunction
+endif
+
+function! s:pair_sort(x, y)
+    if a:x[0] == a:y[0]
+        return a:x[1] == a:y[1] ? 0 : a:x[1] > a:y[1] ? 1 : -1
+    else
+        return a:x[0] > a:y[0] ? 1 : -1
+    endif
+endfunction
 
 " Find backwards the closest open parenthesis/bracket/brace.
-function! s:SearchParensPair()
-  let line = line('.')
-  let col = col('.')
+function! s:find_opening_paren(...)
+    " optional arguments: line and column (defaults to 1) to search around
+    if a:0 > 0
+        let view = winsaveview()
+        call cursor(a:1, a:0 > 1 ? a:2 : 1)
+        let ret = s:find_opening_paren()
+        call winrestview(view)
+        return ret
+    endif
 
-  " Skip strings and comments and don't look too far
-  let skip = "line('.') < " . (line - s:maxoff) . " ? dummy :" .
-        \ 'synIDattr(synID(line("."), col("."), 0), "name") =~? ' .
-        \ '"string\\|comment"'
+    " Return if cursor is in a comment.
+    exe 'if' s:skip_search '| return [0, 0] | endif'
 
-  " Search for parentheses
-  call cursor(line, col)
-  let parlnum = searchpair('(', '', ')', 'bW', skip)
-  let parcol = col('.')
-
-  " Search for brackets
-  call cursor(line, col)
-  let par2lnum = searchpair('\[', '', '\]', 'bW', skip)
-  let par2col = col('.')
-
-  " Search for braces
-  call cursor(line, col)
-  let par3lnum = searchpair('{', '', '}', 'bW', skip)
-  let par3col = col('.')
-
-  " Get the closest match
-  if par2lnum > parlnum || (par2lnum == parlnum && par2col > parcol)
-    let parlnum = par2lnum
-    let parcol = par2col
-  endif
-  if par3lnum > parlnum || (par3lnum == parlnum && par3col > parcol)
-    let parlnum = par3lnum
-    let parcol = par3col
-  endif
-
-  " Put the cursor on the match
-  if parlnum > 0
-    call cursor(parlnum, parcol)
-  endif
-  return parlnum
+    let nearest = [0, 0]
+    for [p, maxoff] in items(s:paren_pairs)
+        let stopline = max([0, line('.') - maxoff, nearest[0]])
+        let next = searchpairpos(
+           \ '\V'.p[0], '', '\V'.p[1], 'bnW', s:skip_special_chars, stopline)
+        if next[0] && (next[0] > nearest[0] || (next[0] == nearest[0] && next[1] > nearest[1]))
+            let nearest = next
+        endif
+    endfor
+    return nearest
 endfunction
 
 " Find the start of a multi-line statement
-function! s:StatementStart(lnum)
-  let lnum = a:lnum
-  while 1
-    if getline(lnum - 1) =~ '\\$'
-      let lnum = lnum - 1
-    else
-      call cursor(lnum, 1)
-      let maybe_lnum = s:SearchParensPair()
-      if maybe_lnum < 1
-        return lnum
-      else
-        let lnum = maybe_lnum
-      endif
-    endif
-  endwhile
+function! s:find_start_of_multiline_statement(lnum)
+    let lnum = a:lnum
+    while lnum > 0
+        if getline(lnum - 1) =~# '\\$'
+            let lnum = prevnonblank(lnum - 1)
+        else
+            let [paren_lnum, _] = s:find_opening_paren(lnum)
+            if paren_lnum < 1
+                return lnum
+            else
+                let lnum = paren_lnum
+            endif
+        endif
+    endwhile
 endfunction
 
-" Find the block starter that matches the current line
-function! s:BlockStarter(lnum, block_start_re)
-  let lnum = a:lnum
-  let maxindent = 10000       " whatever
-  while lnum > 1
-    let lnum = prevnonblank(lnum - 1)
-    if indent(lnum) < maxindent
-      if getline(lnum) =~ a:block_start_re
-        return lnum
-      else
-        let maxindent = indent(lnum)
-        " It's not worth going further if we reached the top level
-        if maxindent == 0
-          return -1
+" Find possible indent(s) of the block starter that matches the current line.
+function! s:find_start_of_block(lnum, types, multiple)
+    let r = []
+    let types = copy(a:types)
+    let re = '\V\^\s\*\('.join(a:types, '\|').'\)\>'
+    let lnum = a:lnum
+    let last_indent = indent(lnum) + 1
+    while lnum > 0 && last_indent > 0
+        let indent = indent(lnum)
+        if indent < last_indent
+            for type in types
+                let re = '\v^\s*'.type.'>'
+                if getline(lnum) =~# re
+                    if !a:multiple
+                        return [indent]
+                    endif
+                    if index(r, indent) == -1
+                        let r += [indent]
+                    endif
+                    " Remove any handled type, e.g. 'if'.
+                    call remove(types, index(types, type))
+                endif
+            endfor
+            let last_indent = indent(lnum)
         endif
-      endif
+        let lnum = prevnonblank(lnum - 1)
+    endwhile
+    return r
+endfunction
+
+" Is "expr" true for every position in "lnum", beginning at "start"?
+" (optionally up to a:1 / 4th argument)
+function! s:match_expr_on_line(expr, lnum, start, ...)
+    let text = getline(a:lnum)
+    let end = a:0 ? a:1 : len(text)
+    if a:start > end
+        return 1
     endif
-  endwhile
-  return -1
+    let save_pos = getpos('.')
+    let r = 1
+    for i in range(a:start, end)
+        call cursor(a:lnum, i)
+        if !(eval(a:expr) || text[i-1] =~# '\s')
+            let r = 0
+            break
+        endif
+    endfor
+    call setpos('.', save_pos)
+    return r
+endfunction
+
+" Line up with open parenthesis/bracket/brace.
+function! s:indent_like_opening_paren(lnum)
+    let [paren_lnum, paren_col] = s:find_opening_paren(a:lnum)
+    if paren_lnum <= 0
+        return -2
+    endif
+    let text = getline(paren_lnum)
+    let base = indent(paren_lnum)
+
+    let nothing_after_opening_paren = s:match_expr_on_line(
+                \ s:skip_after_opening_paren, paren_lnum, paren_col+1)
+    let starts_with_closing_paren = getline(a:lnum) =~# '^\s*[])}]'
+
+    if nothing_after_opening_paren
+        if starts_with_closing_paren
+            let res = base
+        else
+            let res = base + s:sw()
+        endif
+    else
+        " Indent to match position of opening paren.
+        let res = paren_col
+    endif
+
+    " If this line is the continuation of a control statement
+    " indent further to distinguish the continuation line
+    " from the next logical line.
+    if text =~# b:control_statement && res == base + s:sw()
+        return base + s:sw() * 2
+    else
+        return res
+    endif
+endfunction
+
+" Match indent of first block of this type.
+function! s:indent_like_block(lnum)
+    let text = getline(a:lnum)
+    for [multiple, block_rules] in [
+                \ [0, s:block_rules],
+                \ [1, s:block_rules_multiple]]
+        for [line_re, blocks] in items(block_rules)
+            if text !~# line_re
+                continue
+            endif
+
+            let indents = s:find_start_of_block(a:lnum - 1, blocks, multiple)
+            if !len(indents)
+                return -1
+            endif
+            if len(indents) == 1
+                return indents[0]
+            endif
+
+            " Multiple valid indents, e.g. for 'else' with both try and if.
+            let indent = indent(a:lnum)
+            if index(indents, indent) != -1
+                " The indent is valid, keep it.
+                return indent
+            endif
+            " Fallback to the first/nearest one.
+            return indents[0]
+        endfor
+    endfor
+    return -2
+endfunction
+
+function! s:indent_like_previous_line(lnum)
+    let lnum = prevnonblank(a:lnum - 1)
+
+    " No previous line, keep current indent.
+    if lnum < 1
+      return -1
+    endif
+
+    let text = getline(lnum)
+    let start = s:find_start_of_multiline_statement(lnum)
+    let base = indent(start)
+    let current = indent(a:lnum)
+
+    " Jump to last character in previous line.
+    call cursor(lnum, len(text))
+    let ignore_last_char = eval(s:skip_special_chars)
+
+    " Search for final colon that is not inside something to be ignored.
+    while 1
+        let curpos = getpos('.')[2]
+        if curpos == 1 | break | endif
+        if eval(s:skip_special_chars) || text[curpos-1] =~# '\s'
+            normal! h
+            continue
+        elseif text[curpos-1] ==# ':'
+            return base + s:sw()
+        endif
+        break
+    endwhile
+
+    if text =~# '\\$' && !ignore_last_char
+        " If this line is the continuation of a control statement
+        " indent further to distinguish the continuation line
+        " from the next logical line.
+        if getline(start) =~# b:control_statement
+            return base + s:sw() * 2
+        endif
+
+        " Nest (other) explicit continuations only one level deeper.
+        return base + s:sw()
+    endif
+
+    let empty = getline(a:lnum) =~# '^\s*$'
+
+    " Current and prev line are empty, next is not -> indent like next.
+    if empty && a:lnum > 1 &&
+          \ (getline(a:lnum - 1) =~# '^\s*$') &&
+          \ !(getline(a:lnum + 1) =~# '^\s*$')
+      return indent(a:lnum + 1)
+    endif
+
+    " If the previous statement was a stop-execution statement or a pass
+    if getline(start) =~# s:stop_statement
+        " Remove one level of indentation if the user hasn't already dedented
+        if empty || current > base - s:sw()
+            return base - s:sw()
+        endif
+        " Otherwise, trust the user
+        return -1
+    endif
+
+    if !empty && s:is_dedented_already(current, base)
+        return -1
+    endif
+
+    " In all other cases, line up with the start of the previous statement.
+    return base
+endfunction
+
+" If this line is dedented and the number of indent spaces is valid
+" (multiple of the indentation size), trust the user.
+function! s:is_dedented_already(current, base)
+    let dedent_size = a:current - a:base
+    return (dedent_size < 0 && a:current % s:sw() == 0) ? 1 : 0
+endfunction
+
+" Is the syntax at lnum (and optionally cnum) a python string?
+function! s:is_python_string(lnum, ...)
+    let line = getline(a:lnum)
+    let linelen = len(line)
+    if linelen < 1
+      let linelen = 1
+    endif
+    let cols = a:0 ? type(a:1) != type([]) ? [a:1] : a:1 : range(1, linelen)
+    for cnum in cols
+        if match(map(synstack(a:lnum, cnum),
+                    \ "synIDattr(v:val, 'name')"), 'python\S*String') == -1
+            return 0
+        end
+    endfor
+    return 1
 endfunction
 
 function! GetPythonPEPIndent(lnum)
-  let scol = col('.')
-
-  " First line has indent 0
-  if a:lnum == 1
-    return 0
-  endif
-
-  " If we can find an open parenthesis/bracket/brace, line up with it.
-  call cursor(a:lnum, 1)
-  let parlnum = s:SearchParensPair()
-  if parlnum > 0
-    let parcol = col('.')
-    let matches = matchlist(getline(a:lnum), '^\(\s*\)[])}]')
-    if len(matches) == 0
-      let closing_paren = 0
-      let closing_paren_pos = 0
-    else
-      let closing_paren = 1
-      let closing_paren_pos = len(matches[1])
+    " First line has indent 0
+    if a:lnum == 1
+        return 0
     endif
-    if match(getline(parlnum), '[([{]\s*$', parcol - 1) != -1
-      if closing_paren
-        return indent(parlnum)
-      else
-        return indent(parlnum) + &shiftwidth
-      endif
-    elseif a:lnum - 1 != parlnum
-      if closing_paren && closing_paren_pos > scol
-        return indent(parlnum)
-      else
-        let lastindent = match(getline(a:lnum - 1), '\S')
-        if lastindent != -1 && lastindent < parcol
-          return lastindent
+
+    let line = getline(a:lnum)
+    let prevline = getline(a:lnum-1)
+
+    " Multilinestrings: continous, docstring or starting.
+    if s:is_python_string(a:lnum-1, len(prevline))
+                \ && (s:is_python_string(a:lnum, 1)
+                \     || match(line, '^\%("""\|''''''\)') != -1)
+
+        " Indent closing quotes as the line with the opening ones.
+        let match_quotes = match(line, '^\s*\zs\%("""\|''''''\)')
+        if match_quotes != -1
+            " closing multiline string
+            let quotes = line[match_quotes:(match_quotes+2)]
+            let pairpos = searchpairpos(quotes, '', quotes, 'b')
+            if pairpos[0] != 0
+                return indent(pairpos[0])
+            else
+                " TODO: test to cover this!
+            endif
         endif
-      endif
+
+        if s:is_python_string(a:lnum-1)
+            " Previous line is (completely) a string.
+            return indent(a:lnum-1)
+        endif
+
+        if match(prevline, '^\s*\%("""\|''''''\)') != -1
+            " docstring.
+            return indent(a:lnum-1)
+        endif
+
+        let indent_multi = get(b:, 'python_pep8_indent_multiline_string',
+                    \ get(g:, 'python_pep8_indent_multiline_string', 0))
+        if match(prevline, '\v%("""|'''''')$') != -1
+            " Opening multiline string, started in previous line.
+            if (&autoindent && indent(a:lnum) == indent(a:lnum-1))
+                        \ || match(line, '\v^\s+$') != -1
+                " <CR> with empty line or to split up 'foo("""bar' into
+                " 'foo("""' and 'bar'.
+                if indent_multi == -2
+                    return indent(a:lnum-1) + s:sw()
+                endif
+                return indent_multi
+            endif
+        endif
+
+        " Keep existing indent.
+        if match(line, '\v^\s*\S') != -1
+            return -1
+        endif
+
+        if indent_multi != -2
+            return indent_multi
+        endif
+
+        return s:indent_like_opening_paren(a:lnum)
     endif
 
-    " If we line up with an opening column there is a special case
-    " we want to handle: a docstring as argument.  In that case we
-    " don't want to line up with the paren but with the statement
-    " imagine foo(doc=""" as example
-    echo getline(parlnum)
-    if match(getline(parlnum), '\("""\|' . "'''" . '\)\s*$') != -1
-      return indent(parlnum)
+    " Parens: If we can find an open parenthesis/bracket/brace, line up with it.
+    let indent = s:indent_like_opening_paren(a:lnum)
+    if indent >= -1
+        return indent
     endif
 
-    return parcol
-  endif
-
-  " Examine this line
-  let thisline = getline(a:lnum)
-  let thisindent = indent(a:lnum)
-
-  " If the line starts with 'elif' or 'else', line up with 'if' or 'elif'
-  if thisline =~ '^\s*\(elif\|else\)\>'
-    let bslnum = s:BlockStarter(a:lnum, '^\s*\(if\|elif\)\>')
-    if bslnum > 0
-      return indent(bslnum)
-    else
-      return -1
+    " Blocks: Match indent of first block of this type.
+    let indent = s:indent_like_block(a:lnum)
+    if indent >= -1
+        return indent
     endif
-  endif
 
-  " If the line starts with 'except' or 'finally', line up with 'try'
-  " or 'except'
-  if thisline =~ '^\s*\(except\|finally\)\>'
-    let bslnum = s:BlockStarter(a:lnum, '^\s*\(try\|except\)\>')
-    if bslnum > 0
-      return indent(bslnum)
-    else
-      return -1
-    endif
-  endif
-
-  " Examine previous line
-  let plnum = a:lnum - 1
-  let pline = getline(plnum)
-  let sslnum = s:StatementStart(plnum)
-
-  " If the previous line is blank, keep the same indentation
-  if pline =~ '^\s*$'
-    return -1
-  endif
-
-  " If this line is explicitly joined, try to find an indentation that looks
-  " good.
-  if pline =~ '\\$'
-    let compound_statement = '^\s*\(if\|while\|from\|import\|for\s.*\sin\|except\)\s*'
-    let maybe_indent = matchend(getline(sslnum), compound_statement)
-    if maybe_indent != -1
-      return maybe_indent
-    else
-      return indent(sslnum) + &sw * 2
-    endif
-  endif
-
-  " If the previous line ended with a colon and is not a comment, indent
-  " relative to statement start.
-  if pline =~ '^[^#]*:\s*\(#.*\)\?$'
-    return indent(sslnum) + &sw
-  endif
-
-  " If the previous line was a stop-execution statement or a pass
-  if getline(sslnum) =~ '^\s*\(break\|continue\|raise\|return\|pass\)\>'
-    " See if the user has already dedented
-    if indent(a:lnum) > indent(sslnum) - &sw
-      " If not, recommend one dedent
-      return indent(sslnum) - &sw
-    endif
-    " Otherwise, trust the user
-    return -1
-  endif
-
-  " In all other cases, line up with the start of the previous statement.
-  return indent(sslnum)
+    return s:indent_like_previous_line(a:lnum)
 endfunction
 
 endif

indent/tex.vim

@@ -0,0 +1,140 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+" LaTeX indent file (part of LaTeX Box)
+" Maintainer: David Munger (mungerd@gmail.com)
+
+if exists("g:LatexBox_custom_indent") && ! g:LatexBox_custom_indent
+	finish
+endif
+if exists("b:did_indent")
+	finish
+endif
+
+let b:did_indent = 1
+
+setlocal indentexpr=LatexBox_TexIndent()
+setlocal indentkeys=0=\\end,0=\\end{enumerate},0=\\end{itemize},0=\\end{description},0=\\right,0=\\item,0=\\),0=\\],0},o,O,0\\
+
+let s:list_envs = ['itemize', 'enumerate', 'description']
+" indent on \left( and on \(, but not on (
+" indent on \left[ and on \[, but not on [
+" indent on \left\{ and on {, but not on \{
+let s:open_pat = '\\\@<!\%(\\begin\|\\left\a\@!\|\\(\|\\\[\|{\)'
+let s:close_pat = '\\\@<!\%(\\end\|\\right\a\@!\|\\)\|\\\]\|}\)'
+let s:list_open_pat = '\\\@<!\\begin{\%(' . join(s:list_envs, '\|') . '\)}'
+let s:list_close_pat	= '\\\@<!\\end{\%(' . join(s:list_envs, '\|') . '\)}'
+
+function! s:CountMatches(str, pat)
+	return len(substitute(substitute(a:str, a:pat, "\n", 'g'), "[^\n]", '', 'g'))
+endfunction
+
+
+" TexIndent {{{
+function! LatexBox_TexIndent()
+
+	let lnum_curr = v:lnum
+	let lnum_prev = prevnonblank(lnum_curr - 1)
+
+	if lnum_prev == 0
+		return 0
+	endif
+
+	let line_curr = getline(lnum_curr)
+	let line_prev = getline(lnum_prev)
+
+	" remove \\
+	let line_curr = substitute(line_curr, '\\\\', '', 'g')
+	let line_prev = substitute(line_prev, '\\\\', '', 'g')
+
+	" strip comments
+	let line_curr = substitute(line_curr, '\\\@<!%.*$', '', 'g')
+	let line_prev = substitute(line_prev, '\\\@<!%.*$', '', 'g')
+
+	" find unmatched opening patterns on previous line
+	let n = s:CountMatches(line_prev, s:open_pat)-s:CountMatches(line_prev, s:close_pat)
+	let n += s:CountMatches(line_prev, s:list_open_pat)-s:CountMatches(line_prev, s:list_close_pat)
+
+	" reduce indentation if current line starts with a closing pattern
+	if line_curr =~ '^\s*\%(' . s:close_pat . '\)'
+		let n -= 1
+	endif
+
+	" compensate indentation if previous line starts with a closing pattern
+	if line_prev =~ '^\s*\%(' . s:close_pat . '\)'
+		let n += 1
+	endif
+
+	" reduce indentation if current line starts with a closing list
+	if line_curr =~ '^\s*\%(' . s:list_close_pat . '\)'
+		let n -= 1
+	endif
+
+	" compensate indentation if previous line starts with a closing list
+	if line_prev =~ '^\s*\%(' . s:list_close_pat . '\)'
+		let n += 1
+	endif
+
+	" reduce indentation if previous line is \begin{document}
+	if line_prev =~ '\\begin\s*{document}'
+		let n -= 1
+	endif
+
+	" less shift for lines starting with \item
+	let item_here =  line_curr =~ '^\s*\\item'
+	let item_above = line_prev =~ '^\s*\\item'
+	if !item_here && item_above
+		let n += 1
+	elseif item_here && !item_above
+		let n -= 1
+	endif
+
+	return indent(lnum_prev) + n * &sw
+endfunction
+" }}}
+
+" Restore cursor position, window position, and last search after running a
+" command.
+function! Latexbox_CallIndent()
+  " Save the current cursor position.
+  let cursor = getpos('.')
+
+  " Save the current window position.
+  normal! H
+  let window = getpos('.')
+  call setpos('.', cursor)
+
+  " Get first non-whitespace character of current line.
+  let line_start_char = matchstr(getline('.'), '\S')
+
+  " Get initial tab position.
+  let initial_tab = stridx(getline('.'), line_start_char)
+
+  " Execute the command.
+  execute 'normal! =='
+
+  " Get tab position difference.
+  let difference = stridx(getline('.'), line_start_char) - initial_tab
+
+  " Set new cursor Y position based on calculated difference.
+  let cursor[2] = cursor[2] + difference
+
+  " Restore the previous window position.
+  call setpos('.', window)
+  normal! zt
+
+  " Restore the previous cursor position.
+  call setpos('.', cursor)
+endfunction
+
+" autocmd to call indent after completion
+" 7.3.598
+if v:version > 703 || (v:version == 703 && has('patch598'))
+	augroup LatexBox_Completion
+		autocmd!
+		autocmd CompleteDone <buffer> call Latexbox_CallIndent()
+	augroup END
+endif
+
+" vim:fdm=marker:ff=unix:noet:ts=4:sw=4
+
+endif

syntax/carp.vim

@@ -0,0 +1,127 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'carp') == -1
+  
+" Vim syntax file
+" Language:     Carp
+" Maintainer:   Veit Heller <veit@veitheller.de>
+" URL:          http://github.com/hellerve/carp-vim.git
+" Description:  Contains all of the keywords in #lang carp
+
+if exists("b:current_syntax")
+  finish
+endif
+
+syn match carpError ,[]})],
+
+if version < 600
+  set iskeyword=33,35-39,42-43,45-58,60-63,65-90,94,95,97-122,124,126,_
+else
+  setlocal iskeyword=33,35-39,42-43,45-58,60-63,65-90,94,95,97-122,124,126,_
+endif
+
+syn keyword carpSyntax def defn let do if while ref address set! the
+syn keyword carpSyntax defmacro defdynamic quote car cdr cons list array
+syn keyword carpSyntax expand deftype register system-include register-type
+syn keyword carpSyntax defmodule copy use module defalias definterface eval
+syn keyword carpSyntax expand instantiate type info help quit env build run
+syn keyword carpSyntax cat use project-set! local-include system-include
+syn keyword carpSyntax add-cflag add-lib project load reload
+
+syn keyword carpFunc Int Float Double Bool String Char Array Fn Ref Long
+syn keyword carpFunc not or and + - * / = /= >= <= > < inc dec
+syn keyword carpFunc println print get-line from-string mod seed random
+syn keyword carpFunc random-between str mask delete append count duplicate
+syn keyword carpFunc cstr chars from-chars to-int from-int sin cos sqrt acos
+syn keyword carpFunc atan2 exit time srand for cond floor abs neg to-float
+syn keyword carpFunc from-float tan asin atan cosh sinh tanh exp frexp ldexp
+syn keyword carpFunc log log10 modf pow ceil clamp approx refstr foreach
+syn keyword carpFunc => ==> repeat nth replicate range raw aset aset! count
+syn keyword carpFunc push-back pop-back sort index-of element-count
+
+
+syn match carpSymbol ,\k+,  contained
+syn match carpTodo /\v<(FIXME|NOTE|TODO|OPTIMIZE)/ containedin=carpComment,carpString
+
+syn cluster carpNormal  contains=carpSyntax,carpFunc,carpDelimiter
+syn cluster carpQuotedStuff  contains=carpSymbol
+syn cluster carpQuotedOrNormal  contains=carpDelimiter
+
+syn region carpQuotedStruc start="@("rs=s+2 end=")"re=e-1 contains=@carpQuotedStuff,@carpQuotedOrNormal contained
+syn region carpQuotedStruc start="&("rs=s+2 end=")"re=e-1 contains=@carpQuotedStuff,@carpQuotedOrNormal contained
+syn region carpQuotedStruc start="("rs=s+1 end=")"re=e-1 contains=@carpQuotedStuff,@carpQuotedOrNormal contained
+syn region carpQuotedStruc start="\["rs=s+1 end="\]"re=e-1 contains=@carpQuotedStuff,@carpQuotedOrNormal contained
+
+syn cluster carpQuotedStuff add=carpQuotedStruc
+
+syn region carpStruc matchgroup=Delimiter start="@("rs=s+2 matchgroup=Delimiter end=")"re=e-1 contains=@carpNormal
+syn region carpStruc matchgroup=Delimiter start="&("rs=s+2 matchgroup=Delimiter end=")"re=e-1 contains=@carpNormal
+syn region carpStruc matchgroup=Delimiter start="&"rs=s+1 end=![ \t()\[\]";]!me=e-1 contains=@carpNormal
+syn region carpStruc matchgroup=Delimiter start="@"rs=s+1 end=![ \t()\[\]";]!me=e-1 contains=@carpNormal
+syn region carpStruc matchgroup=Delimiter start="("rs=s+1 matchgroup=Delimiter end=")"re=e-1 contains=@carpNormal
+syn region carpStruc matchgroup=Delimiter start="\["rs=s+1 matchgroup=Delimiter end="\]"re=e-1 contains=@carpNormal
+
+syn region carpString start=/\%(\\\)\@<!"/ skip=/\\[\\"]/ end=/"/
+
+syn cluster carpNormal          add=carpError,carpStruc,carpString
+syn cluster carpQuotedOrNormal  add=carpString
+
+syn match carpNumber    "\<[-+]\?\(\d\+\|\d\+#*\.\|\d*\.\d\+\)#*\(/\d\+#*\)\?[lf]\?\>" contains=carpContainedNumberError
+syn match carpNumber    "\<[-+]\?\d\+/\d\+[lf]\?\>" contains=carpContainedNumberError
+
+
+syn keyword carpBoolean  true false
+
+syn match carpChar    "\<\\.\w\@!"
+
+syn region carpQuoted matchgroup=Delimiter start="['`]" end=![ \t()\[\]";]!me=e-1 contains=@carpQuotedStuff,@carpQuotedOrNormal
+syn region carpQuoted matchgroup=Delimiter start="['`](" matchgroup=Delimiter end=")" contains=@carpQuotedStuff,@carpQuotedOrNormal
+
+syn cluster carpNormal  add=carpNumber,carpBoolean,carpChar
+syn cluster carpQuotedOrNormal  add=carpNumber,carpBoolean
+
+syn match carpComment /;.*$/ contains=@Spell
+
+syn region carpQuoted matchgroup=Delimiter start="#['`]"rs=s+2 end=![ \t()\[\]";]!re=e-1,me=e-1 contains=@carpQuotedStuff,@carpQuotedOrNormal
+syn region carpQuoted matchgroup=Delimiter start="#['`]("rs=s+3 matchgroup=Delimiter end=")"re=e-1 contains=@carpQuotedStuff,@carpQuotedOrNormal
+
+syn cluster carpNormal  add=carpQuoted,carpComment
+syn cluster carpQuotedOrNormal  add=carpComment
+
+syn sync match matchPlace grouphere NONE "^[^ \t]"
+
+if version >= 508 || !exists("carp_syntax_init")
+  if version < 508
+    let carp_syntax_init = 1
+    command -nargs=+ HiLink hi link <args>
+  else
+    command -nargs=+ HiLink hi def link <args>
+  endif
+
+  HiLink carpSyntax             Statement
+  HiLink carpFunc               Function
+  HiLink carpCopy               Function
+
+  HiLink carpString             String
+  HiLink carpChar               Character
+  HiLink carpBoolean            Boolean
+
+  HiLink carpNumber             Number
+  HiLink carpNumberError        Error
+  HiLink carpContainedNumberError Error
+
+  HiLink carpQuoted             Structure
+  HiLink carpQuotedStruc        Structure
+  HiLink carpSymbol             Structure
+  HiLink carpAtom               Structure
+
+  HiLink carpDelimiter          Delimiter
+  HiLink carpConstant           Constant
+
+  HiLink carpTodo               Todo
+  HiLink carpComment            Comment
+  HiLink carpError              Error
+  delcommand HiLink
+endif
+
+let b:current_syntax = "carp"
+
+endif

syntax/elixir.vim

@@ -64,9 +64,10 @@ syn match elixirVariable '&\d\+'
 
 syn keyword elixirPseudoVariable __FILE__ __DIR__ __MODULE__ __ENV__ __CALLER__
 
-syn match elixirNumber '\<\d\(_\?\d\)*\(\.[^[:space:][:digit:]]\@!\(_\?\d\)*\)\?\([eE][-+]\?\d\(_\?\d\)*\)\?\>'
-syn match elixirNumber '\<0[xX][0-9A-Fa-f]\+\>'
-syn match elixirNumber '\<0[bB][01]\+\>'
+syn match elixirNumber '\<-\?\d\(_\?\d\)*\(\.[^[:space:][:digit:]]\@!\(_\?\d\)*\)\?\([eE][-+]\?\d\(_\?\d\)*\)\?\>'
+syn match elixirNumber '\<-\?0[xX][0-9A-Fa-f]\+\>'
+syn match elixirNumber '\<-\?0[oO][0-7]\+\>'
+syn match elixirNumber '\<-\?0[bB][01]\+\>'
 
 syn match elixirRegexEscape            "\\\\\|\\[aAbBcdDefGhHnrsStvVwW]\|\\\d\{3}\|\\x[0-9a-fA-F]\{2}" contained
 syn match elixirRegexEscapePunctuation "?\|\\.\|*\|\\\[\|\\\]\|+\|\\^\|\\\$\|\\|\|\\(\|\\)\|\\{\|\\}" contained

syntax/go.vim

@@ -40,6 +40,10 @@ if !exists("g:go_highlight_functions")
   let g:go_highlight_functions = 0
 endif
 
+if !exists("g:go_highlight_function_arguments")
+  let g:go_highlight_function_arguments = 0
+endif
+
 if !exists("g:go_highlight_methods")
   let g:go_highlight_methods = 0
 endif
@@ -96,7 +100,7 @@ if exists("g:go_fold_enable")
   if index(g:go_fold_enable, 'package_comment') == -1
     let s:fold_package_comment = 0
   endif
- 
+
   " Disabled by default.
   if index(g:go_fold_enable, 'comment') > -1
     let s:fold_comment = 1
@@ -231,14 +235,14 @@ endif
 " var, const
 if s:fold_varconst
   syn region    goVar               start='var ('   end='^\s*)$' transparent fold
-                        \ contains=ALLBUT,goParen,goBlock,goFunction,goTypeName,goReceiverType,goReceiverVar
+                        \ contains=ALLBUT,goParen,goBlock,goFunction,goTypeName,goReceiverType,goReceiverVar,goArgumentName,goArgumentType,goSimpleArguments
   syn region    goConst             start='const (' end='^\s*)$' transparent fold
-                        \ contains=ALLBUT,goParen,goBlock,goFunction,goTypeName,goReceiverType,goReceiverVar
+                        \ contains=ALLBUT,goParen,goBlock,goFunction,goTypeName,goReceiverType,goReceiverVar,goArgumentName,goArgumentType,goSimpleArguments
 else
-  syn region    goVar               start='var ('   end='^\s*)$' transparent 
-                        \ contains=ALLBUT,goParen,goBlock,goFunction,goTypeName,goReceiverType,goReceiverVar
+  syn region    goVar               start='var ('   end='^\s*)$' transparent
+                        \ contains=ALLBUT,goParen,goBlock,goFunction,goTypeName,goReceiverType,goReceiverVar,goArgumentName,goArgumentType,goSimpleArguments
   syn region    goConst             start='const (' end='^\s*)$' transparent
-                        \ contains=ALLBUT,goParen,goBlock,goFunction,goTypeName,goReceiverType,goReceiverVar
+                        \ contains=ALLBUT,goParen,goBlock,goFunction,goTypeName,goReceiverType,goReceiverVar,goArgumentName,goArgumentType,goSimpleArguments
 endif
 
 " Single-line var, const, and import.
@@ -345,14 +349,22 @@ endif
 hi def link     goOperator          Operator
 
 " Functions;
-if g:go_highlight_functions != 0
-  syn match goDeclaration       /\<func\>/ nextgroup=goReceiver,goFunction skipwhite skipnl
-  syn match goReceiver          /(\(\w\|[ *]\)\+)/ contained nextgroup=goFunction contains=goReceiverVar skipwhite skipnl
-  syn match goReceiverVar       /\w\+/ nextgroup=goPointerOperator,goReceiverType skipwhite skipnl contained
+if g:go_highlight_functions isnot 0 || g:go_highlight_function_arguments isnot 0
+  syn match goFunctionCall      /\w\+\ze(/ contains=goBuiltins,goDeclaration
+  syn match goDeclaration       /\<func\>/ nextgroup=goReceiver,goFunction,goSimpleArguments skipwhite skipnl
+  syn match goReceiverVar       /\w\+\ze\s\+\(\w\|\*\)/ nextgroup=goPointerOperator,goReceiverType skipwhite skipnl contained
   syn match goPointerOperator   /\*/ nextgroup=goReceiverType contained skipwhite skipnl
+  syn match goFunction          /\w\+/ nextgroup=goSimpleArguments contained skipwhite skipnl
   syn match goReceiverType      /\w\+/ contained
-  syn match goFunction          /\w\+/ contained
-  syn match goFunctionCall      /\w\+\ze(/ contains=GoBuiltins,goDeclaration
+if g:go_highlight_function_arguments isnot 0
+  syn match goSimpleArguments   /(\(\w\|\_s\|[*\.\[\],\{\}<>-]\)*)/ contained contains=goArgumentName nextgroup=goSimpleArguments skipwhite skipnl
+  syn match goArgumentName      /\w\+\(\s*,\s*\w\+\)*\ze\s\+\(\w\|\.\|\*\|\[\)/ contained nextgroup=goArgumentType skipwhite skipnl
+  syn match goArgumentType      /\([^,)]\|\_s\)\+,\?/ contained nextgroup=goArgumentName skipwhite skipnl
+                        \ contains=goVarArgs,goType,goSignedInts,goUnsignedInts,goFloats,goComplexes,goDeclType,goBlock
+  hi def link   goReceiverVar       goArgumentName
+  hi def link   goArgumentName      Identifier
+endif
+  syn match goReceiver          /(\s*\w\+\(\s\+\*\?\s*\w\+\)\?\s*)\ze\s*\w/ contained nextgroup=goFunction contains=goReceiverVar skipwhite skipnl
 else
   syn keyword goDeclaration func
 endif

syntax/json5.vim

@@ -0,0 +1,56 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'json5') == -1
+  
+" Syntax setup {{{1
+if exists('b:current_syntax') && b:current_syntax == 'json5'
+  finish
+endif
+
+" Syntax: Strings {{{1
+syn region  json5String    start=+"+  skip=+\\\\\|\\"+  end=+"+  contains=json5Escape
+syn region  json5String    start=+'+  skip=+\\\\\|\\'+  end=+'+  contains=json5Escape
+
+" Syntax: Escape sequences
+syn match   json5Escape    "\\["\\/bfnrt]" contained
+syn match   json5Escape    "\\u\x\{4}" contained
+
+" Syntax: Numbers {{{1
+syn match   json5Number    "-\=\<\%(0\|[1-9]\d*\)\%(\.\d\+\)\=\%([eE][-+]\=\d\+\)\=\>"
+syn keyword json5Number    Infinity -Infinity
+
+" Syntax: An integer part of 0 followed by other digits is not allowed.
+syn match   json5NumError  "-\=\<0\d\.\d*\>"
+
+" Syntax: Boolean {{{1
+syn keyword json5Boolean   true false
+
+" Syntax: Null {{{1
+syn keyword json5Null      null
+
+" Syntax: Braces {{{1
+syn match   json5Braces	   "[{}\[\]]"
+syn match   json5ObjAssign /@\?\%(\I\|\$\)\%(\i\|\$\)*\s*\ze::\@!/
+
+" Syntax: Comment {{{1
+syn region  json5LineComment    start=+\/\/+ end=+$+ keepend
+syn region  json5LineComment    start=+^\s*\/\/+ skip=+\n\s*\/\/+ end=+$+ keepend fold
+syn region  json5Comment        start="/\*"  end="\*/" fold
+
+" Define the default highlighting. {{{1
+hi def link json5String             String
+hi def link json5ObjAssign          Identifier
+hi def link json5Escape             Special
+hi def link json5Number             Number
+hi def link json5Braces             Operator
+hi def link json5Null               Function
+hi def link json5Boolean            Boolean
+hi def link json5LineComment        Comment
+hi def link json5Comment            Comment
+hi def link json5NumError           Error
+
+if !exists('b:current_syntax')
+  let b:current_syntax = 'json5'
+endif
+
+" vim: fdm=marker
+
+endif

syntax/latextoc.vim

@@ -0,0 +1,13 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'latex') == -1
+  
+syntax match helpText /^.*: .*/
+syntax match secNum /^\S\+\(\.\S\+\)\?\s*/ contained conceal
+syntax match secLine /^\S\+\t.\+/ contains=secNum
+syntax match mainSecLine /^[^\.]\+\t.*/ contains=secNum
+syntax match ssubSecLine /^[^\.]\+\.[^\.]\+\.[^\.]\+\t.*/ contains=secNum
+highlight link helpText		PreProc
+highlight link secNum		Number
+highlight link mainSecLine	Title
+highlight link ssubSecLine	Comment
+
+endif

syntax/markdown.vim

@@ -110,11 +110,9 @@ syn match  mkdCode         /^\s*\n\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/ containe
 syn match  mkdListItem     /^\s*\%([-*+]\|\d\+\.\)\ze\s\+/ contained
 syn region mkdListItemLine start="^\s*\%([-*+]\|\d\+\.\)\s\+" end="$" oneline contains=@mkdNonListItem,mkdListItem,@Spell
 syn region mkdNonListItemBlock start="\(\%^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@!\|\n\(\_^\_$\|\s\{4,}[^ ]\|\t+[^\t]\)\@!\)" end="^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@=" contains=@mkdNonListItem,@Spell
-syn match  mkdRule         /^\s*\*\s\{0,1}\*\s\{0,1}\*$/
-syn match  mkdRule         /^\s*-\s\{0,1}-\s\{0,1}-$/
-syn match  mkdRule         /^\s*_\s\{0,1}_\s\{0,1}_$/
-syn match  mkdRule         /^\s*-\{3,}$/
-syn match  mkdRule         /^\s*\*\{3,5}$/
+syn match  mkdRule         /^\s*\*\s\{0,1}\*\s\{0,1}\*\(\*\|\s\)*$/
+syn match  mkdRule         /^\s*-\s\{0,1}-\s\{0,1}-\(-\|\s\)*$/
+syn match  mkdRule         /^\s*_\s\{0,1}_\s\{0,1}_\(_\|\s\)*$/
 
 " YAML frontmatter
 if get(g:, 'vim_markdown_frontmatter', 0)

syntax/proto.vim

@@ -61,6 +61,7 @@ syn keyword pbRepeat     optional required repeated
 syn keyword pbDefault    default
 syn keyword pbExtend     extend extensions to max reserved
 syn keyword pbRPC        service rpc returns
+syn keyword pbStream     stream
 
 syn keyword pbType      int32 int64 uint32 uint64 sint32 sint64
 syn keyword pbType      fixed32 fixed64 sfixed32 sfixed64
@@ -92,6 +93,7 @@ if version >= 508 || !exists("did_proto_syn_inits")
   HiLink pbDefault      Keyword
   HiLink pbExtend       Keyword
   HiLink pbRPC          Keyword
+  HiLink pbStream       Keyword
   HiLink pbType         Type
   HiLink pbTypedef      Typedef
   HiLink pbBool         Boolean

syntax/python.vim

@@ -1,326 +1,487 @@
 if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'python') == -1
   
-" Vim syntax file
-"
-" Based on python.vim (from Vim 6.1 distribution)
-" by Neil Schemenauer <nas@python.ca>
-"
-" Notes Armin:
-"
-"     This version of the syntax file works better for 2.x and 3.x without
-"     having to switch modes.
-"
-" Thanks:
-"
-"    Jeroen Ruigrok van der Werven
-"        for the idea of highlighting for erroneous operators
-"    Pedro Algarvio
-"        for the patch to enable spell checking only for the right spots
-"        (strings and comments)
-
-"
-" Options:
-"
-"    For set option do: let OPTION_NAME = 1
-"    For clear option do: let OPTION_NAME = 0
-"
-" Option names:
-"
-"    For highlight builtin functions:
-"       python_highlight_builtins
-"
-"    For highlight standard exceptions:
-"       python_highlight_exceptions
-"
-"    For highlight string formatting:
-"       python_highlight_string_formatting
-"
-"    For highlight indentation errors:
-"       python_highlight_indent_errors
-"
-"    For highlight trailing spaces:
-"       python_highlight_space_errors
-"
-"    For highlight doc-tests:
-"       python_highlight_doctests
-"
-"    If you want all possible Python highlighting:
-"    (This option not override previously set options)
-"       python_highlight_all
-"
-"    For fast machines:
-"       python_slow_sync
-"
-
 " For version 5.x: Clear all syntax items
-" For version 6.x: Quit when a syntax file was already loaded
-if version < 600
+" For versions greater than 6.x: Quit when a syntax file was already loaded
+if v:version < 600
   syntax clear
-elseif exists("b:current_syntax")
+elseif exists('b:current_syntax')
   finish
 endif
 
-if exists("python_highlight_all") && python_highlight_all != 0
-  " Not override previously set options
-  if !exists("python_highlight_builtins")
-    let python_highlight_builtins = 1
+"
+" Commands
+"
+command! -buffer Python2Syntax let b:python_version_2 = 1 | let &syntax=&syntax
+command! -buffer Python3Syntax let b:python_version_2 = 0 | let &syntax=&syntax
+
+" Enable option if it's not defined
+function! s:EnableByDefault(name)
+  if !exists(a:name)
+    let {a:name} = 1
   endif
-  if !exists("python_highlight_exceptions")
-    let python_highlight_exceptions = 1
+endfunction
+
+" Check if option is enabled
+function! s:Enabled(name)
+  return exists(a:name) && {a:name}
+endfunction
+
+" Is it Python 2 syntax?
+function! s:Python2Syntax()
+  if exists('b:python_version_2')
+      return b:python_version_2
   endif
-  if !exists("python_highlight_string_formatting")
-    let python_highlight_string_formatting = 1
-  endif
-  if !exists("python_highlight_indent_errors")
-    let python_highlight_indent_errors = 1
-  endif
-  if !exists("python_highlight_space_errors")
-    let python_highlight_space_errors = 1
-  endif
-  if !exists("python_highlight_doctests")
-    let python_highlight_doctests = 1
+  return s:Enabled('g:python_version_2')
+endfunction
+
+"
+" Default options
+"
+
+call s:EnableByDefault('g:python_slow_sync')
+call s:EnableByDefault('g:python_highlight_builtin_funcs_kwarg')
+
+if s:Enabled('g:python_highlight_all')
+  call s:EnableByDefault('g:python_highlight_builtins')
+  if s:Enabled('g:python_highlight_builtins')
+    call s:EnableByDefault('g:python_highlight_builtin_objs')
+    call s:EnableByDefault('g:python_highlight_builtin_funcs')
   endif
+  call s:EnableByDefault('g:python_highlight_exceptions')
+  call s:EnableByDefault('g:python_highlight_string_formatting')
+  call s:EnableByDefault('g:python_highlight_string_format')
+  call s:EnableByDefault('g:python_highlight_string_templates')
+  call s:EnableByDefault('g:python_highlight_indent_errors')
+  call s:EnableByDefault('g:python_highlight_space_errors')
+  call s:EnableByDefault('g:python_highlight_doctests')
+  call s:EnableByDefault('g:python_print_as_function')
+  call s:EnableByDefault('g:python_highlight_class_vars')
+  call s:EnableByDefault('g:python_highlight_operators')
 endif
 
+"
 " Keywords
-syn keyword pythonStatement	break continue del
-syn keyword pythonStatement	exec return
-syn keyword pythonStatement	pass raise
-syn keyword pythonStatement	global assert
-syn keyword pythonStatement	lambda yield
-syn keyword pythonStatement	async await
-syn keyword pythonStatement	with nonlocal True False None
-syn keyword pythonStatement	def class nextgroup=pythonFunction skipwhite
-syn match   pythonFunction	"[a-zA-Z_][a-zA-Z0-9_]*" display contained
-syn keyword pythonRepeat	for while
-syn keyword pythonConditional	if elif else
-syn keyword pythonImport	import from as
-syn keyword pythonException	try except finally
-syn keyword pythonOperator	and in is not or
+"
 
-" Print keyword but only if not used as function
-syn match pythonStatement "\<print\>\((\|,\|*=\)\@!" display
+syn keyword pythonStatement     break continue del return pass yield global assert lambda with
+syn keyword pythonStatement     raise nextgroup=pythonExClass skipwhite
+syn keyword pythonStatement     def class nextgroup=pythonFunction skipwhite
+if s:Enabled('g:python_highlight_class_vars')
+  syn keyword pythonClassVar    self cls
+endif
+syn keyword pythonRepeat        for while
+syn keyword pythonConditional   if elif else
+syn keyword pythonException     try except finally
+" The standard pyrex.vim unconditionally removes the pythonInclude group, so
+" we provide a dummy group here to avoid crashing pyrex.vim.
+syn keyword pythonInclude       import
+syn keyword pythonImport        import
+syn match pythonRaiseFromStatement      '\<from\>'
+syn match pythonImport          '^\s*\zsfrom\>'
 
+
+if s:Python2Syntax()
+  if !s:Enabled('g:python_print_as_function')
+    syn keyword pythonStatement  print
+  endif
+  syn keyword pythonStatement   exec
+  syn keyword pythonImport      as
+  syn match   pythonFunction    '[a-zA-Z_][a-zA-Z0-9_]*' display contained
+else
+  syn keyword pythonStatement   as nonlocal
+  syn match   pythonStatement   '\v\.@<!<await>'
+  syn match   pythonFunction    '\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*' display contained
+  syn match   pythonStatement   '\<async\s\+def\>' nextgroup=pythonFunction skipwhite
+  syn match   pythonStatement   '\<async\s\+with\>'
+  syn match   pythonStatement   '\<async\s\+for\>'
+  syn cluster pythonExpression contains=pythonStatement,pythonRepeat,pythonConditional,pythonOperator,pythonNumber,pythonHexNumber,pythonOctNumber,pythonBinNumber,pythonFloat,pythonString,pythonBytes,pythonBoolean,pythonBuiltinObj,pythonBuiltinFunc
+endif
+
+
+"
+" Operators
+"
+syn keyword pythonOperator      and in is not or
+if s:Enabled('g:python_highlight_operators')
+    syn match pythonOperator        '\V=\|-\|+\|*\|@\|/\|%\|&\||\|^\|~\|<\|>\|!='
+endif
+syn match pythonError           '[$?]\|\([-+@%&|^~]\)\1\{1,}\|\([=*/<>]\)\2\{2,}\|\([+@/%&|^~<>]\)\3\@![-+*@/%&|^~<>]\|\*\*[*@/%&|^<>]\|=[*@/%&|^<>]\|-[+*@/%&|^~<]\|[<!>]\+=\{2,}\|!\{2,}=\+' display
+
+"
 " Decorators (new in Python 2.4)
-syn match   pythonDecorator	"@" display nextgroup=pythonFunction skipwhite
+"
 
+syn match   pythonDecorator    '^\s*\zs@' display nextgroup=pythonDottedName skipwhite
+if s:Python2Syntax()
+  syn match   pythonDottedName '[a-zA-Z_][a-zA-Z0-9_]*\%(\.[a-zA-Z_][a-zA-Z0-9_]*\)*' display contained
+else
+  syn match   pythonDottedName '\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\%(\.\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\)*' display contained
+endif
+syn match   pythonDot        '\.' display containedin=pythonDottedName
+
+"
 " Comments
-syn match   pythonComment	"#.*$" display contains=pythonTodo,@Spell
-syn match   pythonRun		"\%^#!.*$"
-syn match   pythonCoding	"\%^.*\(\n.*\)\?#.*coding[:=]\s*[0-9A-Za-z-_.]\+.*$"
-syn keyword pythonTodo		TODO FIXME XXX contained
+"
 
+syn match   pythonComment       '#.*$' display contains=pythonTodo,@Spell
+if !s:Enabled('g:python_highlight_file_headers_as_comments')
+  syn match   pythonRun         '\%^#!.*$'
+  syn match   pythonCoding      '\%^.*\%(\n.*\)\?#.*coding[:=]\s*[0-9A-Za-z-_.]\+.*$'
+endif
+syn keyword pythonTodo          TODO FIXME XXX contained
+
+"
 " Errors
-syn match pythonError		"\<\d\+\D\+\>" display
-syn match pythonError		"[$?]" display
-syn match pythonError		"[-+&|]\{2,}" display
-syn match pythonError		"[=]\{3,}" display
+"
 
-" TODO: Mixing spaces and tabs also may be used for pretty formatting multiline
-" statements. For now I don't know how to work around this.
-if exists("python_highlight_indent_errors") && python_highlight_indent_errors != 0
-  syn match pythonIndentError	"^\s*\( \t\|\t \)\s*\S"me=e-1 display
+syn match pythonError           '\<\d\+[^0-9[:space:]]\+\>' display
+
+" Mixing spaces and tabs also may be used for pretty formatting multiline
+" statements
+if s:Enabled('g:python_highlight_indent_errors')
+  syn match pythonIndentError   '^\s*\%( \t\|\t \)\s*\S'me=e-1 display
 endif
 
 " Trailing space errors
-if exists("python_highlight_space_errors") && python_highlight_space_errors != 0
-  syn match pythonSpaceError	"\s\+$" display
+if s:Enabled('g:python_highlight_space_errors')
+  syn match pythonSpaceError    '\s\+$' display
 endif
 
+"
 " Strings
-syn region pythonString		start=+'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonEscape,pythonEscapeError,@Spell
-syn region pythonString		start=+"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonEscape,pythonEscapeError,@Spell
-syn region pythonString		start=+"""+ end=+"""+ keepend contains=pythonEscape,pythonEscapeError,pythonDocTest2,pythonSpaceError,@Spell
-syn region pythonString		start=+'''+ end=+'''+ keepend contains=pythonEscape,pythonEscapeError,pythonDocTest,pythonSpaceError,@Spell
+"
 
-syn match  pythonEscape		+\\[abfnrtv'"\\]+ display contained
-syn match  pythonEscape		"\\\o\o\=\o\=" display contained
-syn match  pythonEscapeError	"\\\o\{,2}[89]" display contained
-syn match  pythonEscape		"\\x\x\{2}" display contained
-syn match  pythonEscapeError	"\\x\x\=\X" display contained
-syn match  pythonEscape		"\\$"
+if s:Python2Syntax()
+  " Python 2 strings
+  syn region pythonString   start=+[bB]\='+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
+  syn region pythonString   start=+[bB]\="+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
+  syn region pythonString   start=+[bB]\="""+ skip=+\\"+ end=+"""+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
+  syn region pythonString   start=+[bB]\='''+ skip=+\\'+ end=+'''+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
+else
+  " Python 3 byte strings
+  syn region pythonBytes    start=+[bB]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesError,pythonBytesContent,@Spell
+  syn region pythonBytes    start=+[bB]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesError,pythonBytesContent,@Spell
+  syn region pythonBytes    start=+[bB]'''+ skip=+\\'+ end=+'''+ keepend contains=pythonBytesError,pythonBytesContent,pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonBytes    start=+[bB]"""+ skip=+\\"+ end=+"""+ keepend contains=pythonBytesError,pythonBytesContent,pythonDocTest2,pythonSpaceError,@Spell
 
-" Byte-Strings
-syn region pythonBString	start=+[bB]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBEscape,pythonBEscapeError,@Spell
-syn region pythonBString	start=+[bB]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBEscape,pythonBEscapeError,@Spell
-syn region pythonBString	start=+[bB]"""+ end=+"""+ keepend contains=pythonBEscape,pythonBEscapeError,pythonDocTest2,pythonSpaceError,@Spell
-syn region pythonBString	start=+[bB]'''+ end=+'''+ keepend contains=pythonBEscape,pythonBEscapeError,pythonDocTest,pythonSpaceError,@Spell
-
-syn match  pythonBEscape	+\\[abfnrtv'"\\]+ display contained
-syn match  pythonBEscape	"\\\o\o\=\o\=" display contained
-syn match  pythonBEscapeError	"\\\o\{,2}[89]" display contained
-syn match  pythonBEscape	"\\x\x\{2}" display contained
-syn match  pythonBEscapeError	"\\x\x\=\X" display contained
-syn match  pythonBEscape	"\\$"
-
-" Unicode strings
-syn region pythonUniString	start=+[uU]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonEscape,pythonUniEscape,pythonEscapeError,pythonUniEscapeError,@Spell
-syn region pythonUniString	start=+[uU]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonEscape,pythonUniEscape,pythonEscapeError,pythonUniEscapeError,@Spell
-syn region pythonUniString	start=+[uU]"""+ end=+"""+ keepend contains=pythonEscape,pythonUniEscape,pythonEscapeError,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
-syn region pythonUniString	start=+[uU]'''+ end=+'''+ keepend contains=pythonEscape,pythonUniEscape,pythonEscapeError,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
-
-syn match  pythonUniEscape	"\\u\x\{4}" display contained
-syn match  pythonUniEscapeError	"\\u\x\{,3}\X" display contained
-syn match  pythonUniEscape	"\\U\x\{8}" display contained
-syn match  pythonUniEscapeError	"\\U\x\{,7}\X" display contained
-syn match  pythonUniEscape	"\\N{[A-Z ]\+}" display contained
-syn match  pythonUniEscapeError	"\\N{[^A-Z ]\+}" display contained
-
-" Raw strings
-syn region pythonRawString	start=+[rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,@Spell
-syn region pythonRawString	start=+[rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,@Spell
-syn region pythonRawString	start=+[rR]"""+ end=+"""+ keepend contains=pythonDocTest2,pythonSpaceError,@Spell
-syn region pythonRawString	start=+[rR]'''+ end=+'''+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
-
-syn match pythonRawEscape	+\\['"]+ display transparent contained
-
-" Unicode raw strings
-syn region pythonUniRawString	start=+[uU][rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,pythonUniRawEscape,pythonUniRawEscapeError,@Spell
-syn region pythonUniRawString	start=+[uU][rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,pythonUniRawEscape,pythonUniRawEscapeError,@Spell
-syn region pythonUniRawString	start=+[uU][rR]"""+ end=+"""+ keepend contains=pythonUniRawEscape,pythonUniRawEscapeError,pythonDocTest2,pythonSpaceError,@Spell
-syn region pythonUniRawString	start=+[uU][rR]'''+ end=+'''+ keepend contains=pythonUniRawEscape,pythonUniRawEscapeError,pythonDocTest,pythonSpaceError,@Spell
-
-syn match  pythonUniRawEscape		"\([^\\]\(\\\\\)*\)\@<=\\u\x\{4}" display contained
-syn match  pythonUniRawEscapeError	"\([^\\]\(\\\\\)*\)\@<=\\u\x\{,3}\X" display contained
-
-if exists("python_highlight_string_formatting") && python_highlight_string_formatting != 0
-  " String formatting
-  syn match pythonStrFormat	"%\(([^)]\+)\)\=[-#0 +]*\d*\(\.\d\+\)\=[hlL]\=[diouxXeEfFgGcrs%]" contained containedin=pythonString,pythonBString,pythonUniString,pythonRawString,pythonUniRawString
-  syn match pythonStrFormat	"%[-#0 +]*\(\*\|\d\+\)\=\(\.\(\*\|\d\+\)\)\=[hlL]\=[diouxXeEfFgGcrs%]" contained containedin=pythonString,pythonBString,pythonUniString,pythonRawString,pythonUniRawString
+  syn match pythonBytesError    '.\+' display contained
+  syn match pythonBytesContent  '[\u0000-\u00ff]\+' display contained contains=pythonBytesEscape,pythonBytesEscapeError
 endif
 
-if exists("python_highlight_doctests") && python_highlight_doctests != 0
+syn match pythonBytesEscape       +\\[abfnrtv'"\\]+ display contained
+syn match pythonBytesEscape       '\\\o\o\=\o\=' display contained
+syn match pythonBytesEscapeError  '\\\o\{,2}[89]' display contained
+syn match pythonBytesEscape       '\\x\x\{2}' display contained
+syn match pythonBytesEscapeError  '\\x\x\=\X' display contained
+syn match pythonBytesEscape       '\\$'
+
+syn match pythonUniEscape         '\\u\x\{4}' display contained
+syn match pythonUniEscapeError    '\\u\x\{,3}\X' display contained
+syn match pythonUniEscape         '\\U\x\{8}' display contained
+syn match pythonUniEscapeError    '\\U\x\{,7}\X' display contained
+syn match pythonUniEscape         '\\N{[A-Z ]\+}' display contained
+syn match pythonUniEscapeError    '\\N{[^A-Z ]\+}' display contained
+
+if s:Python2Syntax()
+  " Python 2 Unicode strings
+  syn region pythonUniString  start=+[uU]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
+  syn region pythonUniString  start=+[uU]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
+  syn region pythonUniString  start=+[uU]'''+ skip=+\\'+ end=+'''+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonUniString  start=+[uU]"""+ skip=+\\"+ end=+"""+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
+else
+  " Python 3 strings
+  syn region pythonString   start=+'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
+  syn region pythonString   start=+"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
+  syn region pythonString   start=+'''+ skip=+\\'+ end=+'''+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonString   start=+"""+ skip=+\\"+ end=+"""+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
+
+  syn region pythonFString   start=+[fF]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
+  syn region pythonFString   start=+[fF]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
+  syn region pythonFString   start=+[fF]'''+ skip=+\\'+ end=+'''+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonFString   start=+[fF]"""+ skip=+\\"+ end=+"""+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
+endif
+
+if s:Python2Syntax()
+  " Python 2 Unicode raw strings
+  syn region pythonUniRawString start=+[uU][rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,pythonUniRawEscape,pythonUniRawEscapeError,@Spell
+  syn region pythonUniRawString start=+[uU][rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,pythonUniRawEscape,pythonUniRawEscapeError,@Spell
+  syn region pythonUniRawString start=+[uU][rR]'''+ skip=+\\'+ end=+'''+ keepend contains=pythonUniRawEscape,pythonUniRawEscapeError,pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonUniRawString start=+[uU][rR]"""+ skip=+\\"+ end=+"""+ keepend contains=pythonUniRawEscape,pythonUniRawEscapeError,pythonDocTest2,pythonSpaceError,@Spell
+
+  syn match  pythonUniRawEscape       '\%([^\\]\%(\\\\\)*\)\@<=\\u\x\{4}' display contained
+  syn match  pythonUniRawEscapeError  '\%([^\\]\%(\\\\\)*\)\@<=\\u\x\{,3}\X' display contained
+endif
+
+" Python 2/3 raw strings
+if s:Python2Syntax()
+  syn region pythonRawString  start=+[bB]\=[rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,@Spell
+  syn region pythonRawString  start=+[bB]\=[rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,@Spell
+  syn region pythonRawString  start=+[bB]\=[rR]'''+ skip=+\\'+ end=+'''+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonRawString  start=+[bB]\=[rR]"""+ skip=+\\"+ end=+"""+ keepend contains=pythonDocTest2,pythonSpaceError,@Spell
+else
+  syn region pythonRawString  start=+[rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,@Spell
+  syn region pythonRawString  start=+[rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,@Spell
+  syn region pythonRawString  start=+[rR]'''+ skip=+\\'+ end=+'''+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonRawString  start=+[rR]"""+ skip=+\\"+ end=+"""+ keepend contains=pythonDocTest2,pythonSpaceError,@Spell
+
+  syn region pythonRawFString   start=+\%([fF][rR]\|[rR][fF]\)'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,@Spell
+  syn region pythonRawFString   start=+\%([fF][rR]\|[rR][fF]\)"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,@Spell
+  syn region pythonRawFString   start=+\%([fF][rR]\|[rR][fF]\)'''+ skip=+\\'+ end=+'''+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonRawFString   start=+\%([fF][rR]\|[rR][fF]\)"""+ skip=+\\"+ end=+"""+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
+
+  syn region pythonRawBytes  start=+\%([bB][rR]\|[rR][bB]\)'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,@Spell
+  syn region pythonRawBytes  start=+\%([bB][rR]\|[rR][bB]\)"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,@Spell
+  syn region pythonRawBytes  start=+\%([bB][rR]\|[rR][bB]\)'''+ skip=+\\'+ end=+'''+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
+  syn region pythonRawBytes  start=+\%([bB][rR]\|[rR][bB]\)"""+ skip=+\\"+ end=+"""+ keepend contains=pythonDocTest2,pythonSpaceError,@Spell
+endif
+
+syn match pythonRawEscape +\\['"]+ display contained
+
+if s:Enabled('g:python_highlight_string_formatting')
+  " % operator string formatting
+  if s:Python2Syntax()
+    syn match pythonStrFormatting '%\%(([^)]\+)\)\=[-#0 +]*\d*\%(\.\d\+\)\=[hlL]\=[diouxXeEfFgGcrs%]' contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString,pythonBytesContent
+    syn match pythonStrFormatting '%[-#0 +]*\%(\*\|\d\+\)\=\%(\.\%(\*\|\d\+\)\)\=[hlL]\=[diouxXeEfFgGcrs%]' contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString,pythonBytesContent
+  else
+    syn match pythonStrFormatting '%\%(([^)]\+)\)\=[-#0 +]*\d*\%(\.\d\+\)\=[hlL]\=[diouxXeEfFgGcrs%]' contained containedin=pythonString,pythonRawString,pythonBytesContent
+    syn match pythonStrFormatting '%[-#0 +]*\%(\*\|\d\+\)\=\%(\.\%(\*\|\d\+\)\)\=[hlL]\=[diouxXeEfFgGcrs%]' contained containedin=pythonString,pythonRawString,pythonBytesContent
+  endif
+endif
+
+if s:Enabled('g:python_highlight_string_format')
+  " str.format syntax
+  if s:Python2Syntax()
+    syn match pythonStrFormat '{{\|}}' contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
+    syn match pythonStrFormat '{\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)\=\%(\.\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\[\%(\d\+\|[^!:\}]\+\)\]\)*\%(![rsa]\)\=\%(:\%({\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)}\|\%([^}]\=[<>=^]\)\=[ +-]\=#\=0\=\d*,\=\%(\.\d\+\)\=[bcdeEfFgGnosxX%]\=\)\=\)\=}' contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
+  else
+    syn match pythonStrFormat "{\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)\=\%(\.\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\[\%(\d\+\|[^!:\}]\+\)\]\)*\%(![rsa]\)\=\%(:\%({\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)}\|\%([^}]\=[<>=^]\)\=[ +-]\=#\=0\=\d*,\=\%(\.\d\+\)\=[bcdeEfFgGnosxX%]\=\)\=\)\=}" contained containedin=pythonString,pythonRawString
+    syn region pythonStrInterpRegion start="{"he=e+1,rs=e+1 end="\%(![rsa]\)\=\%(:\%({\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)}\|\%([^}]\=[<>=^]\)\=[ +-]\=#\=0\=\d*,\=\%(\.\d\+\)\=[bcdeEfFgGnosxX%]\=\)\=\)\=}"hs=s-1,re=s-1 extend contained containedin=pythonFString,pythonRawFString contains=pythonStrInterpRegion,@pythonExpression
+    syn match pythonStrFormat "{{\|}}" contained containedin=pythonString,pythonRawString,pythonFString,pythonRawFString
+  endif
+endif
+
+if s:Enabled('g:python_highlight_string_templates')
+  " string.Template format
+  if s:Python2Syntax()
+    syn match pythonStrTemplate '\$\$' contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
+    syn match pythonStrTemplate '\${[a-zA-Z_][a-zA-Z0-9_]*}' contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
+    syn match pythonStrTemplate '\$[a-zA-Z_][a-zA-Z0-9_]*' contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
+  else
+    syn match pythonStrTemplate '\$\$' contained containedin=pythonString,pythonRawString
+    syn match pythonStrTemplate '\${[a-zA-Z_][a-zA-Z0-9_]*}' contained containedin=pythonString,pythonRawString
+    syn match pythonStrTemplate '\$[a-zA-Z_][a-zA-Z0-9_]*' contained containedin=pythonString,pythonRawString
+  endif
+endif
+
+if s:Enabled('g:python_highlight_doctests')
   " DocTests
-  syn region pythonDocTest	start="^\s*>>>" end=+'''+he=s-1 end="^\s*$" contained
-  syn region pythonDocTest2	start="^\s*>>>" end=+"""+he=s-1 end="^\s*$" contained
+  syn region pythonDocTest   start='^\s*>>>' skip=+\\'+ end=+'''+he=s-1 end='^\s*$' contained
+  syn region pythonDocTest2  start='^\s*>>>' skip=+\\"+ end=+"""+he=s-1 end='^\s*$' contained
 endif
 
+"
 " Numbers (ints, longs, floats, complex)
-syn match   pythonHexNumber	"\<0[xX]\x\+[lL]\=\>" display
-syn match   pythonHexNumber	"\<0[xX]\>" display
-syn match   pythonNumber	"\<\d\+[lLjJ]\=\>" display
-syn match   pythonFloat		"\.\d\+\([eE][+-]\=\d\+\)\=[jJ]\=\>" display
-syn match   pythonFloat		"\<\d\+[eE][+-]\=\d\+[jJ]\=\>" display
-syn match   pythonFloat		"\<\d\+\.\d*\([eE][+-]\=\d\+\)\=[jJ]\=" display
+"
 
-syn match   pythonOctalError	"\<0\o*[89]\d*[lL]\=\>" display
-syn match   pythonHexError	"\<0[xX]\X\+[lL]\=\>" display
+if s:Python2Syntax()
+  syn match   pythonHexError    '\<0[xX]\x*[g-zG-Z]\+\x*[lL]\=\>' display
+  syn match   pythonOctError    '\<0[oO]\=\o*\D\+\d*[lL]\=\>' display
+  syn match   pythonBinError    '\<0[bB][01]*\D\+\d*[lL]\=\>' display
 
-if exists("python_highlight_builtins") && python_highlight_builtins != 0
-  " Builtin functions, types and objects
-  syn keyword pythonBuiltinObj	Ellipsis NotImplemented
+  syn match   pythonHexNumber   '\<0[xX]\x\+[lL]\=\>' display
+  syn match   pythonOctNumber   '\<0[oO]\o\+[lL]\=\>' display
+  syn match   pythonBinNumber   '\<0[bB][01]\+[lL]\=\>' display
 
-  syn keyword pythonBuiltinFunc	__import__ abs all any apply
-  syn keyword pythonBuiltinFunc	basestring bool buffer bytearray bytes callable
-  syn keyword pythonBuiltinFunc	chr classmethod cmp coerce compile complex
-  syn keyword pythonBuiltinFunc	delattr dict dir divmod enumerate eval
-  syn keyword pythonBuiltinFunc	execfile file filter float frozenset getattr
-  syn keyword pythonBuiltinfunc globals hasattr hash help hex id 
-  syn keyword pythonBuiltinFunc	input int intern isinstance
-  syn keyword pythonBuiltinFunc	issubclass iter len list locals long map max
-  syn keyword pythonBuiltinFunc	min object oct open ord pow property range
-  syn keyword pythonBuiltinFunc	raw_input reduce reload repr
-  syn keyword pythonBuiltinFunc reversed round set setattr
-  syn keyword pythonBuiltinFunc	slice sorted staticmethod str sum super tuple
-  syn keyword pythonBuiltinFunc	type unichr unicode vars xrange zip
+  syn match   pythonNumberError '\<\d\+\D[lL]\=\>' display
+  syn match   pythonNumber      '\<\d[lL]\=\>' display
+  syn match   pythonNumber      '\<[0-9]\d\+[lL]\=\>' display
+  syn match   pythonNumber      '\<\d\+[lLjJ]\>' display
+
+  syn match   pythonOctError    '\<0[oO]\=\o*[8-9]\d*[lL]\=\>' display
+  syn match   pythonBinError    '\<0[bB][01]*[2-9]\d*[lL]\=\>' display
+
+  syn match   pythonFloat       '\.\d\+\%([eE][+-]\=\d\+\)\=[jJ]\=\>' display
+  syn match   pythonFloat       '\<\d\+[eE][+-]\=\d\+[jJ]\=\>' display
+  syn match   pythonFloat       '\<\d\+\.\d*\%([eE][+-]\=\d\+\)\=[jJ]\=' display
+else
+  syn match   pythonOctError    '\<0[oO]\=\o*\D\+\d*\>' display
+  " pythonHexError comes after pythonOctError so that 0xffffl is pythonHexError
+  syn match   pythonHexError    '\<0[xX]\x*[g-zG-Z]\x*\>' display
+  syn match   pythonBinError    '\<0[bB][01]*\D\+\d*\>' display
+
+  syn match   pythonHexNumber   '\<0[xX][_0-9a-fA-F]*\x\>' display
+  syn match   pythonOctNumber   '\<0[oO][_0-7]*\o\>' display
+  syn match   pythonBinNumber   '\<0[bB][_01]*[01]\>' display
+
+  syn match   pythonNumberError '\<\d[_0-9]*\D\>' display
+  syn match   pythonNumberError '\<0[_0-9]\+\>' display
+  syn match   pythonNumberError '\<0_x\S*\>' display
+  syn match   pythonNumberError '\<0[bBxXoO][_0-9a-fA-F]*_\>' display
+  syn match   pythonNumberError '\<\d[_0-9]*_\>' display
+  syn match   pythonNumber      '\<\d\>' display
+  syn match   pythonNumber      '\<[1-9][_0-9]*\d\>' display
+  syn match   pythonNumber      '\<\d[jJ]\>' display
+  syn match   pythonNumber      '\<[1-9][_0-9]*\d[jJ]\>' display
+
+  syn match   pythonOctError    '\<0[oO]\=\o*[8-9]\d*\>' display
+  syn match   pythonBinError    '\<0[bB][01]*[2-9]\d*\>' display
+
+  syn match   pythonFloat       '\.\d\%([_0-9]*\d\)\=\%([eE][+-]\=\d\%([_0-9]*\d\)\=\)\=[jJ]\=\>' display
+  syn match   pythonFloat       '\<\d\%([_0-9]*\d\)\=[eE][+-]\=\d\%([_0-9]*\d\)\=[jJ]\=\>' display
+  syn match   pythonFloat       '\<\d\%([_0-9]*\d\)\=\.\d\%([_0-9]*\d\)\=\%([eE][+-]\=\d\%([_0-9]*\d\)\=\)\=[jJ]\=' display
 endif
 
-if exists("python_highlight_exceptions") && python_highlight_exceptions != 0
-  " Builtin exceptions and warnings
-  syn keyword pythonExClass	BaseException
-  syn keyword pythonExClass	Exception StandardError ArithmeticError
-  syn keyword pythonExClass	LookupError EnvironmentError
+"
+" Builtin objects and types
+"
 
-  syn keyword pythonExClass	AssertionError AttributeError EOFError
-  syn keyword pythonExClass	FloatingPointError GeneratorExit IOError
-  syn keyword pythonExClass	ImportError IndexError KeyError
-  syn keyword pythonExClass	KeyboardInterrupt MemoryError NameError
-  syn keyword pythonExClass	NotImplementedError OSError OverflowError
-  syn keyword pythonExClass	ReferenceError RuntimeError StopIteration
-  syn keyword pythonExClass	SyntaxError IndentationError TabError
-  syn keyword pythonExClass	SystemError SystemExit TypeError
-  syn keyword pythonExClass	UnboundLocalError UnicodeError
-  syn keyword pythonExClass	UnicodeEncodeError UnicodeDecodeError
-  syn keyword pythonExClass	UnicodeTranslateError ValueError
-  syn keyword pythonExClass	WindowsError ZeroDivisionError
-
-  syn keyword pythonExClass	Warning UserWarning DeprecationWarning
-  syn keyword pythonExClass	PendingDepricationWarning SyntaxWarning
-  syn keyword pythonExClass	RuntimeWarning FutureWarning OverflowWarning
-  syn keyword pythonExClass	ImportWarning UnicodeWarning
+if s:Enabled('g:python_highlight_builtin_objs')
+  syn keyword pythonNone        None
+  syn keyword pythonBoolean     True False
+  syn keyword pythonBuiltinObj  Ellipsis NotImplemented
+  syn match pythonBuiltinObj    '\v\.@<!<%(object|bool|int|float|tuple|str|list|dict|set|frozenset|bytearray|bytes)>'
+  syn keyword pythonBuiltinObj  __debug__ __doc__ __file__ __name__ __package__
+  syn keyword pythonBuiltinObj  __loader__ __spec__ __path__ __cached__
 endif
 
-if exists("python_slow_sync") && python_slow_sync != 0
+"
+" Builtin functions
+"
+
+if s:Enabled('g:python_highlight_builtin_funcs')
+  let s:funcs_re = '__import__|abs|all|any|bin|callable|chr|classmethod|compile|complex|delattr|dir|divmod|enumerate|eval|filter|format|getattr|globals|hasattr|hash|help|hex|id|input|isinstance|issubclass|iter|len|locals|map|max|memoryview|min|next|oct|open|ord|pow|property|range|repr|reversed|round|setattr|slice|sorted|staticmethod|sum|super|type|vars|zip'
+
+  if s:Python2Syntax()
+    let s:funcs_re .= '|apply|basestring|buffer|cmp|coerce|execfile|file|intern|long|raw_input|reduce|reload|unichr|unicode|xrange'
+    if s:Enabled('g:python_print_as_function')
+      let s:funcs_re .= '|print'
+    endif
+  else
+      let s:funcs_re .= '|ascii|exec|print'
+  endif
+
+  let s:funcs_re = 'syn match pythonBuiltinFunc ''\v\.@<!\zs<%(' . s:funcs_re . ')>'
+
+  if !s:Enabled('g:python_highlight_builtin_funcs_kwarg')
+      let s:funcs_re .= '\=@!'
+  endif
+
+  execute s:funcs_re . ''''
+  unlet s:funcs_re
+endif
+
+"
+" Builtin exceptions and warnings
+"
+
+if s:Enabled('g:python_highlight_exceptions')
+    let s:exs_re = 'BaseException|Exception|ArithmeticError|LookupError|EnvironmentError|AssertionError|AttributeError|BufferError|EOFError|FloatingPointError|GeneratorExit|IOError|ImportError|IndexError|KeyError|KeyboardInterrupt|MemoryError|NameError|NotImplementedError|OSError|OverflowError|ReferenceError|RuntimeError|StopIteration|SyntaxError|IndentationError|TabError|SystemError|SystemExit|TypeError|UnboundLocalError|UnicodeError|UnicodeEncodeError|UnicodeDecodeError|UnicodeTranslateError|ValueError|VMSError|WindowsError|ZeroDivisionError|Warning|UserWarning|BytesWarning|DeprecationWarning|PendingDepricationWarning|SyntaxWarning|RuntimeWarning|FutureWarning|ImportWarning|UnicodeWarning'
+
+  if s:Python2Syntax()
+      let s:exs_re .= '|StandardError'
+  else
+      let s:exs_re .= '|BlockingIOError|ChildProcessError|ConnectionError|BrokenPipeError|ConnectionAbortedError|ConnectionRefusedError|ConnectionResetError|FileExistsError|FileNotFoundError|InterruptedError|IsADirectoryError|NotADirectoryError|PermissionError|ProcessLookupError|TimeoutError|StopAsyncIteration|ResourceWarning'
+  endif
+
+  execute 'syn match pythonExClass ''\v\.@<!\zs<%(' . s:exs_re . ')>'''
+  unlet s:exs_re
+endif
+
+if s:Enabled('g:python_slow_sync')
   syn sync minlines=2000
 else
   " This is fast but code inside triple quoted strings screws it up. It
   " is impossible to fix because the only way to know if you are inside a
   " triple quoted string is to start from the beginning of the file.
-  syn sync match pythonSync grouphere NONE "):$"
+  syn sync match pythonSync grouphere NONE '):$'
   syn sync maxlines=200
 endif
 
-if version >= 508 || !exists("did_python_syn_inits")
-  if version <= 508
+if v:version >= 508 || !exists('did_python_syn_inits')
+  if v:version <= 508
     let did_python_syn_inits = 1
     command -nargs=+ HiLink hi link <args>
   else
     command -nargs=+ HiLink hi def link <args>
   endif
 
-  HiLink pythonStatement	Statement
-  HiLink pythonImport		Statement
-  HiLink pythonFunction		Function
-  HiLink pythonConditional	Conditional
-  HiLink pythonRepeat		Repeat
-  HiLink pythonException	Exception
-  HiLink pythonOperator		Operator
+  HiLink pythonStatement        Statement
+  HiLink pythonRaiseFromStatement   Statement
+  HiLink pythonImport           Include
+  HiLink pythonFunction         Function
+  HiLink pythonConditional      Conditional
+  HiLink pythonRepeat           Repeat
+  HiLink pythonException        Exception
+  HiLink pythonOperator         Operator
 
-  HiLink pythonDecorator	Define
+  HiLink pythonDecorator        Define
+  HiLink pythonDottedName       Function
+  HiLink pythonDot              Normal
 
-  HiLink pythonComment		Comment
-  HiLink pythonCoding		Special
-  HiLink pythonRun		Special
-  HiLink pythonTodo		Todo
+  HiLink pythonComment          Comment
+  if !s:Enabled('g:python_highlight_file_headers_as_comments')
+    HiLink pythonCoding           Special
+    HiLink pythonRun              Special
+  endif
+  HiLink pythonTodo             Todo
 
-  HiLink pythonError		Error
-  HiLink pythonIndentError	Error
-  HiLink pythonSpaceError	Error
+  HiLink pythonError            Error
+  HiLink pythonIndentError      Error
+  HiLink pythonSpaceError       Error
 
-  HiLink pythonString		String
-  HiLink pythonBString		String
-  HiLink pythonUniString	String
-  HiLink pythonRawString	String
-  HiLink pythonUniRawString	String
+  HiLink pythonString           String
+  HiLink pythonRawString        String
+  HiLink pythonRawEscape        Special
 
-  HiLink pythonEscape			Special
-  HiLink pythonBEscape			Special
-  HiLink pythonEscapeError		Error
-  HiLink pythonBEscapeError		Error
-  HiLink pythonUniEscape		Special
-  HiLink pythonUniEscapeError		Error
-  HiLink pythonUniRawEscape		Special
-  HiLink pythonUniRawEscapeError	Error
+  HiLink pythonUniEscape        Special
+  HiLink pythonUniEscapeError   Error
 
-  HiLink pythonStrFormat	Special
+  if s:Python2Syntax()
+    HiLink pythonUniString          String
+    HiLink pythonUniRawString       String
+    HiLink pythonUniRawEscape       Special
+    HiLink pythonUniRawEscapeError  Error
+  else
+    HiLink pythonBytes              String
+    HiLink pythonRawBytes           String
+    HiLink pythonBytesContent       String
+    HiLink pythonBytesError         Error
+    HiLink pythonBytesEscape        Special
+    HiLink pythonBytesEscapeError   Error
+    HiLink pythonFString            String
+    HiLink pythonRawFString         String
+    HiLink pythonStrInterpRegion    Special
+  endif
 
-  HiLink pythonDocTest		Special
-  HiLink pythonDocTest2		Special
+  HiLink pythonStrFormatting    Special
+  HiLink pythonStrFormat        Special
+  HiLink pythonStrTemplate      Special
 
-  HiLink pythonNumber		Number
-  HiLink pythonHexNumber	Number
-  HiLink pythonFloat		Float
-  HiLink pythonOctalError	Error
-  HiLink pythonHexError		Error
+  HiLink pythonDocTest          Special
+  HiLink pythonDocTest2         Special
 
-  HiLink pythonBuiltinObj	Structure
-  HiLink pythonBuiltinFunc	Function
+  HiLink pythonNumber           Number
+  HiLink pythonHexNumber        Number
+  HiLink pythonOctNumber        Number
+  HiLink pythonBinNumber        Number
+  HiLink pythonFloat            Float
+  HiLink pythonNumberError      Error
+  HiLink pythonOctError         Error
+  HiLink pythonHexError         Error
+  HiLink pythonBinError         Error
 
-  HiLink pythonExClass	Structure
+  HiLink pythonBoolean          Boolean
+  HiLink pythonNone             Constant
+
+  HiLink pythonBuiltinObj       Structure
+  HiLink pythonBuiltinFunc      Function
+
+  HiLink pythonExClass          Structure
+  HiLink pythonClassVar         Identifier
 
   delcommand HiLink
 endif
 
-let b:current_syntax = "python"
+let b:current_syntax = 'python'
 
 endif

syntax/qml.vim

@@ -59,7 +59,7 @@ syn keyword qmlLabel             case default
 syn keyword qmlException         try catch finally throw
 syn keyword qmlMessage           alert confirm prompt status
 syn keyword qmlGlobal            self
-syn keyword qmlDeclaration       property signal
+syn keyword qmlDeclaration       property signal readonly
 syn keyword qmlReserved          abstract boolean byte char class const debugger enum export extends final float goto implements import interface long native package pragma private protected public short static super synchronized throws transient volatile
 
 if get(g:, 'qml_fold', 0)

syntax/tmux.vim

@@ -19,9 +19,9 @@ if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'tmux') == -1
 " - Switch on syntax highlighting by adding "syntax enable" to .vimrc.
 "
 
-if version < 600
+if v:version < 600
 	syntax clear
-elseif exists("b:current_syntax")
+elseif exists('b:current_syntax')
 	finish
 endif
 
@@ -52,6 +52,7 @@ syn keyword tmuxCmds
 	\ confirm
 	\ confirm-before
 	\ copy-mode
+	\ copy-mode-vi
 	\ delete-buffer
 	\ deleteb
 	\ detach
@@ -327,6 +328,6 @@ hi def link tmuxTodo			Todo
 hi def link tmuxVariable		Constant
 hi def link tmuxVariableExpansion	Constant
 
-let b:current_syntax = "tmux"
+let b:current_syntax = 'tmux'
 
 endif

syntax/toml.vim

@@ -38,7 +38,9 @@ syn match tomlBoolean /\<\%(true\|false\)\>/ display
 hi def link tomlBoolean Boolean
 
 " https://tools.ietf.org/html/rfc3339
-syn match tomlDate /\d\{4\}-\d\{2\}-\d\{2\}T\d\{2\}:\d\{2\}:\d\{2\}\%(\.\d\+\)\?\%(Z\|[+-]\d\{2\}:\d\{2\}\)/ display
+syn match tomlDate /\d\{4\}-\d\{2\}-\d\{2\}/ display
+syn match tomlDate /\d\{2\}:\d\{2\}:\d\{2\}\%(\.\d\+\)\?/ display
+syn match tomlDate /\d\{4\}-\d\{2\}-\d\{2\}[T ]\d\{2\}:\d\{2\}:\d\{2\}\%(\.\d\+\)\?\%(Z\|[+-]\d\{2\}:\d\{2\}\)\?/ display
 hi def link tomlDate Constant
 
 syn region tomlKeyDq oneline start=/"/ end=/"/ contains=tomlEscape contained