Fix MaySet detection for Lua following Neovim update (#195)

With version v0.10.0 of Neovim, the `:verbose` output added
"(run Nvim with -V1 for more details)" to the previous message,
which was simply "Last set from Lua".

.github/FUNDING.yml

@@ -0,0 +1,2 @@
+github: tpope
+custom: ["https://www.paypal.me/vimpope"]

README.markdown

@@ -15,12 +15,12 @@ set of defaults that (hopefully) everyone can agree on.
 
 ## Installation
 
-If you don't have a preferred installation method, I recommend
-installing [pathogen.vim](https://github.com/tpope/vim-pathogen), and
-then simply copy and paste:
+Install using your favorite package manager, or use Vim's built-in package
+support:
 
-    cd ~/.vim/bundle
-    git clone git://github.com/tpope/vim-sensible.git
+    mkdir -p ~/.vim/pack/tpope/start
+    cd ~/.vim/pack/tpope/start
+    git clone https://tpope.io/vim/sensible.git
 
 ## Features
 
@@ -51,7 +51,7 @@ documentation for an option.  If you install [scriptease.vim][], you can press
 
 Normally, sensible.vim loads after your vimrc, making it a bit tricky to
 override (although you could use `after/plugin/sensible.vim`).  If you want to
-load it earlier, add the following line to you vimrc, then put your overrides
+load it earlier, add the following line to your vimrc, then put your overrides
 below.
 
     runtime! plugin/sensible.vim

plugin/sensible.vim

@@ -1,6 +1,6 @@
 " sensible.vim - Defaults everyone can agree on
 " Maintainer:   Tim Pope <http://tpo.pe/>
-" Version:      1.2
+" Version:      2.0
 
 if exists('g:loaded_sensible') || &compatible
   finish
@@ -8,81 +8,151 @@ else
   let g:loaded_sensible = 'yes'
 endif
 
-if has('autocmd')
+" Use :help 'option' to see the documentation for the given option.
+
+" Disable vi compatibility, if for some reason it's on.
+if &compatible
+  set nocompatible
+endif
+
+" Check if an option was set from a file in $HOME.  This lets us avoid
+" overriding options in the user's vimrc, but still override options in the
+" system vimrc.
+function! s:MaySet(option) abort
+  if exists('*execute')
+    let out = execute('verbose setglobal all ' . a:option . '?')
+  else
+    redir => out
+    silent verbose execute 'setglobal all' a:option . '?'
+    redir END
+  endif
+  return out !~# " \\(\\~[\\/]\\|Lua\\)[^\n]*$"
+endfunction
+
+if s:MaySet('backspace')
+  set backspace=indent,eol,start
+endif
+" Disable completing keywords in included files (e.g., #include in C).  When
+" configured properly, this can result in the slow, recursive scanning of
+" hundreds of files of dubious relevance.
+set complete-=i
+if s:MaySet('smarttab')
+  set smarttab
+endif
+
+set nrformats-=octal
+
+" Make the escape key more responsive by decreasing the wait time for an
+" escape sequence (e.g., arrow keys).
+if !has('nvim') && &ttimeoutlen == -1
+  set ttimeout
+  set ttimeoutlen=100
+endif
+
+if has('reltime') && s:MaySet('incsearch')
+  set incsearch
+endif
+" Use CTRL-L to clear the highlighting of 'hlsearch' (off by default) and call
+" :diffupdate.
+if maparg('<C-L>', 'n') ==# ''
+  nnoremap <silent> <C-L> :nohlsearch<C-R>=has('diff')?'<Bar>diffupdate':''<CR><CR><C-L>
+endif
+
+if s:MaySet('laststatus')
+  set laststatus=2
+endif
+if s:MaySet('ruler')
+  set ruler
+endif
+if s:MaySet('wildmenu')
+  set wildmenu
+endif
+
+if s:MaySet('scrolloff')
+  set scrolloff=1
+endif
+if s:MaySet('sidescroll') && s:MaySet('sidescrolloff')
+  set sidescroll=1
+  set sidescrolloff=2
+endif
+set display+=lastline
+if has('patch-7.4.2109')
+  set display+=truncate
+endif
+
+if s:MaySet('listchars')
+  set listchars=tab:>\ ,trail:-,extends:>,precedes:<,nbsp:+
+endif
+
+" Delete comment character when joining commented lines.
+if v:version > 703 || v:version == 703 && has("patch541")
+  set formatoptions+=j
+endif
+
+" Replace the check for a tags file in the parent directory of the current
+" file with a check in every ancestor directory.
+if has('path_extra') && (',' . &g:tags . ',') =~# ',\./tags,'
+  setglobal tags-=./tags tags-=./tags; tags^=./tags;
+endif
+
+if s:MaySet('autoread')
+  set autoread
+endif
+
+if s:MaySet('history')
+  set history=1000
+endif
+if s:MaySet('tabpagemax')
+  set tabpagemax=50
+endif
+
+" Persist g:UPPERCASE variables, used by some plugins, in .viminfo.
+if !empty(&viminfo)
+  set viminfo^=!
+endif
+" Saving options in session and view files causes more problems than it
+" solves, so disable it.
+set sessionoptions-=options
+set viewoptions-=options
+
+" Allow color schemes to do bright colors without forcing bold.
+if &t_Co == 8 && $TERM !~# '^Eterm'
+  set t_Co=16
+endif
+
+" If the running Vim lacks support for the Fish shell, use Bash instead.
+if &shell =~# 'fish$' && (v:version < 704 || v:version == 704 && !has('patch276'))
+  set shell=/usr/bin/env\ bash
+endif
+
+" Disable a legacy behavior that can break plugin maps.
+if has('langmap') && exists('+langremap') && &langremap && s:MaySet('langremap')
+  set nolangremap
+endif
+
+if !(exists('g:did_load_filetypes') && exists('g:did_load_ftplugin') && exists('g:did_indent_on'))
   filetype plugin indent on
 endif
 if has('syntax') && !exists('g:syntax_on')
   syntax enable
 endif
 
-" Use :help 'option' to see the documentation for the given option.
-
-set autoindent
-set backspace=indent,eol,start
-set complete-=i
-set smarttab
-
-set nrformats-=octal
-
-if !has('nvim') && &ttimeoutlen == -1
-  set ttimeout
-  set ttimeoutlen=100
+if empty(mapcheck('<C-U>', 'i'))
+  inoremap <C-U> <C-G>u<C-U>
+endif
+if empty(mapcheck('<C-W>', 'i'))
+  inoremap <C-W> <C-G>u<C-W>
 endif
 
-set incsearch
-" Use <C-L> to clear the highlighting of :set hlsearch.
-if maparg('<C-L>', 'n') ==# ''
-  nnoremap <silent> <C-L> :nohlsearch<C-R>=has('diff')?'<Bar>diffupdate':''<CR><CR><C-L>
+" From `:help :DiffOrig`.
+if exists(":DiffOrig") != 2
+  command DiffOrig vert new | set bt=nofile | r ++edit # | 0d_
+        \ | diffthis | wincmd p | diffthis
 endif
 
-set laststatus=2
-set ruler
-set wildmenu
-
-if !&scrolloff
-  set scrolloff=1
-endif
-if !&sidescrolloff
-  set sidescrolloff=5
-endif
-set display+=lastline
-
-if &encoding ==# 'latin1' && has('gui_running')
-  set encoding=utf-8
-endif
-
-if &listchars ==# 'eol:$'
-  set listchars=tab:>\ ,trail:-,extends:>,precedes:<,nbsp:+
-endif
-
-if v:version > 703 || v:version == 703 && has("patch541")
-  set formatoptions+=j " Delete comment character when joining commented lines
-endif
-
-if has('path_extra')
-  setglobal tags-=./tags tags-=./tags; tags^=./tags;
-endif
-
-if &shell =~# 'fish$' && (v:version < 704 || v:version == 704 && !has('patch276'))
-  set shell=/bin/bash
-endif
-
-set autoread
-
-if &history < 1000
-  set history=1000
-endif
-if &tabpagemax < 50
-  set tabpagemax=50
-endif
-if !empty(&viminfo)
-  set viminfo^=!
-endif
-set sessionoptions-=options
-
-" Allow color schemes to do bright colors without forcing bold.
-if &t_Co == 8 && $TERM !~# '^linux\|^Eterm'
-  set t_Co=16
+" Correctly highlight $() and other modern affordances in filetype=sh.
+if !exists('g:is_posix') && !exists('g:is_bash') && !exists('g:is_kornshell') && !exists('g:is_dash')
+  let g:is_posix = 1
 endif
 
 " Load matchit.vim, but only if the user hasn't installed a newer version.
@@ -90,6 +160,7 @@ if !exists('g:loaded_matchit') && findfile('plugin/matchit.vim', &rtp) ==# ''
   runtime! macros/matchit.vim
 endif
 
-inoremap <C-U> <C-G>u<C-U>
-
-" vim:set ft=vim et sw=2:
+" Enable the :Man command shipped inside Vim's man filetype plugin.
+if exists(':Man') != 2 && !exists('g:loaded_man') && &filetype !=? 'man' && !has('nvim')
+  runtime ftplugin/man.vim
+endif